Native function that gives sequential sub-sequences of a list?

Question

I am very surprised not to find this function in the help (or in other questions on this site, which come close)

Is there a Mathematica function f such that

f[{a,b,c,d}] = {{a},{a,b},{a,b,c},{a,b,c,d}}

or must I construct it?

Thank you all so much for your quick answers! Going with myfun[x_] := Take[x, #] & /@ Range[Length[x]] — user2686410, Jan 15 '18 at 02:20

score 8 · Accepted Answer · answered Jan 15 '18 at 02:16

8

Take[{a, b, c, d}, #] & /@ Range[4]

(* {{a}, {a, b}, {a, b, c}, {a, b, c, d}} *)

answered Jan 15 '18 at 02:16

Bob Hanlon

score 6 · Answer 2 · answered Jan 15 '18 at 04:16

6

Another possibility:

Reverse @ NestList[Most, {a,b,c,d}, 3]

{{a}, {a, b}, {a, b, c}, {a, b, c, d}}

answered Jan 15 '18 at 04:16

Carl Woll

In the same 'vein': FoldList[Flatten[{##}] &, Nothing, {a, b, c, d}] – user1066 Jan 15 '18 at 10:28

halirutan · Answer 3 · 2018-01-15T02:13:07.173

5

Two ideas

f1[l_List] := Rest[FoldList[Append, {}, l]];
f2[l_List] := Table[Take[l, i], {i, Length[l]}]

edited Jan 15 '18 at 02:13

answered Jan 15 '18 at 02:06

halirutan

kglr · Answer 4 · 2018-01-15T05:23:24.673

5

ReplaceList[{a, b, c, d}, {x__, ___} :> {x}]

{{a}, {a, b}, {a, b, c}, {a, b, c, d}}

Table[{a, b, c, d}[[;; i]], {i, 4}]

{{a}, {a, b}, {a, b, c}, {a, b, c, d}}

{a, b, c, d}[[;; #]] & /@ Range@4

{{a}, {a, b}, {a, b, c}, {a, b, c, d}}

Partition[{a, b, c, d}, 4, 1, -1, {}]

{{a}, {a, b}, {a, b, c}, {a, b, c, d}}

Extract[{a, b, c, d}, List /@ Range @ Range @ 4]

{{a}, {a, b}, {a, b, c}, {a, b, c, d}}

edited Jan 15 '18 at 05:23

answered Jan 15 '18 at 02:12

kglr

2

https://mathematica.stackexchange.com/a/16568/5478 – Kuba Jan 15 '18 at 06:37
@Kuba, I knew I have seen this question before:) – kglr Jan 15 '18 at 08:00

score 4 · Answer 5 · answered Jan 15 '18 at 04:40

4

For something different

f[x_List] := 
 LowerTriangularize@ConstantArray[x, Length[x]] /. 0 -> Nothing

f[{a, b, c, d}]

{{a}, {a, b}, {a, b, c}, {a, b, c, d}}

answered Jan 15 '18 at 04:40

Mike Honeychurch

5 Answers5