Higher-order, nonlinear differential equation with Initial Values

Question

I tried to solve for an non-Hookean spring's motion, but the output from Mathematica is weird. It seems that there is inverse functions involved.

DSolve[{x''[t] + x[t]^3 == 0}, x[t], t]
Solve::ifun: Inverse functions are being used by Solve, so some solutions may not be found; use Reduce for complete solution information. >>
Out[1] = {{x[t] -> -I 2^(1/4) Sqrt[-(1/Sqrt[C[1]])] Sqrt[C[1]]
 JacobiSN[Sqrt[
 Sqrt[2] t^2 Sqrt[C[1]] + 2 Sqrt[2] t Sqrt[C[1]] C[2] + 
  Sqrt[2] Sqrt[C[1]] C[2]^2]/Sqrt[2], -1]}, {x[t] -> I 2^(1/4) Sqrt[-(1/Sqrt[C[1]])] Sqrt[C[1]] JacobiSN[Sqrt[Sqrt[2] t^2 Sqrt[C[1]] + 2 Sqrt[2] t Sqrt[C[1]] C[2] + 
  Sqrt[2] Sqrt[C[1]] C[2]^2]/Sqrt[2], -1]}}

If you try Reduce, Mathematica will then give you no output at all, which makes sense because the output is not an equality or inequality.

Also, I added initial values into DSolve, but I'm unable to obtain the answer.

