How to inject an evaluated expression into a held expression?

Question

I know that there are methods to structurally manipulate held expressions (discussed e.g. here), but I failed to apply those for this particular problem:

(Hold[{3, 4, 5 | 6}] /. (Verbatim@Alternatives)[x__] :> RandomChoice@List@x)

Hold[{3, 4, RandomChoice[{5, 6}]}]

The code should replace any Alternatives in the held expression with an appropriate choice from the alternatives, in this case either 5 or 6, i.e. it should evaluate the replacement.

@kguler but HoldFirst is not a "held expression" wrapper, it's an attribute. — FJRA, Mar 07 '12 at 02:08
@FJRA, just realized why OP wanted to use Hold rather than HoldFirst or HoldRest or HoldAll (and deleted my previous comment before I saw your explanation) — kglr, Mar 07 '12 at 02:14
@rm-rf & WReach, is there any particular reason why Verbatim is used in each answer? This will do too: /. x_Alternatives :> RuleCondition@RandomChoice@(List @@ x) or /. x_Alternatives :> With[{eval = RandomChoice@(List @@ x)}, eval /; True]). — Kuba, Nov 22 '13 at 09:47
@Kuba Verbatim is only used becase I wanted to pass on arguments as Sequence[5, 6] instead of 5|6 as in a replacement, the latter could possibly match more than one thing. It's not necessary but I guess they all tried to comply with my original specification. Your's is equally good. — István Zachar, Nov 22 '13 at 09:59

score 26 · Accepted Answer · answered Mar 07 '12 at 06:13

26

Here are a couple of alternatives to Trott-Strzebonski in @R.M's answer:

Hold[{3,4,5|6}] /.
  Verbatim[Alternatives][x__] :> RuleCondition@RandomChoice@List@x

Hold[{3, 4, 5}]

Hold[{3,4,5|6}] /.
  Verbatim[Alternatives][x__] :> Block[{}, RandomChoice@List@x /; True]

Hold[{3, 4, 6}]

They operate on the same principle as Trott-Strzebonski (i.e. RuleCondition), but express the effect in different ways.

answered Mar 07 '12 at 06:13

WReach

68,832
4
164
269

1

I was tempted to post this answer, but decided to wait for you, as the proper one to do it :). +1. – Leonid Shifrin Mar 07 '12 at 06:44

score 23 · Answer 2 · edited May 23 '17 at 12:35

23

This is a case where the Trott-Strzebonski in-place evaluation trick is useful. You use With to inject inside your held expression as:

(Hold[{3, 4, 5 | 6}] /. (Verbatim@Alternatives)[x__] :> 
    With[{eval = RandomChoice@List@x}, eval /; True])

Out[1]= Hold[{3, 4, 5}]

You should definitely read this post by Leonid, that gives you a good insight into how this works, but in short, using Condition or /; forces the evaluation of eval when the condition is True (i.e., always) and then injected arbitrarily deep using With.

edited May 23 '17 at 12:35

Community

1

answered Mar 07 '12 at 03:35

rm -rf

88,781
21
293
472

Just a note the talk title is "Working with Unevaluated Expressions" in case the link to wolfram library changes again in the future. – xslittlegrass Jul 19 '15 at 16:24

How to inject an evaluated expression into a held expression?

2 Answers2

Linked

Related