The default PlotStyle for Plot3D and how to replace the color

Question

I would like to know the default PlotStyle for Plot3D. Below are two codes, one is the default setting and another is my setting.

Default:

Plot3D[{z=1/2(x^2+y^2), z=x^2+y^2, z=2(x^2+y^2), z=3(x^2+y^2)},
{x,-1,1}, {y,-1,1}, Mesh->None]

My:

Plot3D[{z=1/2(x^2 + y^2), z=x^2+y^2, z=2(x^2+y^2), z=3(x^2+y^2)}, 
{x,-1,1}, {y,-1,1}, Mesh->None, 
PlotStyle -> {ColorData[97, "ColorList"][[2]], ColorData[97, "ColorList"][[1]], 
ColorData[97, "ColorList"][[3]], ColorData[97, "ColorList"][[4]]}]

I know there should be some other settings in the default style, such as Specularity. I want to use the default style except that use different colors or change the order of default colors.

Answer 1

Default PlotStyle

defaultplotstyle = "DefaultPlotStyle" /. 
   (Method /. Charting`ResolvePlotTheme[Automatic, Plot3D])

p1 = Plot3D[{1/2 (x^2 + y^2), x^2 + y^2, 2 (x^2 + y^2), 3 (x^2 + y^2)},
   {x, -1, 1}, {y, -1, 1}, Mesh -> None, ImageSize -> 300];
 p2 = Plot3D[{1/2 (x^2 + y^2), x^2 + y^2, 2 (x^2 + y^2), 3 (x^2 + y^2)},
   {x, -1, 1}, {y, -1, 1}, Mesh -> None, ImageSize -> 300, PlotStyle -> defaultplotstyle];
Row[{p1, p2}]

and how to replace the colors

I want to use the default style except that use different colors or change the order of default colors

To use a different set of colors, say, RandomSample[ColorData[43, "ColorList"]] with the same Lighting and Specularity settings as the default style, you can modify defaultplotstyle as follows:

newcolors = RandomSample[ColorData[43, "ColorList"]][[;;4]];
newplotstyle = defaultplotstyle[[;;4]];
newplotstyle[[All, 2]] = newcolors;

Using PlotStyle -> newplotstyle gives

To change the order of colors, use, say, PlotStyle -> defaultplotstyle[[{2, 1, 4, 3}]] to get

See also: search results for ResolvePlotTheme on this site