How to control the positions of contour labels?

Question

ContourPlot[x^2 + 5 y^2, {x, -5, 5}, {y, -2, 2}, 
  Contours -> {2, 4, 6, 8, 10, 12, 14, 16, 20}, 
  ContourLabels -> True, 
  AspectRatio -> Automatic, 
  ContourShading -> None]

gives result

enter image description here

But I want result like this

enter image description here

So I hope this code will work

ContourPlot[x^2 + 5 y^2, {x, -5, 5}, {y, -2, 2}, 
  Contours -> {2, 4, 6, 8, 10, 12, 14, 16, 20}, 
  ContourLabels -> (Text[#3, {#1, 0}, Background -> White] &), 
  AspectRatio -> Automatic, 
  ContourShading -> None]

But it didn't, it gives result

enter image description here

So how to control the position of ContourLabels?

None of the workarounds offered in the answers (so far) explains why ContourPlot is giving the wrong coordinate for 14. What am I missing? — rhermans, Sep 11 '14 at 09:20
@rhermans - Unlike for the other labels, the default location for the label 14 is far from the x=0 (semi-major) axis so that when its y coordinate is just changed to zero without also correcting the x coordinate it ends up in the wrong position. The problem is not with ContourPlot but rather with the manual positioning of that label. — Bob Hanlon, Sep 11 '14 at 12:32

score 10 · Answer 1 · answered Sep 11 '14 at 09:13

This can done with Epilog.

f[x_, y_] := x^2 + 5 y^2;
contours = {2, 4, 6, 8, 10, 12, 14, 16, 20};
lblXY = {#, 0} & /@ (Solve[f[x, 0] == #, x][[2, 1, 2]] & /@ contours // N);

ContourPlot[f[x, y], {x, -5, 5}, {y, -2, 2},
  Contours -> contours,
  AspectRatio -> Automatic,
  ContourShading -> None,
  Epilog -> {Thread[Text[contours, lblXY, Background -> White]]}]

contours

score 8 · Answer 2 · answered Sep 11 '14 at 08:31

Kind of a hack but this is what I would do.

f[x_, y_] := x^2 + 5 y^2;
c = {2, 4, 6, 8, 10, 12, 14, 16, 20};
labelPos = Solve[f[x, 0] == #, x][[2, 1, 2]] & /@ c;

Show[
 ContourPlot[f[x, y], {x, -5, 5}, {y, -2, 2}, Contours -> c, 
  AspectRatio -> Automatic, ContourShading -> None],
 Graphics[Text[#[[2]], {#[[1]], 0}, {0, 0}, Background -> White]] & /@
   Transpose[{labelPos, c}]
 ]

enter image description here

score 7 · Answer 3 · answered Sep 11 '14 at 09:07

Yes another workaround

Show@{ContourPlot[x^2 + 5 y^2, {x, -5, 5}, {y, -2, 2}, 
   Contours -> Range[2, 20, 2], AspectRatio -> Automatic, 
   ContourShading -> None, ImageSize -> 640],
  ContourPlot[x^2 + 5 y^2, {x, 0, 5}, {y, -0.0001, 0.0001}, 
   Contours -> Range[2, 20, 2], 
   ContourLabels -> (Text[#3, {#1, #2}, Background -> White] &), 
   ContourShading -> None]}

enter image description here

I decrease the possible region for labels by the second ContourPlot.

kglr · Answer 4 · 2018-01-17T07:12:48.447

f = x^2 + 5 y^2;
ContourPlot[f, {x, -5, 5}, {y, -2, 2}, 
 Contours -> {2, 4, 6, 8, 10, 12, 14, 16, 20},
 ContourLabels -> (Text[#3, {Max[x /. Solve[f == #3 /. y -> 0, x]], 0},
   Background -> White] &),
 AspectRatio -> Automatic, ContourShading -> None]

Use

ContourLabels -> (Text[#3,  Max[x /. Solve[(f /. y -> x/3) == #3, x]] {1, 1/3}, 
  Background -> White] &)

to get

Update: you can also post-process the ContourPlot output to modify the location of the labels:

cp = ContourPlot[x^2 + 5 y^2, {x, -5, 5}, {y, -2, 2}, 
  Contours -> {2, 4, 6, 8, 10, 12, 14, 16, 20}, PlotPoints -> 200, 
  ContourLabels -> Automatic, AspectRatio -> Automatic, 
  ContourShading -> None]; 

Normal[cp] /. Tooltip[a_, b_] :> {a, 
   Text[Style[b, 16], 
    Nearest[{1, 2 GoldenRatio} # & /@ a[[-1, 1]], {.5, 0}, 1][[1]], 
    Background -> White]}

score -1 · Answer 5 · answered Jan 30 '18 at 13:35

I liked the answer, where the labels were printed on the diagonal, but such placing can often lead to overlapping of some labels, so, I modified it to add random shifts: (the example is in my context)

labelfunction := (Shift = RandomReal[{-30, 30}]; 
Text[#3, {e, 100 - e/3 + Shift} /.FindRoot[(ff - #3, {e,100}]]) & ;
ContourPlot[... , ContourLabels -> labelfunction]

How to control the positions of contour labels?

5 Answers5

Linked