How to calculate the pseudo-remainder and pseudo-quotient of two multivariate polynomials

Question

I have fixed some code, but it always gives me errors. Can anybody tell me its right code?

PsedoRemainder[F_, G_, ord_] :=
  Module[{polyquo, polyrem, MainVariable, Initial, Separant, l}
    polyquo = PolynomialQuotient[F, G, MainVariable]; 
    polyrem = PolynomialRemainder[F, G, MainVariable];
    MainVariable = Last[ord];
    l = Exponent[G, MainVariable];
    Initial = Last[CoefficientList[G, MainVariable]];
    Separant = D[G, MainVariable];
    polyrem[i_] := F;
    polyquo[j_] := 0;
    s := 0;
    deg[i_] := Exponent[R[i], MainVariable]; 
    Initial[i_] := Last[CoefficientList[polyrem[i], MainVariable]]
    While[deg[i] > l && [Initial]^s*F != polyquo[j]*G + polyrem[i], 
      s++;
      polyrem[{i + 1} _] := 
        Initial*R[i] - Initial[i]*[MainVariable]^(deg[i] - l)*G;
      polyquo[{j + 1} _] := 
        Initial*polyquo[j] + Initial[i]*[MainVariable]^(deg[i] - l);
      i++; j++;]
    Print[{[Initial]^s*F = polyquo[j]*G + polyrem[i], Initial[i], polyrem[i], polyquo[j]}];
    Return[polyrem, polyquo];

F = Subscript[x, 1]^2 Subscript[x, 2]^3 - Subscript[x, 2];
G = Subscript[x, 1]^3 Subscript[x, 2] - 2;
ord = [Subscript[x, 1], Subscript[x, 2]]

The following are some explaintation

class of F:=Greatest subscript c for which x_c occurs actually in F,otherwisw 0 if F is a non-zero constant. In notation: cls(F)

MainVariable of F:=x_c if class of F is c>0,otherwise undefined.In notation :MainVariable(F)

Degree of F:=Degree of F in x_c if class of F is c>0,otherwise =0.In notation :deg(F)

For a non-constant polynomial F of class c>0, F is in normal form:= F=I*x_c^d+lower degree terms in x_c

I is called initial of F In notation: Initial(F)

Thank you ,please tell me your code ,maybe I have more ideas about this question. — user36509, Dec 23 '15 at 01:37
Please format your code properly, at the moment reading (esp. after the last edit) is painful. Also make sure to include correct, working code (as far as possible). — Yves Klett, Dec 23 '15 at 07:29
The current version of your code is still nonsense -- full of syntax errors. — m_goldberg, Dec 23 '15 at 08:20
Indeed many errors still. Return can have a single argument only. You use square brackets as parenthesis in the Print line. You also define Initial as a value first and then redefine it as a function. — Sjoerd C. de Vries, Dec 23 '15 at 10:00
using Subscript makes the code very hard to read. I do not see what is the fascination with Subscripts really. — Nasser, Dec 23 '15 at 12:23
Except now I'm away for a few days and the code is in my office. Will post on Monday. Meanwhile you might put some time into fixing the basic errors others keep noting. — Daniel Lichtblau, Dec 23 '15 at 13:29
I get stuck on line 1: what is your intention passing an undefined local module variable MainVariable to PolynomialQuotient ? Its valid but just returns F/G — george2079, Dec 23 '15 at 16:21

Daniel Lichtblau · Answer 1 · 2021-05-19T16:25:44.547

This is perhaps close to what you want. I change the structure so that polynomials are represented as lists of coefficients with respect to the "main" variable (the one with respect to which we are pseudo-dividing). The result is a list comprised of the list of quotients, and the list of pseudo-remainders, each of which is itself one of these coefficient lists.

pseudoRemainder[f_, g_, ord_] := Module[
  {mainVar, initialG, initial, separant, gdeg, fdeg, prem, pquo, deg, 
   flist, glist, i, j} ,
  mainVar = Last[ord];
  flist = CoefficientList[f, mainVar];
  glist = CoefficientList[g, mainVar];
  gdeg = Length[glist] - 1;
  fdeg = Length[flist] - 1;
  initialG = Last[glist];
  separant = D[g, mainVar];
  prem[0] = flist;
  pquo = ConstantArray[0, fdeg - gdeg + 1];
  deg[0] = Length[prem[0]] - 1;
  initial[0] = Last[flist] ;
  i = 0;
  j = Length[prem[0]];
  While[deg[i] >= gdeg,
   i++;
   prem[i] = 
    Expand[initialG*Most[prem[i - 1]] - 
      initial[i - 1]*PadLeft[glist, Length[prem[i - 1]] - 1]];
   pquo = Expand[initial[i - 1]*pquo];
   pquo[[-(fdeg - deg[i - 1] + 1)]] = initial[i - 1];
   j = Length[prem[i]];
   While[j >= 0 && PossibleZeroQ[prem[i][[j]]], j--];
   deg[i] = j - 1;
   prem[i] = prem[i][[1 ;; j]];
   initial[i] = Last[prem[i]];
   ];
  {pquo, Table[prem[j], {j, 0, i}]}
  ]

Here is the example from the post.

fF = x1^2*x2^3 - x2;
 gG = x1^3 *x2 - 2;
pseudoRemainder[fF, gG, {x1, x2}]
(* Out[201]= {{2 x1^5 - x1^6 + x1^8, -2 x1^10 + x1^11 - x1^13, -2 x1^12 +
    x1^13 - x1^15}, {{0, -1, 0, x1^2}, {0, 
   2 x1^2 - x1^3, -x1^5}, {-2 x1^5, 
   2 x1^5 - x1^6 + x1^8}, {-4 x1^8 + x1^9 - x1^11}}} *)

The first pseudo-remainder is just the coefficient list for the dividend, fF. That is, it can be regarded as 0*x2^0 + (-1)*x2^1 + 0*x2^2 + x1^2*x2^3. Since we are (pseudo-)dividing a degree 3 polynomial by a degree 1 polynomial, we expect a "constant" final pseudo-remainder, that is, degree 0 in x2, and indeed we get that: it is -4 x1^8 + x1^9 - x1^11.

I am not sure whether the quotients are being returned in a way that makes them best usable. I guess it depends on what usage one has in mind. I simply tried to return what I thought was the desired form, based on the original code.

I wanted to post a response mostly because the general topic is of some interest, but sufficiently specialized that I was not sure other readers would be familiar with it. That said, I should repeat what others stated in comments: the code as originally presented was nowhere near at a level that belongs in a question on the MSE forum. There were simply too many elementary errors, with no effort shown to debug any part of it.

--- edit 2021-05-19 ---

I put a corrected implementation into the Wolfram Function Repository.

PseudoQuotientRemainder

The implementation is...pedestrian (almost same as above). Possibly it could be done better using SubresultantPolynomialRemainders or similar.

--- end edit ---

How to calculate the pseudo-remainder and pseudo-quotient of two multivariate polynomials

1 Answers1