Bug with SparseArray selector in Pick

Question

Bug introduced in version 8 or earlier and fixed in 10.0

I have created a notebook with two cells. This is the content of the first:

g = Graph[{1 \[UndirectedEdge] 2, 2 \[UndirectedEdge] 3, 1 \[UndirectedEdge] 3, 1 \[UndirectedEdge] 4, 4 \[UndirectedEdge] 5, 4 \[UndirectedEdge] 6}]

And this is the content of the second:

g
listDegree = VertexDegree[g]
vl = VertexList[g]
nodeMaxDegree = Pick[vl, listDegree, Max[VertexDegree[g]]][[1]]
aM = AdjacencyMatrix[g];
vLM = aM[[VertexIndex[g, nodeMaxDegree]]];
nN = Pick[vl, vLM, 0]

If I evaluate the second cell (after processing the first) for a second time:

the first time no problem, the results are correct;
the second time the vertex list of g is inexplicably wrong but the graph remain correct!!

I don't understand the cause because the graph g is never touched.

Thanks in advance

Interesting: FullForm[vl] gives List[1, System`Private`InternSequence[], System`Private`InternSequence[], System`Private`InternSequence[], 5, 6]. — István Zachar, Mar 27 '14 at 18:34
Adam, we were probably never supposed to see that symbol. I bet most WRI employees don't even know what it is does as it is in a private context. Who knows though :) — Jacob Akkerboom, Mar 27 '14 at 19:01
Adam, I've modified your title to better reflect the case. Could you please submit this as a bug report for the TechSupport at WRI? — István Zachar, Mar 27 '14 at 19:07
By the way, System'Private'InternSequence[](by itself, without a wrapper like List) "evaluates to" StandardForm. Peculiar :P — Jacob Akkerboom, Mar 27 '14 at 19:46
Adam, can you please report this to support? This is not an official Wolfram site, so they might never see the bug if it's not reported through the official channels (support @ wolfram.com). We would of course all like to see it fixed, so do report it please! — Szabolcs, Mar 27 '14 at 19:54
@JacobAkkerboom, I expect that comes from Typeset`MakeBoxes[_, StandardForm] not having a rule for System'Private'InternSequence[] like it does for Sequence[] — Simon Woods, Mar 27 '14 at 20:04
@SimonWoods hmm let's call that function sPI for short. If you use a rule to transform sPI[], like in sPI[] /. x_ :> x, it will evaluate to Sequence[]. I thought it might have to do with that. I've never looked at Typeset'Makeboxes, your guess is probably better than mine. By the way your Spelunk gives an error for that one. — Jacob Akkerboom, Mar 27 '14 at 20:13
@Jacob That is not a problem of Simon's Spelunk but the way how MakeBoxes definitions are returned and converted to boxformat: just try for example Attributes[LabeledSlider] = {}; FullDefinition@LabeledSlider and be prepared for LOTS of errors... — István Zachar, Mar 27 '14 at 20:16
@Jacob Do you know in which version this bug first appeared? I'd like to add the appropriate version banner to this post. — Mr.Wizard, Feb 03 '15 at 09:08
@Mr.Wizard well, the bug with SparseArray, as illustrated by istvan's answer, is present in version 7 (I could not test earlier versions). The code by the OP first causes trouble in version 8, as the `Combinatorica`` package in version 7 had different syntax. — Jacob Akkerboom, Feb 03 '15 at 11:03

István Zachar · Answer 1 · 2014-03-27T19:04:06.553

10

This is a bug in Pick caused by SparseArray, has nothing to do with Graph. Minimal example (SparseArray object is the fullform version of your vLM):

x = {1, 2, 3, 4, 5, 6};
Pick[x, SparseArray[Automatic, {6}, 0, {1, {{0, 3}, {{2}, {3}, {4}}}, {1, 1, 1}}], 0];
FullForm@x

{1, System`Private`InternSequence[], System`Private`InternSequence[], 
    System`Private`InternSequence[], 5, 6}

As you can observe, the value of x gets updated though no assignment is done: those members are replaced in x which are listed in the SparseArray (2, 3 and 4).

One obvious solution for your case is to wrap the AdjacencyMatrix into Normal so its result won't be a SparseArray.

edited Mar 27 '14 at 19:04

answered Mar 27 '14 at 18:50

István Zachar

47,032
20
143
291

