Evaluation leak from Dynamic exported to NB format

Question

This is closely related to the recent: Creating self destructing notebook.

However the answer doesn't work in my case.

A small example is:

ExportString[Dynamic[Print[1]], "NB"]

and it prints 1 :-(

A real word case is to save a notebook without triggering dynamics inside:

nb = Notebook[{
   Cell @ BoxData @ ToBoxes @ DynamicModule[{},
       "whatever",
       Initialization :> {Print["initialization"]}
   ]},
   NotebookDynamicExpression :> Refresh[Print["dynamicExpression"], None]
];

Now, I want to save a notebook without prompting Dynamic print statements.

Export[
 FileNameJoin[{$HomeDirectory, "Desktop", "silent.nb"}],
 nb, "NB"
]

Can I prevent that?

In fact, I was wrong. It printed to messages window, and somehow I didn't notice that. So the problem is real also in my case. Don't know off hand how would one solve it, alas. — Leonid Shifrin, Mar 10 '16 at 15:01
Not sure if the word bug fully describes this case, but IMO this is certainly an unwanted behavior. To call this a bug, we need to have somewhere in documentation a statement that Export to NB with dynamic elements does not leak evaluation in dynamics. I don't have the time right now to check whether any such statement was made somewhere in the docs. But in any case, this is certainly an inconvenience, and this behavior seems to be problematic in the majority of cases. — Leonid Shifrin, Sep 09 '16 at 13:20
@LeonidShifrin I think it is done when ImageSizeCache is calculated... — Kuba, Sep 14 '16 at 10:58
Quite possibly you're right. You certainly have more experience with this stuff than me. — Leonid Shifrin, Sep 14 '16 at 11:05
@LeonidShifrin working on an answer. Sorry for bothering you :) wanted to msg you so that you are up to date. Feel free to ignore me at any time :) — Kuba, Sep 14 '16 at 11:07
Quite frankly, if we talk about UI, recently I've got way more interested in what web / browser lets one do, and haven't done much UI-related work in Mathematica. — Leonid Shifrin, Sep 14 '16 at 11:19

score 4 · Accepted Answer · edited Apr 13 '17 at 12:55

Explanation

It is not a leak if this is intended, right? It happens because MMA is trying to determine ImageSizeCache for DynamicBox that will be generated.

ImageSizeCache is explained in

tutorial / AdvancedDynamicFunctionality / ImageSizeCache in Dynamic

My approach to fix it

This tutorial will teach us the the fix is to use a fixed value of ImageSizeCache and SynchronousUpdating -> Automatic.

The problem is that one may want to have a better control over SynchronousUpdating at the end.

To circumvent that we can add additional Dynamic which won't be triggered more than needed and will alow to preserve inner Dynamic's options:

ExportString[
  Dynamic[
    Dynamic[
      Print@1
    ],
    SingleEvaluation    -> True,
    SynchronousUpdating -> Automatic,
    ImageSizeCache      -> {28., {0., 9.}}
  ],
  "NB"
]

WRI support response

I felt like it is something very fundamental for working with UI developement in MMA so I asked WRI Support to help me.

It took a while but I received an answer, which is to suspend DynamicUpdating when Export takes place.

[...]

For the effect you want, turn off the global DynamicUpdating option for the fronend just before the call to Export, and then clear that setting after Export.

For example:
CurrentValue[$FrontEnd, DynamicUpdating] = False;
Export[file, nbexpr] 
CurrentValue[$FrontEnd, DynamicUpdating] = Inherited;
[...]

One should know it may not work well with Dynamics that have UpdateInterval option: Toggling DynamicUpdating aborts dynamics with UpdateInterval

Evaluation leak from Dynamic exported to NB format

1 Answers1

Explanation

My approach to fix it

WRI support response

Linked