10

There is an Export syntax that lets you specify the elements being exported. This appears to be ignored by "PDF".

plots = Plot[#[x], {x, 0, 1}, ImageSize -> Large] & /@ {Sin, Cos, Tan};

To print each of plots to a PDF page the syntax is

SetDirectory[$UserDocumentsDirectory];
Export["plots.pdf", {"Pages" -> plots}, "Rules", "AllowRasterization" -> False]
ResetDirectory[];

However, the resulting PDF places the list (with curly braces) on one page of the PDF.

enter image description here

Any ideas how to get this to work? Mind you this is in version 10.4 on Win 7 Ent as version 11.1.0 always crashes if I try to Export PDF even after reinstalling.

Update: WRI has responded and said that "PDF" "Pages" Export is not currently supported. A similar workaround of creating a notebook with page break cells was provided.

Edmund
  • 42,267
  • 3
  • 51
  • 143
  • "Pages" is an option for Import, non for Export You should look for printing environment styling If you wish to set the margins, paper size, etc for output document. – Rom38 May 16 '17 at 08:33
  • 1
    @Rom38 Look at the documentation for "XLSX" in the Elements section and notice how the "Sheets" element is documented. You can Export "Sheets" for Excel files. In "PDF" "Pages" is documented the same as "Sheets" in "XLSX". Therefore, it stands to reason that you should be able to Export "Pages". – Edmund May 16 '17 at 10:57
  • logic is absent sometimes in Wolfram documentation. – Rom38 May 16 '17 at 12:26
  • Related: (17008), (13251). – Alexey Popkov May 16 '17 at 15:46
  • @user6014 Export of "Sheets" is not undocumented. Read the documentation. – Edmund May 18 '17 at 18:34

2 Answers2

17

You need something like this:

nb = CreateDocument[
   ExpressionCell[#, PageBreakBelow -> True] & /@ plots];
Export["plots.pdf", nb]

Therefore, you first create a structured document with page-breaks and then export (print) it to pdf.

Rom38
  • 5,129
  • 13
  • 28
7

Turn off the popping up of the NB:

nb = CreateDocument[
   ExpressionCell[#, PageBreakBelow -> True] & /@ plots, Visible -> False];
Export["plots.pdf", nb]

After playing around a little bit it is clear that everything is already -magically- built inside CreateDocument (Mathematica 10.3). Just activate the right Options:

nb = CreateDocument[plots, PageBreakBelow -> True, Visible -> False];
Export["plots.pdf", nb]
Alexey Popkov
  • 61,809
  • 7
  • 149
  • 368
Robert Nowak
  • 861
  • 6
  • 12
  • (+1) Nice discovery of PageBreakBelow being supported by CreateDocument! It looks like we can pass in the same way any other Cell option too. – Alexey Popkov Dec 01 '17 at 20:38
  • e.g. TextAlignment -> Center is working. Also tried to pass a List with individual ailgnmnet for pages TextAlignment -> {Left,Left,Center,Right,...} this unfortunately does not work – Robert Nowak Dec 03 '17 at 15:27