How to remove extra levels in list

Question

My question is how to turn a 4-level matrix (notice one extra level)

A = {{{{1, 2, 3}, {4, 5, 6}}}, {{{7, 8, 9}, {10, 11, 12}}}};

into the following:

B = {{{1, 2, 3}, {4, 5, 6}}, {{7, 8, 9}, {10, 11, 12}}};

I think Flatten might do the job but I was unable to understand how it works, especially with these matrix second argument.

So a more general question: is there a way to detect extra levels and eliminate them all together?

I am using Mathematica 10.4.1

Can you answer the general question about how Flatten works and how to remove extra levels in general? I will give you points. Thanks — Kaa1el, Aug 01 '16 at 23:13
Flatten by itself removes all Lists. The second argument specifies which level it should remove. (e.g. 2 removes two enclosing Lists). If you put a list or a matrix in the second argument, it Flattens those levels only. Here is a good explanation on that: (119). — JungHwan Min, Aug 01 '16 at 23:16
Have you even considered searching the site for "Flatten" before you posted your question? — halirutan, Aug 01 '16 at 23:55

score 8 · Accepted Answer · edited Jun 16 '20 at 09:23

In this case, I would recommend ArrayReshape, which I think is easy to understand

Let

a = {{{{1, 2, 3}, {4, 5, 6}}}, {{{7, 8, 9}, {10, 11, 12}}}};
b = {{{1, 2, 3}, {4, 5, 6}}, {{7, 8, 9}, {10, 11, 12}}};

Now

Dimensions[b]

{2, 2, 3}

So you want a to be reshaped into a 2 x 2 x 3 array; therefore,

ArrayReshape[a, {2, 2, 3}] == b

True

Update

ArrayReshape can easily handle complicated cases of unwanted extra levels of List wrapping, which is something Mathematica is prone to produce. In general one can use

ArrayReshape[list, DeleteCases[Dimensions[list], 1]]

to unwrap sub-lists of one element. Thus,

ArrayReshape[a, DeleteCases[Dimensions[a], 1]] == b

True

and

c = {{{{{{1}, {2}, {3}}, {{4}, {5}, {6}}}}, {{{{7}, {8}, {9}}, {{10}, {11}, {12}}}}}}
ArrayReshape[c, DeleteCases[Dimensions[c], 1]] == b

True

You might consider addition a few of these points to Michael's answer here: (105866) — Mr.Wizard, Aug 02 '16 at 07:01
@Mr.Wizard. I added a comment to the answer you cite that links to this answer. I hope that's sufficient -- I feel uncomfortable making substantive edits to the answers. of others. — m_goldberg, Aug 02 '16 at 12:58

score 4 · Answer 2 · answered Aug 01 '16 at 23:30

4

Example

a = {{{{1, 2, 3}, {4, 5, 6}}}, {{{7, 8, 9}, {10, 11, 12}}}};
b = {{{1, 2, 3}, {4, 5, 6}}, {{7, 8, 9}, {10, 11, 12}}};

Flatten[a, 1]

Output

{{{1, 2, 3}, {4, 5, 6}}, {{7, 8, 9}, {10, 11, 12}}}

Test

Flatten[a, 1] == b

True

answered Aug 01 '16 at 23:30

e.doroskevic

5,959
1
13
32

score 3 · Answer 3 · edited Apr 13 '17 at 12:55

3

I use Join @@ (@@ is shorthand for Apply) most of the time but version 10 introduced Catenate which is now arguably the canonical method:

Catenate[A] === B   (* True *)

Be aware however that Catenate and Flatten unpack; this just came up in

Efficiently Delete Duplicates

edited Apr 13 '17 at 12:55

Community

1

answered Aug 02 '16 at 00:24

Mr.Wizard

271,378
34
587
1,371

How to remove extra levels in list

3 Answers3

Update

Linked