Nice István! I will continue to avoids SparseArrays another day :P. That syntax scares me. – Jacob Akkerboom Mar 27 '14 at 18:57
2

Is InternSequence used Privately to splice interns into the WRI System? :D – rm -rf Mar 27 '14 at 19:06
@rm-rf Veeeery suspicious indeed :). A new kind of exploitation of cheap workforce perhaps? – István Zachar Mar 27 '14 at 19:09
@Jacob It's a pity that the internal structure of SparseArray is not documented. I have no idea what most of those numbers are for. – István Zachar Mar 27 '14 at 19:11
@IstvánZachar hm this may have nothing to do with graph, but we end up changing the vertex list – Jacob Akkerboom Mar 27 '14 at 19:16
3

Nice discovery. Horrible bug - it happens even if x is Protected and Locked. – Simon Woods Mar 27 '14 at 20:06
I notice it doesn't happen if x is a packed array, e.g. try with x = Range[6] – Simon Woods Mar 27 '14 at 20:08
@IstvánZachar but if you ask the VertexList of the graph again, it gives you the same broken thing! – Jacob Akkerboom Mar 27 '14 at 20:15
@Jacob Yes, you are right, sorry. This is indeed scary: it actually modifies g (check with FullForm) and not simply VertexList@g! – István Zachar Mar 27 '14 at 20:22
3

Nice work! And here is my guess of the syntax of the SparseArray! :) – Silvia Mar 27 '14 at 22:29
1

@Silvia Plausible hypothesis, it deserves its own thread! – István Zachar Mar 27 '14 at 23:29
Thanks. If you think it's useful, please feel free to add it into your answer. :) And I still don't know the other possible value for Automatic and the 1... – Silvia Mar 27 '14 at 23:38
@Silvia, please post your answer here! – István Zachar Mar 28 '14 at 08:26
2

@Silvia and Istvan, the 1 is for the sparse array version number – rm -rf Mar 28 '14 at 15:16
@rm-rf Interesting... It reminds me there is a version number in CompiledFunction, too. – Silvia Mar 28 '14 at 15:21

Jacob Akkerboom · Answer 2 · 2014-03-28T10:04:03.603

This looks like a bug to me. Here is a slightly more minimal example.

ue = UndirectedEdge;
g = Graph[ue @@@ {{1, 2}, {2, 3}, {1, 3}, {1, 4}, {4, 5}, {4, 6}}];
vl = VertexList[g]
aM = AdjacencyMatrix[g];
vLM = aM[[VertexIndex[g, 1]]];
Pick[vl, vLM, 0];
VertexList[g]

Output

{1, 2, 3, 4, 5, 6}  
{1, 5, 6}

You can solve the error by making a copy of the vertexlist yourself. This can be done by using Append and Delete as follows

ue = UndirectedEdge;
g = Graph[ue @@@ {{1, 2}, {2, 3}, {1, 3}, {1, 4}, {4, 5}, {4, 6}}]
vl = Delete[Append[VertexList[g], 0], -1]
aM = AdjacencyMatrix[g];
vLM = aM[[VertexIndex[g, 1]]];
Pick[vl, vLM, 0];
v1 = VertexList[g]

Output

{1, 2, 3, 4, 5, 6}  
{1, 2, 3, 4, 5, 6}

So in your case you could do

copy[list_] := Delete[Append[list, 0], -1];

g
listDegree = VertexDegree[g]

Block[
 {punchingBag},
 punchingBag = copy[VertexList[g]]; 
 nodeMaxDegree = 
  Pick[punchingBag, listDegree, Max[VertexDegree[g]]][[1]]; 
 aM = AdjacencyMatrix[g]; vLM = aM[[VertexIndex[g, nodeMaxDegree]]]; 
 nN = Pick[punchingBag, vLM, 0];
 ]
vl = VertexList[g]

Another (probably better) solution would be to use Developer`ToPackedArray on VertexList[g], this avoids the strange behaviour from occurring altogether.

There are alternatives to the Pick function to do the same job (in this case find all the vertices that aren't neighbor to a given vertex?)? — Adam Reith, Mar 27 '14 at 18:46
@AdamReith sure! Also you can probably prevent the error altogether. One moment — Jacob Akkerboom, Mar 27 '14 at 18:47

Bug with SparseArray selector in Pick

2 Answers2

Linked