Cell sizing and labeling for $\textit{MaTeX}$ equations

Question

I am writing a book in the Wolfram CDF format and would like to improve upon the default equation typesetting of Mathematica. To this end I've loaded @Szabolcs' valuable MaTeX, which imports $\LaTeX$ typesetting into the Mathematica document:

Needs["MaTeX`"];
ConfigureMaTeX["pdfLaTeX" -> "/usr/texbin/pdflatex"]

Here's a comparison between $\LaTeX$ at the top, and Mathematica at the bottom. There is no question whatsoever that the aesthetic and legibility difference is profound.

Here is just one small part of an actual equation that will appear in my book:

Again: not the slightest doubt that the $\LaTeX$ version (bottom) is vastly superior to that in Mathematica (top).

When I use DisplayNumberedFormula and cut and past an input cell into it, I get something that looks like this:

which I find particularly ugly and illegible, at least compared to $\LaTeX$.

Let me stress that I consider myself an expert $\LaTeX$ user (published many books, solution manuals, etc., with sales into the high 10s of thousands) as well as an expert Mathematica programmer. I'm happy to use whichever tool leads to the best result.

Here is a sample of the rendered Mathematica document. (I've left open the equation cell.) Notice how legible is the rendered equation.

A number of problems arise, however:

1. The default size of the rendered MaTeX equation is too small, so I have to adjust the output using ImageSize, as shown above. However, this option sets the overall size of the rendered equation, of course not the size of individual variables. Some equations have one line, others two or more. Is there a way to automatically set the image size so that the rendered variable (e.g., an $x$-height) is constant?
2. Of course for the final book, I double-click on the bottom half of the highlighted cell to display only the MaTeX-rendered equation, not its source code. I want to be able to edit the typesetting commands and hit return and get an "output" cell of the type NumberedEquation. In short, is there a way to make a special "Equation Input" cell such that its output cell (an equation) is of a type NumberedEquation which retains its Tag and other properties as I type in variations of the source MaTeX code?

Any suggestions?

Answer 1

this is (now a very long) comment not an answer.

The objective is to write a book using Mathematica. Within the book equations are generated from LaTex rather than typeset directly using Mathematica. By definition if this was to be done entirely using Mathematica, the equation typesetting would not be done in an input cell. It would be done either in one of the bundled styles that have been designed for rendering typeset equations, such as "DisplayFormulaNumbered", or a custom cell style with similar properties. Comparing output to input is a disingenuous apples/oranges comparison. If you use Mathematica correctly for creating equations then you can create a book with typesetting like this:

Now this may still be unsatisfactory to some people (who may prefer other methods such as LaTex) but it is also quite different to the apples/oranges comparison presented in the question.

So the first part of the question, when modified to compare like to like, ultimately gets down to what best enables you to do the job (i.e. typesetting a document) efficiently and meet your aesthetic preferences.

The second part of the question was a required code modification so that you can evaluate a cell and have the output in a numbered equation style rather than output. It is disappointing when contributors here devote time to provide an answer, demonstrate the answer, and have it ignored.

Edit to reply in more detail to first comment.

My deleted answer to part 2 was just that. Part 2 asks "In short, is there a way to make a special "Equation Input" cell such that its output cell (an equation) is of a type NumberedEquation". In other words this is not asking about typesetting it is asking about changing a generated cell style. My deleted answer provided a solution.

In your comment you say "Your retracted code that I saw before did not (as far as I could tell) lead to reasonably nice equations, such as in 11.48, above."

As per first edited sentence the answer was a solution to changing a generated cell it was not a solution to typesetting. If you want to typeset in Mathematica you do not type into input, evaluate input, and display the output (and probably hide the input) in your document. That is a fundamentally wrong way to go about typesetting a document ("natively") in Mathematica. If you want to use the "MaTex" package then yes, that is what you need to do, but if you want to typeset directly in Mathematica then that is the last thing you want to do.

Answer 2

I guess my questions are 1) why you are not doing the typesetting in Mathematica; 2) for those of us unfamiliar with MaTeX are the equations rendered as vectors or bitmap or what?

Here is a solution to part 2 of your question.

Step 1. Make a new style. I am going to call it "MaTeX". In this style you will use the CellEpilog option to change the output cell to your desired style.

CellPrint@
 Cell[StyleData["MaTeX", StyleDefinitions -> StyleData["Input"]],
  MenuSortingValue -> 1510,
  CellEpilog :> (SelectionMove[EvaluationCell[], All, GeneratedCell]; 
    FrontEndTokenExecute[EvaluationCell[], "Style", 
     "DisplayFormulaNumbered"])
  ]

Step 2. Add this style to a private style sheet or for regular work create a new stylesheet with this cell.

Step 3. Use this style as per GIF below. In the GIF I first evaluate an input cell and it creates an output cell. Then I repeat but first change the cell style to "MaTeX" (which occurs offscreen) and then you see that the output is a "DisplayFormulaNumbered" cell.

Answer 3

I did not notice this post until today.

MaTeX has two options for setting the size of the output:

• Magnification just scales everything (i.e. the PDF file output by LaTeX) proportionally.

• FontSize passes the font size to LaTeX and thus gives access to the special variants for each point size.

When I work with MaTeX, I tend to set all its option to my preferred value at the start of the session, like this

SetOptions[MaTeX, Magnification -> ..., FontSize -> ..., ...]

I.e. just what @martin mentioned.

