Automatically execute command after save

Question

I want to run some code automatically after saving my notebook. Is there a $ variable or setting for this?

score 21 · Accepted Answer · edited Oct 17 '15 at 12:21

21

Yes, it can be easily implemented with FrontEndExecute, e.g.:

SetOptions[EvaluationNotebook[], NotebookEventActions -> 
  {{"MenuCommand", "Save"} :> Print["HEY"], PassEventsDown -> True}];

You can insert any code instead of Print command

Edit

Above code executes Print["HEY"] before saving the notebook, because you catch the event at the beginning, do some work and release it back to program with PassEventsDown.

To evaluate some code after saving - one has to handle full event manually. The simplest would be just remove PassEventsDown and instead of Print["HEY"] write (NotebookSave[]; Print[123]):

SetOptions[EvaluationNotebook[], NotebookEventActions ->
    {{"MenuCommand", "Save"} :> (NotebookSave[]; Print[123])}]

Unfortunately, this will "intercept" also saving event triggered by "Save As" command and it will always save file with its old name even if we change name in "Save As" window.

edited Oct 17 '15 at 12:21

jkuczm

15,078
2
53
84

answered Nov 21 '14 at 15:03

funnyp0ny

1,905
14
21

1

@funnypony If you replace "HEY" with NotebookFileName[] and try to save notebook as file with different name, you'll get old file name, or $Failed if notebook was not saved before. So it seems that this code is evaluated before saving the notebook. Is there a way to really evaluate code after notebook was saved? – jkuczm Dec 07 '14 at 17:04
1

@jkuczm yes it saves after Print just because you catch the event at the beginning, do some work and release it back to pogram with passeventsdown. To evaluate some code after saving - one has to handle full event manually. The simplest would be just remove passeventdown and instead Print[] write {NotebookSave[]; Print[123]} but! it will work only with saved notebooks, it can't handle SaveAs command.. Unfortunately, I don't know how to catch only SaveAs command.. – funnyp0ny Dec 08 '14 at 13:48
@funnypony +1 I found your answer useful nonetheless. – jkuczm Dec 08 '14 at 23:04

score 3 · Answer 2 · edited Apr 13 '17 at 12:55

Adding to @funnypony's answer, if we really need to execute code after saving a notebook and we don't want to break "Save As" functionality, then we can use following workaround.

In "Save" action use NotebookSave[] and code we want to execute after it.
In "SaveRename" action put code assigning new "Save" notebook action. This new "Save" action will restore previous NotebookEventActions and pass events down.

Whole thing would look like this:

$notebookEventActions = {
{"MenuCommand", "Save"} :> (
    Print["before Save: ", NotebookFileName[], " last modified: ",
        FileDate@NotebookFileName[]];
    NotebookSave[];
    Print["after Save: ", NotebookFileName[], " last modified: ",
        FileDate@NotebookFileName[]]
),
{"MenuCommand", "SaveRename"} :> (
    SetOptions[
        EvaluationNotebook[],
        NotebookEventActions -> {
            {"MenuCommand", "Save"} :>
                SetOptions[
                    EvaluationNotebook[],
                    NotebookEventActions -> $notebookEventActions
                    ],
                PassEventsDown -> True
            }
        ];
        NotebookSave[Interactive -> True]
    )
};

SetOptions[EvaluationNotebook[], NotebookEventActions -> $notebookEventActions]

Now using "Save" command will print "before Save: ..." text, then save notebook, then print "after Save: " text. Using "Save As" will work as if it was not modified at all.

Automatically execute command after save

2 Answers2

Edit

Linked

Related