Is there a way to outline text?

Question

If I have:

Graphics[
  {Red, EdgeForm[Directive[White, Thick]], 
  Inset[Style[Text@"Hi!", 44], {0, 0}]}, Background -> Black
]

I unfortunately get:

Which as you can see does not have a thick white outline. Is there a way to get around this since EdgeForm clearly does not work?

By the way, I would rather NOT delve into making a larger, white "Hi" and then putting the red one on top. That's just not elegant.

MMA 8.0.1 for students
OS Windows 7 64-bit

there was a question on Stack Overflow strongly related to this one. — Dr. belisarius, Jul 13 '12 at 20:02
Oh, I did not know. I sort of gave up googling for MMA help since there usually isn't anything except for stuff here. Also, I can't find it. — VF1, Jul 13 '12 at 20:04

Vitaliy Kaurov · Accepted Answer · 2012-07-13T20:32:08.463

35

Import text as a FilledCurve in graphics, using PDF as an intermediate format. Below are modified examples from Documentation Center:

text = First[First[ImportString[ExportString[Style["Hi", Italic, FontSize -> 24, 
FontFamily -> "Times"], "PDF"], "PDF", "TextMode" -> "Outlines"]]];

Outline fonts using different edge and face forms:

Graphics[{EdgeForm[Directive[White, Thick]], Red, text},
Background -> Black, PlotRange -> {{-5, 25}, {-0, 20}}]

enter image description here

3D text effect:

Graphics[{EdgeForm[Opacity[0.5]], Table[{ColorData["TemperatureMap"][t], 
    Translate[text, 4 {-t, t}]}, {t, 0, 1, 1/10}]}, ImageSize -> Medium]

enter image description here

edited Jul 13 '12 at 20:32

answered Jul 13 '12 at 20:25

Vitaliy Kaurov

73,078
9
204
355

Vitaliy, very nice! – alancalvitti Jul 13 '12 at 20:36
3

Cool. But is this really the only way? It's a bit slow to convert it to a curve and I need to display the graphics quickly in my game. The text changes based on the game's statistics, so precomputing's not an option... – VF1 Jul 13 '12 at 20:55
1

@vlad you can do the curve conversion on a letter basis in advance. You'd need a kerning table as well, but that shouldn't be too difficult to generate. – Sjoerd C. de Vries Jul 13 '12 at 21:57
@vlad, the idea by SjoerdC.deVries is indeed a good solution. Otherwise you're risking to end up "delving into making a larger, white "Hi" and then putting the red one on top" ;-) – Vitaliy Kaurov Jul 13 '12 at 22:02
Interestingly, the option "TextMode" -> "Outlines" can be omitted, as I observed in this answer which also shows another use for outlined characters – Jens Jul 13 '12 at 22:33
5

While clever it strikes me as really quite atrocious to have to do an Export->Import to get the outlines. I keep hoping someone will find or share an internal function that does this. :-/ – Mr.Wizard Jul 14 '12 at 01:10
Congrats on 10k! :) – rm -rf Jul 18 '12 at 18:33
@R.M Thanks! Nice of you to let me know ;-) – Vitaliy Kaurov Jul 18 '12 at 18:56
3

This is now outdated, now text = First[First[ImportString[ExportString[Style["Hi", Italic, FontSize -> 24, FontFamily -> "Times"],"PDF"], {"PDF", "PageGraphics"},"TextMode" -> "Outlines"]]]; should be used as per the documentation. – bRost03 Jul 30 '21 at 22:50

Jens · Answer 2 · 2012-07-14T06:17:46.607

An important issue in the question seems to be that of speed. So as Sjoerd suggested, I wrote a solution that pre-outlines all the characters in a reasonable range of ASCII characters, and then does the replacements on an arbitrary string. The characters are stored in a table ascii, and their graphic replacements in asciiGraphics. I then define the replacement rule (rule) which is part of the function makeText:

ascii = CharacterRange[" ", "z"]

(*
==> {" ", "!", "\"", "#", "$", "%", "&", "'", "(", ")", "*", \
"+", ",", "-", ".", "/", "0", "1", "2", "3", "4", "5", "6", "7", "8", \
"9", ":", ";", "<", "=", ">", "?", "@", "A", "B", "C", "D", "E", "F", \
"G", "H", "I", "J", "K", "L", "M", "N", "O", "P", "Q", "R", "S", "T", \
"U", "V", "W", "X", "Y", "Z", "[", "\\", "]", "^", "_", "`", "a", \
"b", "c", "d", "e", "f", "g", "h", "i", "j", "k", "l", "m", "n", "o", \
"p", "q", "r", "s", "t", "u", "v", "w", "x", "y", "z"}
*)


