Why does ImageFilter fail with radius 1, but works with radius 2?

Question

Bug introduced in 9.0 and persisting through 13.1.0 [CASE:3968469]

When thinking on a way to answer this question using ImageFilter I have found (with Jason B's help) that we can find the end points of the skeleton by increasing the radius in ImageFilter from 1 to 2 in the following way:

pic = Thinning@Binarize@Import["https://i.stack.imgur.com/K8dm3.png"];
ep2 = ImageFilter[If[#[[3, 3]] == 1 && Total[#, 2] == 3, 1, 0] &, pic, 2];
ppos = PixelValuePositions[ep2, White]

{{271, 546}, {190, 471}, {694, 382}, {899, 366}}

But I cannot figure out why the original approach with radius 1 fails:

ep1 = ImageFilter[If[#[[2, 2]] == 1 && Total[#, 2] == 2, 1, 0] &, pic, 1];
PixelValuePositions[ep1, White]

{}

This looks unexpected because there is no actual difference between these two approaches as can be clearly seen by visualizing the neighborhood pixels in the thinned image:

ArrayPlot[1 - ImageData[ImageTrim[pic, {# - .5}, 2]], Mesh -> True, 
   ImageSize -> 100] & /@ ppos

Can anyone explain this issue? Is it a bug?

UPDATE: Additional observations

With the help by Martin Büttner I have discovered that in this particular case the filter function is always supplied with zeros when the radius is 1. Even weirder, there are only 76 (!) evaluations of the filter function:

n = 0; count = 0;
ImageFilter[If[Total[#, 2] == 0, ++n; 0, ++n; ++count; 1] &, pic, 1];
{n, count}

{76, 0}

All the above output was obtained with version 10.4. With version 8.0.4 ImageFilter behaves as expected:

pic = Thinning@Binarize@Import["https://i.stack.imgur.com/K8dm3.png"];
ep1 = ImageFilter[If[#[[2, 2]] == 1 && Total[#, 2] == 2, 1, 0] &, pic, 1];
Total[ImageData[ep1], 2]

So this seems to be a regression bug.

_{Reported as [CASE:3968469]}

I was quite baffled by this as well when trying to answer the other question. It seems that a radius of 1 on a Binarized image always supplies the filter function with zeroes. — Martin Ender, Mar 21 '16 at 13:45
This doesn't seem to be quite the truth. The first input to the filter function can be non-zero, but all the ones afterwards seem to be zero. Tested with: img = Binarize@RandomImage[1, {10, 10}]; ImageFilter[(Print@#; 1) &, img, 1] — Martin Ender, Mar 21 '16 at 13:50
As further proof that the issue is the ImageType (Bit), it's possible to work around the issue by "unbinarising" the image with Image@N@ImageData@... (although I wonder if there isn't a simpler way to convert image types?). — Martin Ender, Mar 21 '16 at 14:30
@Dr.belisarius :). Have you checked it with version 9? I have found that the issue isn't present in version 8.0.4. — Alexey Popkov, Mar 21 '16 at 14:50
The 76 evaluations might be explained by some kind of parallel (nonatomic) writing operations in the variable n during filter evaluation. — Wizard, Mar 21 '16 at 17:37

Alexey Popkov · Accepted Answer · 2017-06-12T07:40:43.730

One can use MorphologicalTransform[image,f] for filtering binary images using 3×3 pixels window:

ep2 = MorphologicalTransform[pic, If[#[[2, 2]] == 1 && Total[#, 2] == 2, 1, 0] &];
ppos = PixelValuePositions[ep2, White]

{{271, 546}, {190, 471}, {694, 382}, {899, 366}}

This method is 2 times faster than the non-buggy ImageFilter, here are timings for Mathematica 8.0.4 on Windows 7 x64:

Do[i1 = ImageFilter[If[#[[2, 2]] == 1 && Total[#, 2] == 2, 1, 0] &, pic, 1], {10}]; // AbsoluteTiming

Do[i2 = MorphologicalTransform[pic, If[#[[2, 2]] == 1 && Total[#, 2] == 2, 1, 0] &], {10}]; // AbsoluteTiming 

i1 == i2

{0.7150409, Null}
{0.3280187, Null}
True

It is also much faster than alternative workarounds listed below and in the original question.

Another way is to use ArrayFilter instead of ImageFilter:

ep3 = Image@
  ArrayFilter[If[#[[2, 2]] == 1 && Total[#, 2] == 2, 1, 0] &, ImageData[pic], {1, 1}]
ppos3 = PixelValuePositions[ep2, White]

{{271, 546}, {190, 471}, {694, 382}, {899, 366}}

ImageData[ep3] == ImageData@ep2

True

... or to use BlockMap along with ArrayPad:

ep4 = Image@
  BlockMap[If[#[[2, 2]] == 1 && Total[#, 2] == 2, 1, 0] &, 
   ArrayPad[ImageData[pic], 1, "Fixed"], {3, 3}, 1]
ppos4 = PixelValuePositions[ep2, White]

Why does ImageFilter fail with radius 1, but works with radius 2?

UPDATE: Additional observations

1 Answers1

Linked