How to show the directions (arrows in the graph) for a ParametricPlot

Question

f[t_] := 2*t - 3;
f1[t_] := 6*t - 7;
ParametricPlot[{f[t], f1[t]}, {t, -3, 3}]

The above code shows the graph... but it can't show me the directions. How can this be achieved?

Welcome to Mathematica.SE!

As you receive help, try to give it too, by answering questions in your area of expertise.

Take the tour and check the faqs!

When you see good questions and answers, vote them up by clicking the gray triangles, because the credibility of the system is based on the reputation gained by users sharing their knowledge.

Also, please remember to accept the answer, if any, that solves your problem, by clicking the checkmark sign! — , Dec 14 '15 at 08:58
See How to copy code from Mathematica so it looks good on this site and Hints and help on using the site efficiently and How do I format my posts using Markdown or HTML? and read the FAQ — , Dec 14 '15 at 08:58

score 3 · Answer 1 · answered Dec 14 '15 at 09:10

3

One way to post-process your plot (caveat: will probably not work for any combination):

f[t_] := 2*t - 3; f1[t_] := 6*t - 7; 
ParametricPlot[{f[t], f1[t]}, {t, -3, 3}] /.  Line[content___] :> {Arrowheads[ConstantArray[0.05, 5]], Arrow[content]}

Mathematica graphics

answered Dec 14 '15 at 09:10

Yves Klett

15,383
5
57
124

Thnx....to you. – Nasim Dec 14 '15 at 09:14

score 2 · Answer 2 · answered Dec 14 '15 at 09:11

This question may get marked as a duplicate, there are many question about adding arrows to plots, but none of them has an answer of how to programmatically add an arrow for a parametric plot. For that answer, I looked to this post on Wolfram Community,

arrowParametricPlot[f_List, p_List, opts : OptionsPattern[]] := 
 Block[{δ = (p[[3]] - p[[2]])/100.}, 
   ParametricPlot[f, p, 
    Evaluate[FilterRules[{opts}, Options[ParametricPlot]]], 
    Epilog -> {Arrowheads[.1, 0], 
      Arrow[{f /. p[[1]] -> p[[3]] - δ, 
        f /. p[[1]] -> p[[3]]}]}, PlotRange -> All]] /; 
  Length[f] == 2 && 
   Length[p] == 3 && ! FreeQ[f[[1]], p[[1]]] && ! 
    FreeQ[f[[2]], p[[1]]]

See that it will show the direction of the parametric curve,

{arrowParametricPlot[{f[t], f1[t]}, {t, -3, 3}, ImageSize -> 100],
 arrowParametricPlot[{f[t], f1[t]}, {t, 3, -3}, ImageSize -> 100]}

How to show the directions (arrows in the graph) for a ParametricPlot

2 Answers2