Delete column from a dataset in mathematica

Question

Hi, can anyone help me with this? I want to delete the column "FIPS" and "Admin2", and keep the dataset as the original. How would I do this?

data = Import[
  "C:\\Users\\49176\\OneDrive\\Desktop\\time_series_covid19_confirmed_\
US(2).csv", "Dataset", HeaderLines -> 1]

Code is here, and the csv file is downloaded from https://github.com/CSSEGISandData/COVID-19/tree/master/csse_covid_19_data/csse_covid_19_time_series

“ and keep the dataset as the original” - so you do not want to modify the original dataset, you just want to create a new one with those columns dropped? — MarcoB, Dec 03 '20 at 03:40
My bad, I want to modify the dataset, not keep it as original — mjf88530, Dec 03 '20 at 03:41
Please provide the Mathematica code for your Dataset. (Also, please keep the image because of the answer by @kglr .) — Anton Antonov, Dec 03 '20 at 13:31
Thank you for reminding me of that. I have provided the code and the resource of the csv file. — mjf88530, Dec 04 '20 at 03:54

kglr · Accepted Answer · 2020-12-03T06:05:11.177

18

You can use KeyDrop:

picture = Import["https://i.stack.imgur.com/p7ax0.jpg"];
table = Transpose[Partition[TextRecognize[picture, "Word"], 9] /. "Long_" -> "Long"];
ds = Dataset[AssociationThread[First @ table, #] & /@ Rest[table]]

KeyDrop[{"FIPS", "Admin2"}] @ ds

We also get the same result using any of the following:

ds[KeyDrop[{"FIPS", "Admin2"}]]
Query[KeyDrop[{"FIPS", "Admin2"}]] @ ds
ds[All, Delete[{{"FIPS"}, {"Admin2"}}]]
ds[All, Delete[{{1}, {2}}]]

edited Dec 03 '20 at 06:05

answered Dec 03 '20 at 04:27

kglr

394,356
18
477
896

Thank you! It is really helpful! – mjf88530 Dec 03 '20 at 04:50
1

@jfm, my pleasure. Thank you for the accept. Welcome to mma.se. – kglr Dec 03 '20 at 04:51
1

Nice use of TextRecognize! – Anton Antonov Dec 03 '20 at 13:30
This looks like it generates a new dataset with the column dropped, is that right? Is there any way to drop the column 'in place', i.e. without copying over the entire dataset? That is, the only way to have the column deleted here is for one to do 'ds=ds[KeyDrop[{"FIPS", "Admin2"}]]'. (But I can see that this isn't the question in the OP.) – berniethejet Feb 20 '21 at 16:38
1

@berniethejet, see this answer by WRech re modification in place and Dataset. – kglr Feb 21 '21 at 00:26

cvgmt · Answer 2 · 2020-12-03T04:05:53.363

list = {
   <|"a" -> 1, "b" -> "b1", "c" -> {1}, "d" -> 1, "e" -> {1}, 
    "f" -> 1|>,
   <|"a" -> 2, "b" -> "b2", "c" -> {2}, "d" -> 2, "e" -> {2}, 
    "f" -> 2|>,
   <|"a" -> 3, "b" -> "b3", "c" -> {3}, "d" -> 3, "e" -> {3}, 
    "f" -> 3|>,
   <|"a" -> 4, "b" -> "b4", "c" -> {4}, "d" -> 4, "e" -> {4}, 
    "f" -> 4|>,
   <|"a" -> 5, "b" -> "b5", "c" -> {5}, "d" -> 5, "e" -> {5}, 
    "f" -> 5|>,
   <|"a" -> 6, "b" -> "b6", "c" -> {6}, "d" -> 6, "e" -> {6}, 
    "f" -> 6|>};
list // Dataset
list[[All, 3 ;; 6]] // Dataset

Delete column from a dataset in mathematica

2 Answers2