From iterative to functional

Question

How to write this small piece in a functional way (ie. without state variables)?:

test[oldJ_List, newJ_List] := Total[Abs[oldJ - newJ]] > 1;
relax[j_List, x_?NumericQ] := Mean[Nearest[j, x, 4]];

j = Range[100]; (* any numeric list *)
j1 = j/2; (*some initial value for the While[] test to return True*)

While[test[j1, j],
 j1 = j; 
 (j[[#]] = relax[j, j[[#]]]) & /@ Range@Length@j]

test[] can also be defined as test[oldJ_List, newJ_List] := ManhattanDistance[oldJ, newJ] > 1. — J. M.'s missing motivation, Sep 30 '12 at 09:52

score 10 · Accepted Answer · answered Sep 29 '12 at 21:40

10

Let me first redefine your relax to return a list as:

Clear@relax1
relax1[j_List, i_Integer] := MapAt[Mean[Nearest[j, #, 4]] &, j, i]

Then, the algorithm can be written in a functional way without state variables using Fold and NestWhile as follows (if I understood your intentions correctly):

With[{indx = Range@Length@#}, NestWhile[Fold[relax1[#1, #2] &, #, indx] &, #, test, 2]] &@j

answered Sep 29 '12 at 21:40

rm -rf

88,781
21
293
472

2

Very nice! thanks! – Dr. belisarius Sep 29 '12 at 21:45
BTW. This is the first iterative structure I used in this answer. I'm still thinking about the second one – Dr. belisarius Sep 30 '12 at 03:21

kglr · Answer 2 · 2012-09-30T22:23:45.647

2

This also works:

fold = Function[{lst},Fold[(ReplacePart[#1, #2 ->relax[#1, #1[[#2]]]]) &, 
  lst,  Range@Length@lst]]; 
fxpnt = FixedPoint[fold, #, SameTest -> (Not[test[#1, #2]] &)] &;
fxpnt@j

edited Sep 30 '12 at 22:23

answered Sep 30 '12 at 21:59

kglr

394,356
18
477
896

nice! Why the N@? – Dr. belisarius Sep 30 '12 at 22:17
1

forgot to remove N (i was using it to simplify the printed output) ... removed now. – kglr Sep 30 '12 at 22:23
@belisarius, on second thought (and few limited timing tests with j=Range[1000]) it seems that N is actually cruical for speed. – kglr Sep 30 '12 at 23:04

From iterative to functional

2 Answers2