Identify the positions of a marker in sublists

Question

I have a list of lists from which I would like to pick out the positions of the number 1 and then print out these positions for each sublist.

I am having some trouble collecting what I am printing into a list / matrix / array though. Below is my list of lists and the commands by which I find the positions of the 1's and print them out. Thanks.

ZeroCrossings = {{0, 0, 1, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0}, {0, 0, 0, 1, 1,
   0, 0, 1, 0, 0, 0, 1, 1, 0}, {0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 0, 1, 1,
   0}, {0, 0, 0, 1, 0, 0, 0, 1, 0, 0, 1, 0, 1, 0}, {0, 0, 0, 1, 0, 0, 
  0, 0, 1, 0, 0, 1, 1, 0}, {0, 0, 0, 0, 1, 1, 0, 0, 0, 0, 1, 0, 0, 0}}
Do[Print[Flatten[Transpose[Position[ZeroCrossings[[t]], 1]]]], {t, 1,Length[ZeroCrossings]}]

{3,9}

{4,5,8,12,13}

{4,12,13}

{4,8,11,13}

{4,9,12,13}

{5,6,11}

Drop the Print and change Do to Table. Is this what you need? — Szabolcs, Jul 22 '14 at 04:11

score 5 · Accepted Answer · edited Apr 13 '17 at 12:55

5

Primarily you just need to use Table instead of Do and Print. Also you can simplify the code:

Table[Flatten @ Position[t, 1], {t, ZeroCrossings}]

{{3, 9}, {4, 5, 8, 12, 13}, {4, 12, 13}, {4, 8, 11, 13}, {4, 9, 12, 13}, {5, 6, 11}}

See Case #2 of: Alternatives to procedural loops and iterating over lists in Mathematica

It may be simpler to use Map:

Flatten @ Position[#, 1] & /@ ZeroCrossings

This is probably a bit advanced for you right now but you could also use:

GatherBy[Position[ZeroCrossings, 1], First][[All, All, 2]]

Or if you are using Mathematica 10:

GroupBy[Position[ZeroCrossings, 1], First -> Last] // Values

edited Apr 13 '17 at 12:55

Community

1

answered Jul 22 '14 at 04:12

Mr.Wizard

271,378
34
587
1,371

Like you said first, I used Table in place of Do to solve my problem.
Table[Flatten[Transpose[Position[ZeroCrossings[[t]], 1]]], {t, 1, Length[ZeroCrossings]}]

Thanks for your help and advice!
– CJ B Jul 22 '14 at 04:16

score 5 · Answer 2 · answered Jul 22 '14 at 04:16

Another approach:

ZeroCrossings = {{0, 0, 1, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0}, {0, 0, 0,
     1, 1, 0, 0, 1, 0, 0, 0, 1, 1, 0}, {0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 
    0, 1, 1, 0}, {0, 0, 0, 1, 0, 0, 0, 1, 0, 0, 1, 0, 1, 0}, {0, 0, 0,
     1, 0, 0, 0, 0, 1, 0, 0, 1, 1, 0}, {0, 0, 0, 0, 1, 1, 0, 0, 0, 0, 
    1, 0, 0, 0}};

Map[Last, GatherBy[Position[ZeroCrossings, 1], First], {-2}]

{{3, 9}, {4, 5, 8, 12, 13}, {4, 12, 13}, {4, 8, 11, 13}, {4, 9, 12,
13}, {5, 6, 11}}

score 4 · Answer 3 · answered May 09 '23 at 11:56

zeroCrossings = {{0, 0, 1, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0}, {0, 0, 0,
     1, 1, 0, 0, 1, 0, 0, 0, 1, 1, 0}, {0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 
    0, 1, 1, 0}, {0, 0, 0, 1, 0, 0, 0, 1, 0, 0, 1, 0, 1, 0}, {0, 0, 0,
     1, 0, 0, 0, 0, 1, 0, 0, 1, 1, 0}, {0, 0, 0, 0, 1, 1, 0, 0, 0, 0, 
    1, 0, 0, 0}};

Using SequencePosition:

SequencePosition[#, {1}] & /@ zeroCrossings /. {a_, a_} :> a

Using MapIndexed:

MapIndexed[If[#1 == 1, First@#2, Nothing] &, #] & /@ zeroCrossings

{{3, 9}, {4, 5, 8, 12, 13}, {4, 12, 13}, {4, 8, 11, 13}, {4, 9, 12,
13}, {5, 6, 11}}

kglr · Answer 4 · 2023-05-09T12:15:12.117

4

SparseArray[ZeroCrossings] @ "AdjacencyLists"

{{3, 9}, {4, 5, 8, 12, 13}, {4, 12, 13}, {4, 8, 11, 13}, 
 {4, 9, 12,  13}, {5, 6, 11}}

edited May 09 '23 at 12:15

answered May 09 '23 at 12:09

kglr

394,356
18
477
896

2

Now the matrix tag is finally justified after all these years. – Syed May 09 '23 at 12:51

score 4 · Answer 5 · answered Jul 22 '14 at 04:19

4

You can also use PositionIndex in Version 10

(PositionIndex /@ ZeroCrossings)[[All, 2]]

Gives:

{{3, 9}, {4, 5, 8, 12, 13}, {4, 12, 13}, {4, 8, 11, 13}, {4, 9, 12, 13}, {5, 6, 11}}

answered Jul 22 '14 at 04:19

RunnyKine

33,088
3
109
176

score 3 · Answer 6 · answered Dec 18 '23 at 10:10

3

Catenate @* Position[1] /@ ZeroCrossings

{{3, 9}, {4, 5, 8, 12, 13}, {4, 12, 13}, {4, 8, 11, 13}, {4, 9, 12, 13}, {5, 6, 11}}

answered Dec 18 '23 at 10:10

eldo

67,911
5
60
168

E. Chan-López · Answer 7 · 2023-12-18T10:21:50.283

Another possibility is to use Position at level -1 and SplitBy as follows:

Map[#[[All, 2]] &, SplitBy[Position[ZeroCrossings, 1, -1], First]]
({{3, 9}, {4, 5, 8, 12, 13}, {4, 12, 13}, {4, 8, 11, 13},
   {4, 9, 12, 13}, {5, 6, 11}})

Or using Count and PartitionRagged with Position at level -1:

#[[All, 2]] & /@ Internal`PartitionRagged[Position[#, 1, -1], 
Count[#, 1] & /@ #] &@ZeroCrossings
({{3, 9}, {4, 5, 8, 12, 13}, {4, 12, 13}, {4, 8, 11, 13},
   {4, 9, 12, 13}, {5, 6, 11}})

bmf · Answer 8 · 2023-12-20T02:52:19.847

1

Since @kglr suggested, already, the use of SparseArray here's another way to go about it

Flatten /@ 
 GatherBy[SparseArray[#]["NonzeroPositions"] & /@ ZeroCrossings, 
  First]

{{3, 9}, {4, 5, 8, 12, 13, 4, 12, 13, 4, 8, 11, 13, 4, 9, 12, 13}, {5, 6, 11}}

edited Dec 20 '23 at 02:52

answered Dec 18 '23 at 10:19

bmf

15,157
2
26
63

1

(+1) Nicely done, mate! :-) – E. Chan-López Dec 20 '23 at 03:27

Identify the positions of a marker in sublists

8 Answers8