asciiGraphics = 
  First@ImportString[
      ExportString[Style[#, FontFamily -> "Times", FontSize -> 44], 
       "PDF"], "TextOutlines" -> True] & /@ ascii;

rule = Dispatch[Thread[ascii -> asciiGraphics]];


Clear[makeText];
Options[makeText] = {"OutlineThickness" -> 1, "OutlineColor" -> White,
   "Color" -> Red}; 
makeText[string_, OptionsPattern[]] := 
 DisplayForm[
  Row[Characters[string] /. rule] /. 
   FilledCurve[
     x__] :> {EdgeForm[{AbsoluteThickness[
        OptionValue["OutlineThickness"]], 
       OptionValue["OutlineColor"]}],
     OptionValue["Color"],
     FilledCurve[x]
     }
  ]

The argument to makeText is the string to be rendered as outlined text. The thickness of the outlines is specified by the option "OutlineThickness". The other two options are "OutlineColor" and "Color" (of the filled areas).

The following is a demo - you win the game by sliding the slider to the right...

Manipulate[
 Style[Pane[
   makeText["Player 1 has " <> ToString[Floor[p]] <> " points", 
    "OutlineThickness" -> .7], ImageSize -> 360], 
   Background -> Black,
   Magnification -> 3
 ], {p, 0, 1000}]

manipulate

Edit

In response to the question in the comment:

By using Dispatch you can eke out a faster timing, and my focus was on getting fast execution. It won't matter much if you're dealing only with a short string. But if you're trying to translate a long text into outlined characters, the replacement is sped up when you first apply Dispatch to the rule.

By using Dispatch you can eke out a faster timing, and my focus was on getting fast execution. It won't matter much if you're dealing only with a short string. But if you're trying to translate a long text into outlined characters, the replacement is sped up when you first apply Dispatch to the rule. — Jens, Jul 14 '12 at 04:08
@Vlad Speed is the biggest hurdle when doing anything interactive in Mathematica - I hope you'll be able to overcome that for your game... — Jens, Jul 14 '12 at 04:09

Szabolcs · Answer 3 · 2015-07-16T07:49:18.320

12

In version 10, we can bypass exporting to PDF and re-importing and can outline text directly using region discretization functions. This is shown in the documentation of BoundaryDiscretizeGraphics.

reg = BoundaryDiscretizeGraphics[Text[Style["R", FontFamily -> "Cambria"]], _Text]

Mathematica graphics

The region can then be converted back to graphics, and the FilledCurve extracted.

WARNING: I just realized that the following line will often crash the kernel with 10.1.0 on OS X! Proceed with caution!

Cases[Normal@Show[reg], _FilledCurve, Infinity]

Normal is for getting rid of GraphicsComplex inside the resulting Graphics object.

If there is a direct way to go from a BoundaryMeshRegion to a FilledCurve, without having to use Show, please let me know!

edited Jul 16 '15 at 07:49

answered Jul 16 '15 at 07:43

Szabolcs

234,956
30
623
1,263

weird, RegionBoundary[reg]//FullForm shows the polygon data, but there is no evident way to programmatically extract it. Apply doesn't work.. on a MeshRegion – george2079 Jul 16 '15 at 19:31
I'm amazing you can discretize a word,and how do you find the pattern of "_Text"??Do you help me discretize a Tube?Such as "Graphics3D[Tube[{{0, 0, 0}, {1, 1, 1}}, .1]]"? – yode Sep 25 '15 at 18:35
@yode It's in the documentation I linked to, almost this very example. I really don't know more than what's there. – Szabolcs Sep 25 '15 at 20:45
If you provide character i, it would generate Polygon instead of FilledCurve. – kh40tika Dec 20 '16 at 11:07
@user1950580 I've done this now where I search for either of them. It suffices to get all the cases I've tried. – b3m2a1 Mar 17 '17 at 05:11

score 3 · Answer 4 · answered Jul 03 '23 at 00:04

3

You can do

Graphics[{Haloing[White], Text[Style["Hi", 40, Red]]}, 
 Background -> Black]

Haloing was introduced in 13.3

answered Jul 03 '23 at 00:04

Peter Burbery

1,695
4
15

Everett You · Answer 5 · 2023-02-10T21:23:19.613

A quick and dirty way to bypass exporting to PDF and re-importing is to put the text on a background of the thickened text, and the text thickening can be achieved by the trick of translating the text around by a small amount.

For example, we have a text to outline:

text = Text[Style["Hello!", Italic, FontSize -> 24]];
Graphics[{White, text}, Background -> Black, PlotRange -> 1, ImageSize -> 100]

We can use Translate to move the text around and CirclePoints to generate a set of uniformly distributed translation vectors along different directions. By dragging the text around, we effectively thicken the text.

Graphics[{{White, Translate[text, 0.02 #] & /@ CirclePoints[32]}}, 
 Background -> Black, PlotRange -> 1, ImageSize -> 100]

Now we can put the original text on top of this thickened background, which effectively creates an outline effect for the text.

Graphics[{{White, Translate[text, 0.02 #] & /@ CirclePoints[32]}, text}, 
 Background -> Black, PlotRange -> 1, ImageSize -> 100]

One may also adjust the thickness of the outline by changing the amount of translation for the background text.

Graphics[{{White, Translate[text, 0.05 #] & /@ CirclePoints[32]}, text}, 
 Background -> Black, PlotRange -> 1, ImageSize -> 100]

This method is much faster than the PDF export-import and the BoundaryDiscretizeGraphics methods. It applies to any text that can be displayed by the Text method without worrying about breaking text into characters and patching them together again (for example, preserving the spacing between characters in a row and between multiple lines can be painful).

Is there a way to outline text?

5 Answers5

Linked

Related