In[1]:= DSolve[{x''[t] + x[t]^3 == 0, x[0] == d, x'[0] == 0}, x[t], t]
Solve::ifun: Inverse functions are being used by Solve, so some solutions may not be found; use Reduce for complete solution information. >>
DSolve::bvfail: For some branches of the general solution, unable to solve the conditions. >>
DSolve::bvfail: For some branches of the general solution, unable to solve the conditions. >>
Out[1]= {}

Answer 1

Well, that was easy:

Block[{Simplify = FullSimplify},
  DSolve[{x''[t] + x[t]^3 == 0, x'[0] == 0, x[0] == x0}, x[t], t]
  ] // FullSimplify
(*
  {{x[t] -> x0 JacobiCD[(t x0)/Sqrt[2], -1]}}
*)

DSolve uses Simplify to check the solution, and Simplify is not up to the task. So I used Block to replace it with FullSimplify, which will reduce the DE to True after DSolve substitutes the solution. Perhaps the Method option could be used, but there are no clues to how to use it.

Answer 2

Instead of giving screenshots you should copy your code and paste to this section properly. Ok, now I give a general approach to solve this problem.

In[1]:= DSolve[x''[t] + x[t] == 0, x[t], t]

Out[1]= {{x[t] -> C[1] Cos[t] + C[2] Sin[t]}}

Well, Mathematica does the job well and easy. Your problem shouldn't be that hard. Let's see:

In[2]:= eqn = x''[t] == -x[t]^3; sol = DSolve[eqn, x, t]

During evaluation of In[2]:= Solve::ifun: Inverse functions are being used by Solve, so some solutions may not be found; use Reduce for complete solution information. >>

Out[2]= {{x -> 
   Function[{t}, -I 2^(1/4) Sqrt[-(1/Sqrt[C[1]])] Sqrt[C[1]]
      JacobiSN[Sqrt[
      Sqrt[2] t^2 Sqrt[C[1]] + 2 Sqrt[2] t Sqrt[C[1]] C[2] + 
       Sqrt[2] Sqrt[C[1]] C[2]^2]/Sqrt[2], -1]]}, {x -> 
   Function[{t}, 
    I 2^(1/4) Sqrt[-(1/Sqrt[C[1]])] Sqrt[C[1]]
      JacobiSN[Sqrt[
      Sqrt[2] t^2 Sqrt[C[1]] + 2 Sqrt[2] t Sqrt[C[1]] C[2] + 
       Sqrt[2] Sqrt[C[1]] C[2]^2]/Sqrt[2], -1]]}}

What happened? I wanted an easy output! Ok, actually, this type of DE does not explicitly depend on t or x'[t]. In order to reduce this equation to first order ODE with independent var x, Mathematica needs (and uses) inverse functions. You see JacobiSN at Out[2] which is the inverse of EllipticK. Solve uses JacobiSN to find an expression for x[t]. Here is the plot of the solutions:

Plot[Evaluate[
  x[t] /. {sol[[1]], sol[[2]]} /. {C[1] -> 1, C[2] -> 3}], {t, -5, 
  5},
 AxesLabel -> {"time", "displacement"},
 Filling -> {1 -> {2}}]

You can change the coefficients C[1] and C[2], and see the resulting plots.

Answer 3

Higher-order, nonlinear differential equation are usually difficult. We can solve the general equation and try to solve the initial condition for the constants of integration.

sol = DSolve[{x''[t] + x[t]^3 == 0}, x, t];

Solve::ifun: Inverse functions are being used by Solve, so some solutions may not be found; use Reduce for complete solution information. >>

If the initial condition is x[0] == x0, x'[0] == p0, then these determine the first two coefficients of the Taylor series. So let's get the first two Taylor coefficients in three steps: First the coefficients of the series, which turn out to have simplifications that Simplify does not perform by default. Second, take the -1s out of the powers, which will cancel out the Is. Finally replace the constants of integration by simpler parameters.

ivterms = Simplify[CoefficientList[Normal@Series[
     x[t] /. First[sol],
     {t, 0, 1}],
   t],
  {C[1], C[2]} ∈ Reals];
ivterms = ivterms /. Power[Times[-1, e__], n_] :> I^(2 n) Power[Times[e]];
  (* Inverse replacement: {c1 -> C[1]C[2]^4, c2 -> C[2]} *)
ivterms = 
 ivterms /. {Power[C[1], n_] :> c1^n/Abs[C[2]]^(4 n)} /. {Power[
     Abs[C[2]], n_?EvenQ] -> c2^n, C[2] -> c2}
(*
  {(2^(1/4) c2^2 JacobiSN[c1^(1/4)/2^(1/4), -1])/Sqrt[c1], 
   (c1^(3/4) JacobiCN[c1^(1/4)/2^(1/4), -1] JacobiDN[c1^(1/4)/2^(1/4), -1])/c2^3}
*)

Solve the initial condition: First case, p0 = 0.

Solve[First@ivterms == x0, {c2}]
Solve[Last@ivterms == 0 /. #, {c1}] & /@ %
(*
  {{c2 -> -((c1^(1/4) Sqrt[x0])/(2^(1/8) Sqrt[JacobiSN[c1^(1/4)/2^(1/4), -1]]))},
   {c2 -> (c1^(1/4) Sqrt[x0])/(2^(1/8) Sqrt[JacobiSN[c1^(1/4)/2^(1/4), -1]])}}
*)

Solve::ifun: Inverse functions are being used by Solve, so some solutions may not be found; use Reduce for complete solution information. >>

Solve::ifun: Inverse functions are being used by Solve, so some solutions may not be found; use Reduce for complete solution information. >>

(*
  {{{c1 -> 0}, {c1 -> 2 EllipticK[-1]^4}}, {{c1 -> 0}, {c1 ->  2 EllipticK[-1]^4}}}
*)

Second case: generic p0. Unfortunately, we can't solve exactly for c1.

Solve[First@ivterms == x0, {c2}]
Solve[Last@ivterms == p0, {c1}]
(*
  {{c2 -> -((c1^(1/4) Sqrt[x0])/(2^(1/8) Sqrt[JacobiSN[c1^(1/4)/2^(1/4), -1]]))},
   {c2 -> (c1^(1/4) Sqrt[x0])/(2^(1/8) Sqrt[JacobiSN[c1^(1/4)/2^(1/4), -1]])}}
*)

Solve::nsmet: This system cannot be solved with the methods available to Solve. >>

So one is left with using FindRoot to numerically solve for c1 for a given numerical initial condition.