Automating Esc [[ Esc formatting?

Question

Is it possible to program the Front End to automatically format double square brackets without having to type Esc[[Esc each time? It's awful to have to type Esc four times for each Part expression, and even more annoying to visually parse the unformatted double brackets.

See also this entry in MathGroup archive: adding a keyboard shortcut for double brackets

I edited the KeyEventTranslations.tr file to add my own shortcuts. — Silvia, May 06 '12 at 02:00
Assuming you are under win, open the file in a text editor, add a line like
**Item[KeyEvent["[", Modifiers -> {Control}],FrontEndExecute[{FrontEnd`NotebookWrite[FrontEnd`InputNotebook[],"\[LeftDoubleBracket]", After]}]]** — Silvia, May 06 '12 at 02:13

score 53 · Accepted Answer · edited May 23 '17 at 12:35

53

Some approaches are discussed in this question on StackOverflow. Original references to these go to Szabolcs's webpage and a MathGroup posting by Mr.Wizard.

To summarize, you copy the file: $InstallationDirectory/SystemFiles/FrontEnd/TextResources/Macintosh/KeyEventTranslations.tr to $UserBaseDirectory/ (with the same directory tree) and add the following modifications after EventTranslations[{ in the file:

Item[KeyEvent["[", Modifiers -> {Control}],
        FrontEndExecute[{
            FrontEnd`NotebookWrite[FrontEnd`InputNotebook[],
                "\[LeftDoubleBracket]", After]
        }]],
Item[KeyEvent["]", Modifiers -> {Control}],
        FrontEndExecute[{
            FrontEnd`NotebookWrite[FrontEnd`InputNotebook[],
                "\[RightDoubleBracket]", After]
        }]], 
Item[KeyEvent["]", Modifiers -> {Control, Command}],
        FrontEndExecute[{
            FrontEnd`NotebookWrite[FrontEnd`InputNotebook[],
                "\[LeftDoubleBracket]", After],
            FrontEnd`NotebookWrite[FrontEnd`InputNotebook[],
                "\[RightDoubleBracket]", Before]
        }]],

These provide the following shortcuts:

〚 using Ctrl+[
〛 using Ctrl+]
〚〛 using Ctrl+Cmd+]

Replace Command with Alt for Windows/Linux and modify the paths above accordingly.

You can also try Andrew Moylan's suggestion, in the same post, but I haven't tried it.

edited May 23 '17 at 12:35

Community

1

answered May 06 '12 at 02:15

rm -rf

88,781
21
293
472

this is a nice trick, however I couldn't get it to work on a German keyboard. Since the [ and ] keys events are generated by pressing Alt-Gr 8 and Alt-Gr 9 it seems Mathematica does not catch the KeyEvent correctly. Switching over to EN keyboard design works however... Any ideas how to capture Alt-Gr? – Rainer Oct 27 '13 at 10:54
@xslittlegrass It's not a good idea to modify those files, as they can be overwritten by a new version (if you're in the habit of just having the current version). There might be something else going on with your setup if the above doesn't work. – rm -rf May 13 '14 at 00:38
On my Windows 7 (64 bit) computer using Mathematica 9.0.0.0, I did not need to replace Command with Alt. The code works as written without modification. – Carl Morris Aug 12 '14 at 20:49
@Rainer It seems Alt-Gr is Command+Alt. I tried to get these commands working with this knowledge with no success. But try typing Shift+Alt+Alt-Gr+9 and you'll get (). These are called "MatchingParentheses" and in the MenuSetup.trlinked with MenuKey[")", Modifiers->{"Command"}. Which would beShift+Alt+9 on a german keyboard. Unfortunately MatchingBraces {} and MatchingBrackets [] dont work. – Phab Nov 25 '14 at 13:44
@R.M. does this work for you on v11.1? – glS Apr 03 '17 at 11:18
@glS I don't have 11.1 – rm -rf Apr 04 '17 at 04:20
@R.M. well, it seems to not work for me, but I wasn't sure if it was just me. May it be that something changed in the latest versions that broke this? – glS Apr 04 '17 at 15:49

score 12 · Answer 2 · edited May 06 '12 at 05:25

Edit the KeyEventTranslations.tr file in a plain text editor by adding the following definitions to the first section of the file:

EventTranslations[{

(* Custom shortcuts *)
Item[KeyEvent["[",Modifiers->{Control}],
    FrontEndExecute[{FrontEnd`NotebookWrite[FrontEnd`InputNotebook[],
    "[\[SelectionPlaceholder]]"],FrontEndToken["MovePreviousPlaceHolder"]}]],

Item[KeyEvent["]",Modifiers->{Control}],
    FrontEndExecute[{FrontEnd`NotebookWrite[FrontEnd`InputNotebook[],
    "\[LeftDoubleBracket]\[SelectionPlaceholder]\[RightDoubleBracket]"],
    FrontEndToken["MovePreviousPlaceHolder"],FrontEndToken["MovePreviousPlaceHolder"]}]],

(* Evaluation *)

Note that these shortcuts are set up to use the "Control" modifier to insert a template for pairs of single/double brackets.

These no longer work in 11.2 on windows – Nasser Dec 19 '17 at 01:39 — Nasser, Dec 19 '17 at 01:39

Automating Esc [[ Esc formatting?

2 Answers2

Linked