Why are my plots displaying behind the axes?

Question

I need to create graphs with light gray axes and black lines. All of my plots display behind the axes. How can I make the plots display over the axes?

Plot[2 x - 2, {x, -10, 10}, PlotRange -> {{-10, 10}, {-10, 10}},    
    PlotStyle -> Directive[Black, AbsoluteThickness[2]], ImageSize -> 300, 
    AxesStyle -> Directive[RGBColor[.8, .8, .8], AbsoluteThickness[2]], AspectRatio -> 1]

This post by Verbeia might also be of interest. – user1066 Jun 13 '13 at 09:45 — user1066, Jun 13 '13 at 09:45

J. M.'s missing motivation · Answer 1 · 2015-06-02T16:04:06.390

57

The cure is ~~undocumented, unfortunately~~ now documented, as of version 10. Try adding Method -> {"AxesInFront" -> False}, like so:

Plot[2 x - 2, {x, -10, 10}, PlotRange -> {{-10, 10}, {-10, 10}}, 
     PlotStyle -> Directive[Black, AbsoluteThickness[2]], ImageSize -> 300, 
     AxesStyle -> Directive[RGBColor[.8, .8, .8], AbsoluteThickness[2]], 
     AspectRatio -> 1, Method -> {"AxesInFront" -> False}]

plot with axes in front

There is also a corresponding "FrameInFront" option for frames, and "GridLinesInFront" for grid lines.

edited Jun 02 '15 at 16:04

answered Jun 13 '13 at 04:08

J. M.'s missing motivation

124,525
11
401
574

2

In version 10 it is documented on the Graphics documentation page under "Details and options". – Alexey Popkov May 31 '15 at 08:11
Nice to know that it's finally documented. Thanks! – J. M.'s missing motivation May 31 '15 at 08:12
I wonder if something similar exist for the tick labels. It seems there's no reference for that in the documentation. – abcd Sep 03 '20 at 23:47

score 13 · Answer 2 · edited May 31 '15 at 03:09

13

There can be another solution. FullGraphics can convert the axes to graphics primitives, then you can manipulate the order of layers by hand:

FullGraphics[
Plot[2 x - 2, {x, -10, 10}, PlotRange -> {{-10, 10}, {-10, 10}}, 
PlotStyle -> Directive[Black, AbsoluteThickness[2]], 
ImageSize -> 300, 
AxesStyle -> Directive[RGBColor[.8, .8, .8], AbsoluteThickness[2]],
AspectRatio -> 1]] /. Graphics[x_] :> Graphics[Reverse[x]]

Comment from rcollyer:

FullGraphics is spotty, so take care in its use.

edited May 31 '15 at 03:09

J. M.'s missing motivation

124,525
11
401
574

answered Jun 13 '13 at 04:13

mmjang

2,583
20
26

AxisInFront is simple and works well. I'll give that a good testing for my project. Good to know there is another option, especially for my own knowledge. Thank you! – lvames Jun 13 '13 at 10:40
@lvames Glad I can help. – mmjang Jun 13 '13 at 10:58
7

@lvames FullGraphics is spotty, so take care in its use. – rcollyer Jun 13 '13 at 16:20

score 4 · Answer 3 · edited Jun 14 '13 at 06:10

I found this useful, though a little ugly.

Overlay[{
 ListPlot[{0,0},PlotRange->{{-10,10},{-10,10}}, ImageSize->300, AspectRatio->1,
          AxesStyle->Directive[RGBColor[.8,.8,.8], AbsoluteThickness[2]]],
 Plot[2 x-2,{x,-10,10}, PlotRange->{{-10,10},{-10,10}}, Axes->False, AspectRatio->1,      
      PlotStyle->Directive[Black,AbsoluteThickness[2]],ImageSize->300]
}]

But you cannot directly save the image, you can select the cell and save selection as image.

enter image description here

Reverse the list in Overlay will get the result where black line behind the axes.

Why are my plots displaying behind the axes?

3 Answers3

Linked

Related