Mathematica's default font size is 14, but MaTeX's is 12. So you may want to start with FontSize -> 14 and leave Magnification at the default value of 1.

Here's a little demo of how FontSize and magnification differ:

MaTeX["\\int_0^\\infty e^{-x}\\, dx", FontSize -> 20, Magnification -> 1]

MaTeX["\\int_0^\\infty e^{-x}\\, dx", FontSize -> 10, Magnification -> 2]

MaTeX["\\int_0^\\infty e^{-x}\\, dx", FontSize -> 5, Magnification -> 4]

5 pt is designed for legibility at small sizes and looks awkward magnified 4 times. 20 pt is designed for beauty when displayed at its actual size.

---

Since version 1.2.0 it also has the options ContentPadding and LineSpacing which effectively control vertical margins and shouldn't be necessary most of the time. Here's a small demo:

f = Framed[#, ContentPadding -> False, FrameMargins -> None, 
    FrameStyle -> AbsoluteThickness[1]] &;

f /@ MaTeX /@ {"x", "y", "M"}

f /@ (MaTeX[#, LineSpacing -> {1, 0}] &) /@ {"x", "y", "M"}

f /@ (MaTeX[#, ContentPadding -> False] &) /@ {"x", "y", "M"}

Both options follow the standard Mathematica usage. LineSpacing -> {m,a} makes the line height be m*fontsize + a, in points. ContentPadding -> True enforces a minimal height equal to one line heigh for the output. A display style output is usually taller than one line height, so it won't make a difference there.

---

Here's a little modification to @Mike's special cell style.

CellPrint@
 Cell[StyleData["MaTeX", StyleDefinitions -> StyleData["Program"]], 
  MenuSortingValue -> 1510, 
  CellEpilog :> (SelectionMove[EvaluationCell[], All, GeneratedCell];
    FrontEndTokenExecute[EvaluationCell[], "Style", 
     "DisplayFormulaNumbered"]),
  Evaluatable -> True, 
  CellEvaluationFunction -> (MaTeX[
      First[FrontEndExecute[ExportPacket[Cell[#1], "InputText"]]]] &),
   CellFrameLabels -> {{None, "MaTeX"}, {None, None}}, 
  CellGroupingRules -> "InputGrouping"]

Sorry about the messy code formatting. This is a special evaluatable input cell that renders LaTeX code:

You could probably modify this to suit your need better. One advantage is that there's no need to type \\ all the time anymore. A single \ will be fine.

---

Finally, I have to give a few warnings, as this is not really the use case I anticipated for MaTeX. I made MaTeX because I wanted to have more beautiful labels in publication figures. But I never meant it to be used for in-notebook display. There will be a few disadvantages if you do this.

1. MaTeX returns the result as vector graphics. This takes up considerably more space than the text equivalent.

   expr = HoldForm[Integrate[Exp[-x], {x, 0, Infinity}]]
   
   ByteCount /@ {expr, MaTeX[expr]}
   
   (* {304, 24328} *)
   

2. MaTeX's output is really meant for print or for PDF viewers, which tend to render vector graphics with quite a lot of care. Font glyphs are always rendered differently by computers than other vector drawings. Text rendering is special and it is optimized for legibility. This is going to be lost with MaTeX because it converts everything to simple curves. If you use a "retina" display, you will not be able to notice this. But many of your readers will have low resolution screens, and to them the MaTeX output will look more "blurry" than other text.

   My personal opinion about this is that if the formulas are displayed in a large enough size (and if there aren't too many of them), then LaTeX's superior typesetting outweighs the disadvantage of the blurriness. But it's something to be aware of.

3. MaTeX takes great care to preserve the baseline. Thus mixing MaTeX output with text should be okay in theory ... it looks like this in large size.

   

   But it turns out that the front end aggressively rounds everything to integer screen pixels early in the display pipeline, and this causes misalignments when displaying things at standard sizes:

   

   So in practice it won't be possible to mix MaTeX output with standard text and still make it look good.

All in all, I would be very careful with using too much MaTeX in a CDF document. In figures meant for print/PDF I use it all the type. If I had to use it in CDF, I would restrict it to a few display formulas only, and I would be very careful to keep everything legible at lower resolution screens.

Answer 4

You could set it up it manually:

SetOptions[MaTeX, "Preamble" -> {"\\usepackage{amsmath,amssymb,array}"}, 
Magnification -> 1.5];

    MaTeX["\\begin{tabular}{>{\\raggedright}m{12cm} c}
 $\\displaystyle\\mbox{}\ \\int\\limits_{x = \
-\\infty}^\\infty\\!\\!\\! |f(x)|^2 dx = \\dfrac{1}{2\\pi} \
\\int\\limits_{\\omega = -\\infty}^\\infty\\!\\!\\! |F(\\omega)|^2 \
d\\omega$ 
 &\\small{(1.1)}
 \\\\\\\\
 $\\text{This is some text.}$
 \\\\\\
 \\\\\\
 $\\displaystyle\\mbox{}\ p(\\mathcal{D}|\\theta)=\\prod\\limits_{k = \
1}^{n}\\dfrac{1}{(2\\pi)^{d/2}|\\Sigma|^{1/2}} \
\\operatorname{Exp}[(x_k-\\theta)^{t}\\Sigma^{-1}(x_k-\\theta)]$ 
 &\\small{(1.2)}
 \\end{tabular}"]