Can I stop the python interpreter appearing?

Question

I am using version 12.1.1.0 on OS X 10.13.

Every so often, a Python interpreter cell appears:

I think I am probably summoning it by inadvertently pressing ">" (due to clumsy typing). Or maybe some other keyboard shortcut which I haven't discovered is to blame.

Before the interpreter cell appears it often causes a beachball for several seconds, and I find it annoying.

Can I disable the interpreter?

Can I disable all keyboard shortcuts which summon it?

For context, this question discusses the interpreter and the keyboard shortcut, but doesn't address how to disable them.

Answer 1

The short-cut > at the beginning of a line to start an external code cell is set as part of style definitions for Input cells:

CurrentValue[{StyleDefinitions, "Input", StyleKeyMapping}]

{"=" -> "WolframAlphaShort", "*" -> "Item", ">" -> "ExternalLanguage"}

You can modify the style definitions and remove ">" -> "ExternalLanguage" to disable this short-cut:

SetOptions[EvaluationNotebook[],   
  StyleDefinitions -> 
    Notebook[
     {Cell[StyleData[StyleDefinitions -> "Default.nb"]],      
      Cell[StyleData["Input"], 
        StyleKeyMapping -> {"=" -> "WolframAlphaShort", "*" -> "Item"}]},     
  StyleDefinitions -> "PrivateStylesheetFormatting.nb"]]

Use StyleKeyMapping -> {} to remove all short-cuts associated with Input cells.

Answer 2

For future reference, this is how to remove the shortcut by default in all new notebooks.

1. Evaluate

   CreateDocument@Notebook[{
     Cell[StyleData[StyleDefinitions -> "Default.nb"]], 
     Cell[StyleData["Input"], 
          StyleKeyMapping -> {"=" -> "WolframAlphaShort", "*" -> "Item"}]
     }, StyleDefinitions -> "PrivateStylesheetFormatting.nb"]
   

2. Save the resulting notebook to $UserBaseDirectory/SystemFiles/FrontEnd/Stylesheets/MyDefault.nb.

3. In Format>Option Inspector, choose Global Preferences and then search for DefaultStyleDefinitions and set it to "MyDefault.nb".

4. Restart Mathematica.

Sources: @kglr's answer, Quickly editing the stylesheet and saving it and How do I change my default stylesheet in Mathematica?

Answer 3

Here is a solution:

Download Autohotkey.exe from https://www.autohotkey.com/ Then make a script file , put it on the desktop.I call it disableWolfram.ahk. It has two lines, one for each use case mentioned above.

^>::return
^=::return

Basically this script is disabling Ctrl > and Ctrl =. Start Mathematica and then double click on the script. Keys have been disabled. For a more animated version:

^>::return
^=::
Send "You shall not pass"
return

My apologies: I haven't looked into Linux/Mac offerings as I am not working on those systems.