How do I change the Font in BarChart Legend?

Question

Just wondering if anyone knows the proper Syntax to change the Text properties in the BarChart's ChartLegend. I cannot seem to figure out how to get Style[] to apply. Here is an example:

BarChart[{1, 2, 3}, ChartStyle -> "Pastel", 
 ChartLegends -> Placed[{"John", "Mary", "Bob"}, Bottom]]

BarChart[{1, 2, 3}, ChartStyle -> "Pastel", 
 ChartLegends -> Placed[Style[{"John", "Mary", "Bob"},
  FontFamily->"Courier"], Bottom]]

Any help would be greatly appreciated.

t.

Answer 1

Actually you can do it without using Map[] as Placed[] takes a third optional argument for cases like this:

BarChart[{1, 2, 3}, ChartStyle -> "Pastel", 
 ChartLegends -> 
  Placed[{"John", "Mary", "Bob"}, Bottom, Style[#, FontFamily -> "Courier"] &]]

Answer 2

Map[] (i.e., /@) does the trick:

BarChart[{1, 2, 3}, ChartStyle -> "Pastel", 
 ChartLegends -> 
  Placed[Style[#, FontFamily -> "Courier"] & /@ {"John", "Mary", "Bob"}, Bottom]]

Answer 3

One can also do this globally with Legending`LegendContainer:

SetOptions[Legending`GridLegend,
  Legending`LegendContainer -> (Framed @ Append[#, FontFamily -> "Mathematica6"] &)
];

BarChart[{1, 2, 3},
  ChartStyle -> "Pastel", 
  ChartLegends -> Placed[{"John", "Mary", "Bob"}, Bottom]
]

This works because the expression passed to the LegendContainer function has head Style, and Append therefore inserts the given style.