Problems with PlotStyle in mathematica 10

Question

Bug introduced in 9.0 and fixed in 10.0.1

---

The simplest way to ask is to post the code of what I'm doing:

ListPlot[{Table[x, {x, 1, 10, 1}], Table[x + x^2, {x, 1, 10, 1}]}, 
  PlotMarkers -> None, PlotRange -> All, 
  PlotStyle -> {
   {Thickness[.005], Dashing[{.03, .015}], ColorData[1, 1]},   
   {Thickness[.0075], ColorData[1, 1]}},
  Joined -> True
]

When I did this in Mathematica 8, the first line was dashed and the second line was a thicker, solid line of the same color:

Now having upgraded to Mathematica 10 and the second line is also dashed, same as the first:

It seems that if I leave out an explicit Dashing[{x,x}] command, the curve inherits the last dashing style, rather than go back to the default! How do I get the second curve to be solid? More importantly, what has changed in Mathematica 10 that causes this?

Obviously, my real task is more complicated than this, but this will reproduce the behavior.

Answer 1

Your code is missing a bracket and it should be a ListLinePlot. After correcting those errors I get one solid and one thinner dashed line just like you wanted.

ListLinePlot[{Table[x, {x, 1, 10, 1}], Table[x + x^2, {x, 1, 10, 1}]},
  PlotMarkers -> None, PlotRange -> All, 
  PlotStyle -> {{Thickness[.005], Dashing[{.03, .015}], 
    ColorData[1, 1]}, {Thickness[.0075], ColorData[1, 1]}}]

Answer 2

This is fixed in 10.0.1. The output from ListPlot now matches that from ListLinePlot.

---

You are supposed to use ListLinePlot for line charts since Mathematica 6, which as paw illustrated handles this correctly.

The behavior of ListPlot is due to the structure of the Graphics object that is produced:

g1 = ListPlot[{Table[Sin[i], {i, 25}], Table[Cos[i], {i, 25}]}, Joined -> True, 
   PlotStyle -> {{Red, Thick, Dashed}, {Blue, Thin}}];

g1[[1]] /. (h : Hue | Line | Directive)[___] :> h[]

{{}, {Hue[], Directive[], Line[], Hue[], Directive[], Line[]}, {}}

Observe that the body is a single list of the form {color, directive, line, color, directive, line, ...}.
This has the implication that any earlier directive which is not expressly overridden by a later one will affect not only the Line immediately following it but all the rest. Colors do not appear to persist in this fashion only because Mathematica automatically provides these styles.

Now compare the output of ListLinePlot:

g2 = ListLinePlot[{Table[Sin[i], {i, 25}], Table[Cos[i], {i, 25}]}, 
   PlotStyle -> {{Red, Thick, Dashed}, {Blue, Thin}}];

g2[[1]] /. (h : Hue | Line | Directive)[___] :> h[]

{{}, {{{}, {}, {Hue[], Directive[], Line[]}, {Hue[], Directive[], Line[]}}}, {}}

Note the structure {{color, directive, line}, {color, directive, line}, ...}. This has the effect of localizing the styling directives to a specific line; they will not persist across multiple lines.

I suppose either behavior could be intentional but I find the latter less surprising, and therefore better.

---

The version 10.0.0 behavior has been confirmed as a bug.

1. This is a bug, not a typo. – rcollyer (WRI employee)

2. I reported the behavior of Dashed in ListPlot to WRI tech support, and in their reply they agreed it was a bug. Should the question, therefore, be tagged with the bugs tag? – m_goldberg

Answer 3

As per Documentation Dashing[{}] "specifies that lines should be solid". Hence

ListPlot[{Table[x, {x, 1, 10, 1}], Table[x + x^2, {x, 1, 10, 1}]},
 PlotMarkers -> None,
 PlotRange -> All,
 PlotStyle -> {
   {Dashing[{.03, .015}], Thickness[.005], ColorData[1, 1]},
   {Dashing[{}], Thickness[.0075], ColorData[1, 1]}},
 Joined -> True]

You have the same "problem" with V9.

Where are the bugs ? I just tried to remove this tag, but it stays.