ControlActive doesn't distinguish the active element in list-based controls

Question

There are three controls in the following code: the first one is a "stand-alone" one and the other two are based on the list angle. When one of the "angles" becomes active, all of them do the same. How to prevent it?

DynamicModule[{angle = Array[0 &, 2]},
 Panel@Dynamic@
   Column[{Row@{
      Slider[Dynamic[x], {0, 2 Pi}], Dynamic[{x, ControlActive["a", "Inactive"]}]}, 
   Grid[
    MapIndexed[
       With[{i = #2[[1]]}, {Slider[Dynamic[angle[[i]]], {0, 2 Pi}], 
          Dynamic[{angle[[i]], ControlActive["Active", "Inactive"]}]}] &, angle]]}]]

Mathematica graphics

"Dynamic is a wild beast" -- Yes, perhaps it is the proverbial dancing bear, of which was said: we should be grateful that it dances at all and not expect it to dance gracefully. — m_goldberg, Feb 28 '16 at 15:20

score 5 · Answer 1 · answered Feb 28 '16 at 00:14

5

It looks that ControlActive treats angle as a one variable which will be same for both ControlActive.

See if this help:

 DynamicModule[{angle = Array[0 &, 2]}, 
 Panel@Dynamic@
   Column[{Row@{Slider[Dynamic[x], {0, 2 Pi}], 
       Dynamic[{x, ControlActive["a", "Inactive"]}]}, 
     Grid[MapIndexed[
       With[{i = #2[[1]]}, {DynamicModule[{y}, 
           Row@{Slider[Dynamic[y, (angle[[i]] = y = #) &], {0, 2 Pi}],
              Dynamic[{y, ControlActive["Active", "Inactive"]}]}]}] &,
        angle]]}]]

answered Feb 28 '16 at 00:14

Basheer Algohi

19,917
1
31
78

Yep! It works :) I don't find the idea of nesting neat but .... :).Thans! – Dr. belisarius Feb 28 '16 at 00:18
@Dr. belisarius I am trying to create different variable for each controller. The only way I have (for automatic goal) is to use DynamicModule. It is something like this angle={a,b} and then work with a and b instead of working with angle itself. – Basheer Algohi Feb 28 '16 at 00:24
In my real problem I don't know a priori how many "angles" I will have – Dr. belisarius Feb 28 '16 at 01:26
That is why is use DynamicModule to generate different variable for each element of angle – Basheer Algohi Feb 28 '16 at 01:34
1

yes,yes. Your answer works.I was referring to your previous comment "I am trying to create different variable" – Dr. belisarius Feb 28 '16 at 02:16
@Dr.belisarius and Algohli, worth to mention that those controllers are now only one way bouded with angle. If the stand-alone one uses Dynamic[angle[[1]]] it won'y be reflected by those grom grid. – Kuba Feb 28 '16 at 09:55
won'y->won't grom->from – Kuba Feb 28 '16 at 10:02
@Kuba I want a sip of what you're drinking – Dr. belisarius Feb 28 '16 at 17:33

ControlActive doesn't distinguish the active element in list-based controls

1 Answers1

Linked