ParallelTable and Random

Question

Each time I execute the following code it generates the same cylinders with the same format.

SeedRandom[157]
cylinders = 
  Table[{RandomReal[{-100, 100}, {2, 3}], RandomReal[5]}, {50}];
SeedRandom[157]
ImageCrop[
 Graphics3D[{EdgeForm[None], 
     Directive[Opacity@RandomReal[{.4, .9}], Hue[RandomReal[]]], 
     Cylinder[First@#, Last@#]} & /@ cylinders, Boxed -> False, 
  ImageSize -> 800]]

However,

SeedRandom[157]
cylinders = 
  ParallelTable[{RandomReal[{-100, 100}, {2, 3}], 
    RandomReal[5]}, {50}];
SeedRandom[157]
ImageCrop[
 Graphics3D[{EdgeForm[None], 
     Directive[Opacity@RandomReal[{.4, .9}], Hue[RandomReal[]]], 
     Cylinder[First@#, Last@#]} & /@ cylinders, Boxed -> False, 
  ImageSize -> 800]]

does not exhibit the same behavior. I guess I am missing something fundamental here.

SeedRandom is only set for the main kernel, not for the subkernels. Even when you would set it in each subkernel, I think you will get a result different from the first one. — Fred Simons, Nov 30 '15 at 14:53

Karsten7 · Accepted Answer · 2015-11-30T15:22:49.460

6

ParallelEvaluate[SeedRandom[157]]
cylinders = 
  ParallelTable[{RandomReal[{-100, 100}, {2, 3}], 
    RandomReal[5]}, {50}];
SeedRandom[157]
ImageCrop[
 Graphics3D[{EdgeForm[None], 
     Directive[Opacity@RandomReal[{.4, .9}], Hue[RandomReal[]]], 
     Cylinder[First@#, Last@#]} & /@ cylinders, Boxed -> False, 
  ImageSize -> 800]]

ParallelEvaluate[SeedRandom[157 + $KernelID]]
cylinders = 
  ParallelTable[{RandomReal[{-100, 100}, {2, 3}], 
    RandomReal[5]}, {50}];
SeedRandom[157]
ImageCrop[
 Graphics3D[{EdgeForm[None], 
     Directive[Opacity@RandomReal[{.4, .9}], Hue[RandomReal[]]], 
     Cylinder[First@#, Last@#]} & /@ cylinders, Boxed -> False, 
  ImageSize -> 800]]

edited Nov 30 '15 at 15:22

answered Nov 30 '15 at 15:13

Karsten7

27,448
5
73
134

Karsten, note that evaluating the second SeedRandom in parallel doesn't keep the coloring repeatable. I think that the second call should simply be to the local master kernel, i.e. no ParallelEvaluate there. – MarcoB Nov 30 '15 at 15:20
@MarcoB Thanks! Fixed it. – Karsten7 Nov 30 '15 at 15:23
Why the first image contains fewer cylinders? – Dimitris Nov 30 '15 at 15:26
@dimitris Because all kernels produce the same cylinders. – Karsten7 Nov 30 '15 at 15:28
@dimitris Compare for example Length@cylinders with Length@DeleteDuplicates@cylinders. – Karsten7 Nov 30 '15 at 15:30
Thanks a lot . Nice explanation and solution. – Dimitris Nov 30 '15 at 15:36

ParallelTable and Random

1 Answers1

Linked