Replacement in a nested matrix

Question

We have a nested matrix

m1 = {{{1, 2, 2, I}, {1, 1, -2, 1}, {3, 2, 2, -I}}, {{3, 4, 4, I}, {1, 1, 4, 1}, {3, 3, 4, -1}}};

we must replace the first number of each sub_list with the third number and vise versa and and achieve to m2 as:

m2 = {{{2, 2, 1, I}, {-2, 1, 1, 1}, {2, 2, 3, -I}}, {{4, 4, 3, I}, {4, 1, 1, 1}, {4, 3, 3, -1}}};

The shape of m1 and m2 are as below. We know that we can use of two loops with an IF condition but we don't think it is a good way. If Possible please let us know how can we obtain m2?

m1:

m2:

Closely related: (3069), (47017) – Mr.Wizard Jan 21 '16 at 18:45 — Mr.Wizard, Jan 21 '16 at 18:45

score 6 · Accepted Answer · answered Jan 21 '16 at 18:33

6

One way:

m2 = Apply[{#3, #2, #, #4} &, m1, {2}]

or another:

m2 = m1;
m2[[;; , ;; , {3, 1}]] = m2[[;; , ;; , {1, 3}]];
m2

answered Jan 21 '16 at 18:33

Kuba

136,707
13
279
740

Can I use of MapAt instead of Apply[ ,{2}]? – Unbelievable Jan 21 '16 at 18:36
2

@Ackaran Apply is shorter because with Map you have to refer to #[[2]] instead of #2 etc. And you need Map not MapAt. – Kuba Jan 21 '16 at 18:37
1

Damn, both of my favorite methods in one post. Nothing left for me to write. :^) – Mr.Wizard Jan 21 '16 at 18:44
The second way is so intelligent, I enjoyed it. – Unbelievable Jan 21 '16 at 18:44
@Ackaran See the question I just linked in a comment below your post for more examples like this. – Mr.Wizard Jan 21 '16 at 18:45
I favorite your address commented. That link contains more things to be understood and practiced. – Unbelievable Jan 21 '16 at 18:49

score 3 · Answer 2 · answered Jan 22 '16 at 11:28

3

"Monster voodoo machine" method for those who want MapAt, do not want to bother with Part and like Span:

MapAt[Replace[{a_, b_, c_, d_} -> {c, b, a, d}], m1, {;; , ;;}]

answered Jan 22 '16 at 11:28

garej

4,865
2
19
42

You can use Map[Replace[...], m1, {2}] too. – Kuba Jan 22 '16 at 11:32
1

@Kuba, I see it, but the OP asked for MapAt. I've made it just for fun :))) – garej Jan 22 '16 at 11:33
BTW, this Replace[m1, {a_, b_, c_, d_} -> {c, b, a, d}, {2}] also does the job. – garej Jan 23 '16 at 09:02

E. Chan-López · Answer 3 · 2023-12-30T04:00:32.440

2

 m = 
 {{{1, 2, 2, I}, {1, 1, -2, 1}, {3, 2, 2, -I}}, 
  {{3, 4, 4, I}, {1, 1, 4, 1}, {3, 3, 4, -1}}};

wanted = 
 {{{2, 2, 1, I}, {-2, 1, 1, 1}, {2, 2, 3, -I}}, 
  {{4, 4, 3, I}, {4, 1, 1, 1}, {4, 3, 3, -1}}};

Using ReplaceAll:

(m /. v_?VectorQ :> Reverse@RotateRight[v, 1]) === wanted
(True)

edited Dec 30 '23 at 04:00

answered Dec 30 '23 at 03:46

E. Chan-López

23,117
3
21
44

score 1 · Answer 4 · answered Dec 30 '23 at 00:20

m = 
 {{{1, 2, 2, I}, {1, 1, -2, 1}, {3, 2, 2, -I}}, 
  {{3, 4, 4, I}, {1, 1, 4, 1}, {3, 3, 4, -1}}};

wanted = 
 {{{2, 2, 1, I}, {-2, 1, 1, 1}, {2, 2, 3, -I}}, 
  {{4, 4, 3, I}, {4, 1, 1, 1}, {4, 3, 3, -1}}};

Using SubsetMap (new in 12.0)

result = Map[SubsetMap[RotateRight, #, {1, 3}] &, m, {2}]

returns

 {{{2, 2, 1, I}, {-2, 1, 1, 1}, {2, 2, 3, -I}}, 
  {{4, 4, 3, I}, {4, 1, 1, 1}, {4, 3, 3, -1}}};
result == wanted

True

Replacement in a nested matrix

4 Answers4

Linked

Related