5

i want to see the simulation of two uncoupled Simple Harmonic Motion (SHM) pendulum with different Lengths and released at different initial displacement angles. in this case adding one more pendulum in my code

also, How to plot the graph of phase difference between these two pendulums vs time. for a fixed initial displacement.

this is my code so far with single pendulum.

theta0 = 15 Degree; L = 2.01; g = 9.81;
omega = Sqrt[g/L];
T = 2 Pi/omega;
theta[t_] := theta0*Cos[omega*t];
x[t_] := L*Sin[theta[t]]; y[t_] := -L*Cos[theta[t]];

Manipulate[
 line := Line[{{0, 0}, {x[t], y[t]}}];
 Graphics[
  {Point[{x[t], y[t]}],
   line}, PlotRange -> {{-5, 5}, {-5, 0}}, Frame -> True], {t, 0, 2 T,
   0.05 T}]

enter image description here

All help is much appreciated.

Nabil
  • 513
  • 3
  • 16
  • 1
    What is the actual MMA problem you are unable to solve? – Quantum_Oli Mar 17 '16 at 10:17
  • @Quantum_Oli i want to add another pendulum and see it phase difference. given difference length, – Nabil Mar 17 '16 at 11:24
  • 1
    The different initial angles do not change anything, since this just scales the amplitude. The difference in length means different frequencies (thus different times for the phase to accumulate 2Pi). Phase of a harmonic oscillator is linear in time. You will not get a very interesting graph, you'll simply get a linear function of time. Perhaps you are looking for something else? You can get some groovy beat-frequency patterns if you take the difference in displacement, for example. – LLlAMnYP Mar 17 '16 at 11:29

2 Answers2

6

This allows you to watch two pendulums swing in time, 

g = 9.81;
pendulumTrajectory[L_, theta0_, t_] := With[
   {theta = theta0 Cos[Sqrt[g/L] t]},
   {L Sin[theta], -L Cos[theta]}
   ];
Manipulate[
 point1 = pendulumTrajectory[2.01, 15 Degree, t];
 point2 = pendulumTrajectory[3.01, 25 Degree, t];

 line2 = Line[{{0, 0}, point2}];
 Graphics[{{Red, {PointSize[Large], Point[point1]}, 
    Line[{{0, 0}, point1}]},
   {Blue, {PointSize[Large], Point[point2]}, 
    Line[{{0, 0}, point2}]}},
  PlotRange -> {{-5, 5}, {-5, 0}}, Frame -> True], {t, 0, 10, 0.05}]

enter image description here

Jason B.
  • 68,381
  • 3
  • 139
  • 286
6

Here is a generalization to many pendula. The phase differences in this case are revealed by the special points in time at which "revivals" occur, i.e., where the pendula that have all been launched with the same angle all group back together: 

pendulum[α_, l_] := 
 Module[{radius = .03, 
   p = -l {Sin[α], Cos[α]}}, {{Brown, 
    Line[{{0, 0}, p}]}, {Orange, Disk[p, radius]}}]

pendulumArray[t_, α0_] := 
 Graphics[{{Cyan, Disk[{0, 0}, .03]}, 
   Table[pendulum[α0 Cos[2 Pi ν t], 1/ν^2], {ν, 
     51/60, 65/60, 1/60}]}, Background -> Black, 
  PlotRange -> {1.8 {-Sin[α0], Sin[α0]}, {-1.45, .05}}]

created with convert -scale 33% -colors 8

Jens
  • 97,245
  • 7
  • 213
  • 499
  • Thank you, dear Jens, for sharing this with us. This is truly mesmerizing. +ComplexInfinity. Just how many frames is this? – LLlAMnYP Mar 17 '16 at 17:14
  • @LLlAMnYP Thanks - it's about 2400 frames (from a ListAnimate), and I had to shrink the GIF down quite a lot because the upload limit on this site is just 2MB... – Jens Mar 17 '16 at 18:05
  • @Jens , I'm always amazed by how in-depth your answers are. The post I linked to with the double pendulum I saw that you answered 2 hours after it was asked and I wondered "Did he have that already worked out for a class or did he just make it on the fly?" – Jason B. Mar 17 '16 at 18:32
  • Indeed, low res, 8 color pallete, no doubt it's one full period of the system. Does anyone else see ballet dancers, turning into a tense game of ping-pong, then quite a lively game of soccer, before gradually restoring order? – LLlAMnYP Mar 17 '16 at 18:40
  • @JasonB Indeed, I had something prepared already in both this and the double-pendulum answer. The hard part was remembering where I kept it... and then making the movies to upload here. For this answer, I definitely wanted to show a movie, of course. As they say: two thousand pictures say more than a thousand words. Or something like that. – Jens Mar 17 '16 at 19:13
  • @Jens For future reference it is possible to use large gifs, if you upload them to imgur directly. Then you take their "direct link" URL and change the extension from .gifv to .gif and itcan be included here. – Jason B. Mar 17 '16 at 19:30
  • @JasonB Thanks for the info! In this case, the original was over 20MB, so I think it was worth reducing the size just for the sake of page load times... – Jens Mar 17 '16 at 19:33