Bug in MovingMap (breaking change between version 10.1 and 10.0.2)?

Question

The MovingMap window spec has been changed between version 10.1 and 10.0.2.

Version 10.0.2

MovingMap[h, {a, b, c, d, e, f}, 2]
(* {h[{a, b}], h[{b, c}], h[{c, d}], h[{d, e}], h[{e, f}]} *)

Here we get a moving window of 2 items as expected.

Version 10.1

MovingMap[h, {a, b, c, d, e, f}, 2]
(* {h[{a, b, c}], h[{b, c, d}], h[{c, d, e}], h[{d, e, f}]} *)

In 10.1 the same statement returns a moving window of 3 items.

Is there a way to have a bug marked as urgent. I have a few functions in a package that I made in 10.0.2 that I am using in 10.1 that use MovingMap and direct uses scattered about in notebooks.

I think all the other "moving" functions should be testing as well.

Update on outcome

The short story is that the change was accidentally omitted from 10.1 release notes which lead to it being interpreted as a bug (it is a breaking change but not a bug). Below in there is a response (unofficial) in one of the comments from a WRI employee that states WRI is looking into how this happened in order to prevent this in future. And the beat goes on.

---

Answer 1

This is not a bug. MovingMap underwent a significant design change in 10.1. Please consult the documentation for details on the new specification. For your particular example, you would now do

MovingMap[h, {a, b, c, d, e, f}, Quantity[2,"Events"]]

Answer 2

MovingMap as of 10.1 specifies windows by their absolute length. Since lists are treated as implicit time-series with (zero-based) integer index as time, window size of 2 means that the windowing function sees $\{x_{n-2}, x_{n-1}, x_n\}$. This is the only window specification that admits a clean generalization to irregular time series.

Using Quantity[2,"Events"] specifies possibly variable size window that always includes 2 events (points).

In[26]:= tvPairs = 
 Table[{t, x[t]}, {t, Accumulate[PadLeft[{}, 6, {1, 3}]]}]

Out[26]= {{1, x[1]}, {4, x[4]}, {5, x[5]}, {8, x[8]}, {9, x[9]}, {12, 
  x[12]}}

In[27]:= MovingMap[f, tvPairs, 2]

Out[27]= {{4, f[{x[4]}]}, {5, f[{x[4], x[5]}]}, {8, f[{x[8]}]}, {9, 
  f[{x[8], x[9]}]}, {12, f[{x[12]}]}}

In[28]:= MovingMap[f, tvPairs, Quantity[2, "Events"]]

Out[28]= {{4, f[{x[1], x[4]}]}, {5, f[{x[4], x[5]}]}, {8, 
  f[{x[5], x[8]}]}, {9, f[{x[8], x[9]}]}, {12, f[{x[9], x[12]}]}}

[Added]

The legacy behavior, can also be recovered using Method->"Legacy" option.

In[29]:= MovingMap[f, tvPairs, 2, Method -> "Legacy"]

Out[29]= {{4, f[{x[1], x[4]}]}, {5, f[{x[4], x[5]}]}, {8, 
  f[{x[5], x[8]}]}, {9, f[{x[8], x[9]}]}, {12, f[{x[9], x[12]}]}}

[/Added]

---

Notice that MovingMap has become much more powerful in 10.1. It is now possible to align windows at specific positions. For instance, consider a daily closing values of the Starbucks stocks from the beginning of 2002 and through the end of 2014.

sb = TimeSeries[FinancialData["SBUX", {{2002}, {2014}}]];

The following computes past monthly median weekly starting from Fri, Feb 1 of 2012:

MovingMap[Median, sb, {"Month", 
  Right, {"Feb 1 2002", Automatic, "Week"}}, None]

This was not easy to do in v9.

Answer 3

I would echo's @Kuba comments about most of the examples being for Time related windows, I would also note that there is an explicit example in the help that returns a window size of 3, so it could be an indication that its deliberate.

MovingMap[Mean, {x1, x2, x3, x4, x5}, 2]

(* {1/3 (x1 + x2 + x3), 1/3 (x2 + x3 + x4), 1/3 (x3 + x4 + x5)} *)

There is a workaround that seems to have no ill effects though.

MovingMap[h, {a, b, c, d, e, f}, Quantity[2, "Events"]]

(* {h[{a, b}], h[{b, c}], h[{c, d}], h[{d, e}], h[{e, f}]} *)