Textures are not rendered in combined graphics

Question

p1 = Plot[x^2, {x, -2, 2}, PlotStyle -> {Thick, Black}]; 
p2 = Graphics3D[{EdgeForm[Black], Texture[p1], 
 Polygon[{{-2, 0, -1}, {2, 0, -1}, {2, 4, -1}, {-2, 4, -1}}, 
 VertexTextureCoordinates -> {{0, 0}, {1, 0}, {1, 1}, {0, 1}}], 
 Opacity[1]}, Lighting -> "Neutral", Boxed -> False];
squares = 
 Table[Graphics3D[{Opacity[.3], 
 Polygon[{{-Sqrt[y], y, 0}, {Sqrt[y], y, 0}, {Sqrt[y], y, 
 2 Sqrt[y]}, {-Sqrt[y], y, 2 Sqrt[y]}}]}, Boxed -> False], {y, 0, 4, .25}];
all = Show[Table[squares[[j]], {j, 1, 16}]];
Show[p2]
Show[p2, all]

results in this output for me:

However, for others (at least one of whom is a Mac user), indeed the p2 graphic shows up in the second result.

When I click on the cell bracket, and Save As... PDF, the result is

And finally, if I directly copy and paste the figure (rather than export), I get this:

enter image description here

I need some independent confirmation of if this a bug in the Windows 7 version of v8.0.4 and if you have any ideas for workarounds since I need a PDF version of the last figure for insertion into other docs. Thanks.

Please only use the tag [tag:bugs] if the unexpected behaviour is indeed confirmed by the community (see tag wiki). — István Zachar, Jul 02 '12 at 16:15
On my machine (Win7, Mathematica 8.0.4) the output in Mathematica is the first one, and I see the second image when I save it to PDF. — István Zachar, Jul 02 '12 at 16:55
@texasAUtiger No, it's missing in the PDF file. Notice that even exporting p2 along has the same problem. — b.gates.you.know.what, Jul 02 '12 at 16:55
@Ajasja: Actually the expected/desired result is a PDF version of the 4th image in my original post. So something is being lost in the conversion to PDF. — JohnD, Jul 02 '12 at 17:02
@b.gatessucks: Yes, that seems to isolate the problem, i.e. it is an issue with exporting the Textures graphic to PDF. — JohnD, Jul 02 '12 at 17:07
I can confirm I get the same problem with 8.0.4 on Windows 7. There seems to be a general problem with opacity and textures in 3D graphics - if I go to the documentation for Texture neither of the examples in the Generalizations & Extensions section work. — Simon Woods, Jul 02 '12 at 21:03
@SimonWoods Could you check this question and confirm if you seem to have the same problem as described there? — Sjoerd C. de Vries, Jul 02 '12 at 21:49
I am on 8.0.4. and Windows 7 - I get the same PDF (but not PNG) output but I think the first output is because the two Show statements are not in separate cells? In the notebook (and in PNG export) I get the nice-looking last graphic. Since the PDF and EPS versions are not vector graphics anyway, why not just export as PNG? — Verbeia, Jul 02 '12 at 22:48
@SimonWoods: Neither of those examples in that Texture documentation show up for me as they should. — JohnD, Jul 03 '12 at 04:50
@IstvánZachar It is indeed a bug, confirmed by John Fultz, see the link at the end of my posted answer. So I've taken the liberty of adding the bug tag again. — Jens, Jul 03 '12 at 05:23
Thanks @Jens! confirmed bug is a good bug, a dead bug is an even better bug. — István Zachar, Jul 03 '12 at 08:03
@texasAUtiger Are you referring in your comment to the same experience I reported here? — Sjoerd C. de Vries, Jul 03 '12 at 11:20
@SjoerdC.deVries, yes it's exactly the same problem as you describe. This is on Windows 7 64 bit, with an NVidia GTX 550 Ti graphics card. — Simon Woods, Jul 03 '12 at 19:40
@SjoerdC.deVries: Windows 7, 64 bit on Intel on Intel iCore i7-2760QM 2.4 ghz, NVidia NVS 4200M graphics card — JohnD, Jul 04 '12 at 01:57

score 7 · Accepted Answer · edited Apr 13 '17 at 12:55

This non-appearance of the texture is a known bug that also affects Macs. It can be fixed by providing as the Texture only the ImageData of the rasterized graphic. So you have to replace

Texture[p1]

by

Texture[ImageData@Rasterize[p1, "Image"]]

and then the texture will show up. I modified your definitions a little, in line with what I already said in this answer:

p1 = Plot[x^2, {x, -2, 2}, PlotStyle -> {Thick, Black}, 
   ImageSize -> 600];

p2 = Graphics3D[{EdgeForm[Black], 
    Texture[ImageData[
      Rasterize[p1, "Image", ImageResolution -> 120]]], Polygon[
     {{-2, 0, -1}, {2, 0, -1}, {2, 4, -1}, {-2, 4, -1}}, 
     VertexTextureCoordinates -> {{0, 0}, {1, 0}, {1, 1}, {0, 1}}
     ],
    Opacity[1]},
   Lighting -> "Neutral",
   Boxed -> False,
   ImageSize -> 600
   ];

squares = 
  Graphics3D[
   Table[{Opacity[.3], 
     Polygon[{{-Sqrt[y], y, 0}, {Sqrt[y], y, 0}, {Sqrt[y], y, 
        2 Sqrt[y]}, {-Sqrt[y], y, 2 Sqrt[y]}}]}, {y, 0, 4, .25}], 
   Boxed -> False, ImageSize -> 600];

all = Graphics3D[{p2[[1]], squares[[1]]},
  Lighting -> "Neutral",
  Boxed -> False,
  ImageSize -> 600]

Note I added ImageResolution to the Rasterize command to try and make the resulting texture look a little smoother.

The resulting file after Export["file.pdf", all] is here:

pdf

Edit

A reference for this bug fix is this MathGroup discussion.

This does produce the desired result in the exported PDF, but the output of the code in Mathematica still doesn't show the bottom Texture graphic for me. (However, my main concern was the PDF.) — JohnD, Jul 03 '12 at 14:52

Textures are not rendered in combined graphics

1 Answers1

Linked