Get the coefficient matrix from a quadratic form

Question

Suppose I have a quadratic form of

qf = a x^2 + b y^2 + c z^2 + 2 d x y + 2 e x z + 2 f y z

How can I easily to get the symmetric matrix A, such that $X^TAX=qf$? where $X^T=(x,y,z)$.

I hope that the method will work for general quadratic form (i.e., for 2nd-homogenous polynomial of variable x,y,z,w,...)

I have tried the function CoefficientRules, but it seem there needs a step to transform the order of each term into the "position" of matrix.

score 22 · Answer 1 · edited Apr 13 '17 at 12:55

22

Here is a very short solution:

qf = a x^2 + b y^2 + c z^2 + 2 d x y + 2 e x z + 2 f y z;

1/2 D[qf, {{x, y, z}, 2}]
(* ==> {{a, d, e}, {d, b, f}, {e, f, c}} *)

This is just an application of the answer to Quick Hessian matrix and gradient calculation.

edited Apr 13 '17 at 12:55

Community

1

answered May 06 '16 at 05:39

Jens

97,245
7
213
499

1

Very slick! (+1) – Greg Hurst May 06 '16 at 05:54
1

@Jens neat +1 :) – ubpdqn May 06 '16 at 06:05
good idea (and trick)! – van abel May 06 '16 at 08:29
Can anyone explain to me the rationality of this answer ? – Tuong Nguyen Minh Jan 28 '21 at 07:59

xzczd · Accepted Answer · 2016-05-06T05:32:55.293

14

I think you need CoefficientArrays:

mat = Last@CoefficientArrays[qf, {x, y, z}, "Symmetric"->True];
{x, y, z}.mat.{x, y, z} == qf // Simplify
(* True *)

edited May 06 '16 at 05:32

answered May 06 '16 at 04:46

xzczd

65,995
9
163
468

1

I need mat be symmetric (and I re-edit the question). – van abel May 06 '16 at 04:57
4

Ok, I find the option "Symmetric" -> True, please update your answer? – van abel May 06 '16 at 05:01
2

@vanabel thank you for pointing out this option. Embarrassing ignorance. :) – ubpdqn May 06 '16 at 05:15
1

@vanabel Edited :) – xzczd May 06 '16 at 05:34

score 8 · Answer 3 · answered May 06 '16 at 05:08

Here is a way that yields symmetric matrix (for this example you could just write it down):

m=Module[{r = {x -> 1, y -> 2, z -> 3}, tu = Tuples[{x, y, z}, 2]},
 Normal@SparseArray[(## /. r) -> 
      Coefficient[qf, Times @@ ##]/(2 - Boole[#[[1]] === #[[2]]]) & /@
     tu, {3, 3}]]

yields:

{{a, d, e}, {d, b, f}, {e, f, c}}

Check:

Expand[{x, y, z}.m.{x, y, z}]

yields qf

CoefficientArrays as per @xzczd yields:

{{a, 2 d, 2 e}, {0, b, 2 f}, {0, 0, c}}

which is also a valid representation.

Get the coefficient matrix from a quadratic form

3 Answers3