5
Animate[x, {x, 0, h}, Initialization :> (h = 1)]

The code above gives the error:

Animate::vsform: Animate argument {x,0,h} does not have the correct form for a variable specification. >>

It's strange to me in that if Animate is replaced by Manipulate, no error is generated. What then is the reason for the error?

User18
  • 882
  • 4
  • 12
  • The error message seems clear to me. The 2nd argument of Animate is not a control specification, so you should not expect it have the same semantics as it would have if it were the 2nd argument of Manipulate. What are you really trying to accomplish by using an initialized variable in a range specification? Also, you might consider injecting a value with With. – m_goldberg Mar 19 '16 at 13:23
  • In reply to the question asked, my original code, containing the structure exemplified by the simple code above, is much longer, and in there the range specification has to be calculated before the expression to be animated. – User18 Mar 19 '16 at 14:06
  • The reason I put that calculation within Initialization is that if it is placed outside Animate, then each time the notebook of this code is opened, Animate runs automatically - it runs without the range specification, hence errors appear. – User18 Mar 19 '16 at 14:08
  • Interesting, I thought Animate is just a Manipulate with ControlType -> Animator! – xzczd Mar 20 '16 at 04:32

2 Answers2

4

This has to do with the order in which the arguments of Animate are executed. Let's see if we can determine that:

ClearAll[eval, low, hi, init, x];
i = 1;
Animate[
   eval[If[i > 10, 10, i++]] = x,
   {x, low[i++] = x; 0, hi[i++] = x; 1}, 
   Initialization :> (init[i++] = x;), 
   AnimationRunning -> False
]

Mathematica graphics

Information /@ {low, hi, init, eval};

Mathematica graphics

So, Mathematica first evaluates Animate's lower bound, then its upper bound, then repeats this process (!?).

It then sets Animate's running variable to the lower bound and only then does it execute the initialization.

Evaluation of the main body is the last step. Note that even though the animation isn't running (because of AnimationRunning -> False) the main body is evaluated continuously, just like in Manipulate since an assignment took place there, triggering a refresh.

Hence, the reason for your error is that you use the value set in the initialization in the animation bounds, but that part is executed earlier than the initialization.

Sjoerd C. de Vries
  • 65,815
  • 14
  • 188
  • 323
  • What a great answer! Thank you very much. – User18 Mar 19 '16 at 15:13
  • Please allow me to ask a further question. As I mentioned in replying to m_goldberg, Animate runs automatically when the notebook containing it is open, but in certain cases we need the newly opened notebook to automatically calculate something else first, before Animate is activated. Is it possible to ensure that? – User18 Mar 19 '16 at 15:25
  • I'm afk at the moment. Have you tried AnimationRunning ->False? – Sjoerd C. de Vries Mar 19 '16 at 15:28
  • Yes I tried that option, but it doesn't work. The following example can illustrate this: – User18 Mar 20 '16 at 02:55
  • h = 3; f[x_] := x; Animate[Graphics[Circle[{0, 0}, f[x]], PlotRange -> 3.6], {x, 0, h}, AnimationRunning -> False] – User18 Mar 20 '16 at 03:12
  • Each time Mathematica is started afresh, and one opens the notebook where the above code and its output Animation window have been saved, there is an error, because, as you have pointed out, even though the animation isn't running the main body is evaluated continuously, but here without the required definitions for h and f[x]. – User18 Mar 20 '16 at 03:16
1

Sjoerd's investigation into the causes of the error is very fascinating, but in order to prevent the error it seems to me that you will want to use the SaveDefinitions -> True option, which "specifies whether current definitions relevant for the evaluation of the expression being manipulated should automatically be saved" (docs).

I executed the following code in a new notebook, then saved the notebook, closed Mathematica, and reopened the saved notebook directly by double-clicking on it. Mathematica warned me about possibly dangerous dynamic content; I chose to enable the dynamic content, after which the animation re-started from where it had been paused without a hitch:

h = 3;
f[x_] := x;

Animate[
  Graphics[Circle[{0, 0}, f[x]], PlotRange -> 3.6], {x, 0, h},
  SaveDefinitions -> True
]
MarcoB
  • 67,153
  • 18
  • 91
  • 189