How to test if file exists and stop

Question

At the moment I'm using >

filename = FileNameJoin[{root = "F:\\somefolderpath", file = "somefile.extention"}];
If[! DirectoryQ[root], 
  Print[Style["Directory '" <> root <> "' does not exist!", {Red, Bold, Large}]]; Quit[]];
If[! FileExistsQ[filename], 
  Print[Style["File '" <> filename <> "' does not exist!", {Red, Bold, Large}]]; Quit[]];
(*Start using 'filename'*)

edit: Ended up using

SafeFile::usage = "Use instead of Import.";
SafeFile::nodir = "Directory `1` does not exist.";
SafeFile::nofile = "File `1` does not exist.";
SafeFile[filename_,root_:NotebookDirectory[]]:=Module[{
    fullfilename=FileNameJoin[{root,filename}]
},
    If[!TrueQ@DirectoryQ@root,Message[SafeFile::nodir,root];Quit[]];
    If[!TrueQ@FileExistsQ@fullfilename,Message[SafeFile::nofile,filename];Quit[]];
    Import[fullfilename]
]

Quitting kernel was actually what I needed.

The messages would usually be named SafeFile::nodir, and you don't need to define them in your function; they can go right next to the SafeFile::usage definition. — Brett Champion, Apr 13 '12 at 22:06

Mr.Wizard · Accepted Answer · 2012-04-13T17:22:27.037

12

You might consider using Messages instead of Print. You should also consider using TrueQ if either root or filename might not be a string.

file::nodir = "Directory `1` does not exist.";
file::nofile = "File `1` does not exist.";

If[! TrueQ @ DirectoryQ @ root, Message[file::nodir, root]; Abort[]];
If[! TrueQ @ FileExistsQ @ filename, Message[file::nofile, filename]; Abort[]];

edited Apr 13 '12 at 17:22

answered Apr 13 '12 at 17:16

Mr.Wizard

271,378
34
587
1,371

score 7 · Answer 2 · edited Apr 13 '12 at 17:05

7

What you are doing seems pretty minimal already; the fact that MMA notation is very verbose is something that cannot be avoided. You could separate the whole check into a separate function and put that into an invisible initialization cell so it is out of the way.

As for not killing the kernel, just use Abort[] instead of Quit[].

edited Apr 13 '12 at 17:05

Mr.Wizard

271,378
34
587
1,371

answered Apr 13 '12 at 16:50

Timo

835
7
11

How to test if file exists and stop

2 Answers2

Linked