Add terms to nested list

Question

Suppose I have a nested list of the following:

list={{1,2},{5,8},{4,1}...}

I would like to add a number to each first term of the list. The output would be like the following:

{{1+x,2},{5+x,8},{4+x},1}...}

Szabolcs · Answer 1 · 2016-02-05T17:08:02.123

18

list = {{1, 2}, {5, 8}, {4, 1}};

Apply, Function:

{#1 + x, #2} & @@@ list
(* {{1 + x, 2}, {5 + x, 8}, {4 + x, 1}} *)

Map:

# + {x, 0} & /@ list    
(* {{1 + x, 2}, {5 + x, 8}, {4 + x, 1}} *)

Part, Transpose:

Transpose[{list[[All, 1]] + x, list[[All, 2]]}]    
(* {{1 + x, 2}, {5 + x, 8}, {4 + x, 1}} *)

MapAt:

MapAt[x + # &, list, {All, 1}]
(* {{1 + x, 2}, {5 + x, 8}, {4 + x, 1}} *)

Transpose only:

Transpose[Transpose@list + {x, 0}]
(* {{1 + x, 2}, {5 + x, 8}, {4 + x, 1}} *)

Replace:

Replace[list, {a_, b_} :> {a + x, b}, {1}]
(* {{1 + x, 2}, {5 + x, 8}, {4 + x, 1}} *)

Inner:

Inner[Plus, list, {x, 0}, List]
(* {{1 + x, 2}, {5 + x, 8}, {4 + x, 1}} *)

edited Feb 05 '16 at 17:08

answered Feb 05 '16 at 14:44

Szabolcs

234,956
30
623
1,263

Don't forget MapAt[x + # &, list, {All, 1}] – Jason B. Feb 05 '16 at 14:44
I like this format really much – e.doroskevic Feb 05 '16 at 14:45
2

@JasonB Great, made it community wiki feel free to edit! – Szabolcs Feb 05 '16 at 14:45
1

@march The problem with ReplaceAll is: what if Length[list] == 2? – Szabolcs Feb 05 '16 at 17:07
@Szabolcs. Oh. Agreed. I like the Replace version better, since fixing the ReplaceAll version by doing, for instance, a_Symbol won't be general enough.Those not-so-corner cases kill me sometimes. – march Feb 05 '16 at 17:09
ReplacePart[#, {i_} -> {x, 0}] + # &@list – garej Feb 05 '16 at 20:00

score 3 · Answer 2 · answered Dec 31 '23 at 00:01

3

list = {{1, 2}, {5, 8}, {4, 1}};

Using Threaded (new in 13.1)

list + Threaded[{x, 0}]

{{1 + x, 2}, {5 + x, 8}, {4 + x, 1}}

answered Dec 31 '23 at 00:01

eldo

67,911
5
60
168

score 3 · Answer 3 · answered Dec 31 '23 at 02:17

3

Using SubsetMap:

list = {{1, 2}, {5, 8}, {4, 1}};
SubsetMap[# + x &, list, {All, 1}]

{{1 + x, 2}, {5 + x, 8}, {4 + x, 1}}

answered Dec 31 '23 at 02:17

Syed

52,495
4
30
85

score 3 · Answer 4 · answered Dec 31 '23 at 02:55

3

list = {{1, 2}, {5, 8}, {4, 1}};

Using Cases:

Cases[list, {a_, b_} :> {a + x, b}]
({{1 + x, 2}, {5 + x, 8}, {4 + x, 1}})

answered Dec 31 '23 at 02:55

E. Chan-López

23,117
3
21
44

score 2 · Answer 5 · answered Dec 31 '23 at 03:01

First and foremost, I have to say that the solution using Threaded looks like the nicest one to me. Kudos to @eldo.

I want to demonstrate the use of ThroughOperator that was developed by @Sjoerd Smit. To the extend of my knowledge it was first suggested in this answer.

In this example we do

ResourceFunction["ThroughOperator"][{#1 + x &, #2 &}] @@@ list

{{1 + x, 2}, {5 + x, 8}, {4 + x, 1}}

A not so normal way of doing it is to use Outer

Transpose[{First /@ Join @@@ Outer[Plus, list, {x, 0}], 
  Last /@ Join @@@ Outer[Plus, list, {x, 0}]}]

score 2 · Answer 6 · answered Dec 31 '23 at 18:38

2

list + ConstantArray[{x,0},Length@list]


(* {{1+x,2},{5+x,8},{4+x,1}} *)

answered Dec 31 '23 at 18:38

user1066

17,923
3
31
49

Add terms to nested list

6 Answers6