24

Bug introduced in 8 or earlier and persisting through 12.0

I'm trying to plot a graph wit a logarithmic y-axis. Since I'm exporting the graph to pdf and later printing it, I want to manually set the frame and tick marks to a reasonable thickness. However the logarithmic tick marks do not change their thickness.

(Note: I exaggerated the thickness of the tick marks on purpose to illustrate my point.)

LogPlot[x^2, {x, 1, 3}, PlotStyle -> Red, Frame -> True,
FrameStyle -> Directive[Black, AbsoluteThickness[2]],
FrameTicksStyle -> Directive[Black, AbsoluteThickness[2]]
]

Plot with Logarithmic Ticks

I'm working with Mathematica 10 on Mac OS X 10.9.4. In Mathematica Version 9 the logarithmic tick marks change their thickness as expected.

Can anyone reproduce this behavior? Is this a bug or did the FrameTicksStyle change in Mathematica 10?

Ray Shadow
  • 7,816
  • 1
  • 16
  • 44
theDriver
  • 634
  • 5
  • 13

2 Answers2

29

Reproduced in v.10.0.0 under Win7 x64. In versions 8.0.4 and 9.0.1 the behavior differs in details but the bug is also present: only major logarithmic frame ticks change their thickness, but not minor ticks.

Let us elaborate. First of all, in v.10 the logarithmic tick specifications are generated dynamically when the plot is rendered by the FrontEnd by calling Charting`ScaledTicks and Charting`ScaledFrameTicks:

LogPlot[x^2, {x, 1, 3}, Frame -> True];
Options[%, FrameTicks]    

{FrameTicks -> {{Charting`ScaledTicks[{Log, Exp}], 
    Charting`ScaledFrameTicks[{Log, Exp}]}, {Automatic, Automatic}}}

Here is what these functions return (I have shortened the output for readability):

Charting`ScaledTicks[{Log, Exp}][1, 10]

{{2.30259, 10, {0.01, 0.}, {AbsoluteThickness[0.1]}}, 
{4.60517, 100, {0.01, 0.}, {AbsoluteThickness[0.1]}}, 
{6.90776, 1000, {0.01, 0.}, {AbsoluteThickness[0.1]}}, 
{9.21034, Superscript[10,4], {0.01, 0.}, {AbsoluteThickness[0.1]}}, 
{0., Spacer[{0, 0}], {0.005, 0.}, {AbsoluteThickness[0.1]}}, 
{0.693147, Spacer[{0, 0}], {0.005, 0.}, {AbsoluteThickness[0.1]}}}

It is clear that the thickness specifications are already included and have higher priorities than the FrameTicksStyle directive. That is the reason why the latter has no effect.

So this behavior reflects inconsistent implementation of Charting`ScaledTicks and Charting`ScaledFrameTicks which should NOT include styling into the tick specifications they generate. It is a bug.

Here is a function fixLogPlot which fixes this:

fixLogPlot[gr_] := 
  Show[gr, FrameTicks -> {{# /. _AbsoluteThickness :> (## &[]) &@*
       Charting`ScaledTicks[{Log, 
         Exp}], # /. _AbsoluteThickness :> (## &[]) &@*
       Charting`ScaledFrameTicks[{Log, Exp}]}, {Automatic, 
      Automatic}}];

fixLogPlot@
 LogPlot[x^2, {x, 1, 3}, Frame -> True, 
  FrameTicksStyle -> Directive[Black, AbsoluteThickness[2]]]

plot

UPDATE

Here is universal fix for version 10 which works for all types of log plots:

fixLogPlots[gr_] := 
 gr /. f : (Charting`ScaledTicks | Charting`ScaledFrameTicks)[{Log, Exp}] :>
                                                   (Part[#, ;; , ;; 3] &@*f)

UPDATE 2

And here is universal fix for versions 8 and 9:

fixLogPlots[gr_] := gr /. f : (Ticks | FrameTicks -> _) :> (f /. _Thickness :> (## &[]))
Alexey Popkov
  • 61,809
  • 7
  • 149
  • 368
  • Great elaboration of the problem. (In my personal opinion this is a clearly bug.) I'm wondering if there is a way to overcome the problem and change the thickness of the logarithmic tick without having to manually override the ticks with my one values. – theDriver Aug 15 '14 at 11:45
  • 1
    Added a workaround. – Alexey Popkov Aug 15 '14 at 13:16
  • @AlexeyPopkov Well, not entirely. It fixes ListLogLogPlot and LogLogPlot, but one cannot then do Show and combine them. – Carl Apr 02 '17 at 06:15
  • @Carl Can you give an example? It works for me. – Alexey Popkov Apr 02 '17 at 06:26
  • @AlexeyPopkov There is a lot of code, and, I do not own the data. Suggestions as to what to show, and how to show it, would be helpful. – Carl Apr 02 '17 at 07:09
  • @AlexeyPopkov, It does not work in Mathematica 11.1.0. ,May I know whether you have some fix there? – TM90 Apr 30 '17 at 22:38
  • @TM90 It works for me with version 11.1.1 on Windows 7 x64. Can you give an example where it fails? – Alexey Popkov May 01 '17 at 05:18
  • (+1) Got it to work by combining plots within a single ListLogLogPlot. Could not figure out how to use with Show. – Carl Mar 02 '19 at 11:45
  • @Carl It works for me, try: fixLogPlots@Show[LogPlot[x^2,{x,1,3},Frame->True,FrameTicksStyle->Directive[Black,AbsoluteThickness[2]]],ListLogPlot[Table[{x,x^2},{x,1,3,.1}]]] (checked with Mathematica 11.3). – Alexey Popkov Mar 03 '19 at 17:52
2

This seems to be fixed in 12.1.1:

screenshot of notebook

imas145
  • 988
  • 6
  • 19