How to get "one Cell - one line" code format inside of NB files?

Question

The PageWidth option controls the way the Cell's content is displayed, not the manner it's written in a .nb file. I wish to get a "one Cell - one line" representation (i.e., with no line breaking, a sort of PageWidth -> Infinity for the file). Is it possible?

This question arises from the necessity of ransacking in a large stack of notebooks by means of a strings search tool.

Answer 1

For producing a NB file without the line breaks you can Get it as a Notebook expression, then Export it with PageWidth -> Infinity as "Package" (other possible options does not work correctly: Export ignores PageWidth -> Infinity when exporting as "NB" and corrupts the code when exporting as "Text"):

Export["document.nb", Get["ExampleData/document.nb"], "Package", 
 PageWidth -> Infinity, "Comments" -> None]

This method is safe. Mathematica directly opens the generated file as a valid Notebook identical to the original Notebook. The only significant difference is that non-printable ASCII characters (excepting \b\t\n\r\f) are written "as is" when exporting as "Package", but in FullForm when exporting as "NB" (this difference doesn't affect the actual contents of the file when the latter is opened by the FrontEnd).

If you really need the "one Cell - one line" formatting you can simply add a line break before each Cell[ in the obtained string:

Export["document.nb", 
 StringReplace[
  ExportString[Get["ExampleData/document.nb"], "Package", PageWidth -> Infinity, 
   "Comments" -> None], c : "Cell[" :> "\n" <> c], "Text"]

A special note: this will affect all Cells including the Inline Cells (what may be undesirable but is safe). But the above code isn't safe in the sense that if your file contains textual strings with verbatim Cell[, they will also be modified. You can avoid this corruption by replacing the Head Cell in the Notebook expression with your own uniquely named Head before exporting:

Export["document.nb", 
 StringReplace[
  ExportString[Get["ExampleData/document.nb"] /. Cell -> $$$MyUniqueCellHead$$$, 
   "Package", PageWidth -> Infinity, "Comments" -> None], 
  "$$$MyUniqueCellHead$$$" -> "\nCell"], "Text"]

You can ensure that your Head is really unique by appending a random number to it:

With[{uniqName = "$$$MyUniqueCellHead$$$" <> ToString[RandomInteger[{10^8, 10^10}]]},
 Export["document.nb", 
  StringReplace[
   ExportString[Get["ExampleData/document.nb"] /. Cell -> Symbol[uniqName], "Package", 
    PageWidth -> Infinity, "Comments" -> None], uniqName -> "\nCell"], "Text"]]

This method is based on the well-documented and widely used functionality and hence should work reliably.

Here is how the obtained file looks in Notepad with word wrapping turned off:

---

04/19/2022 IMPORTANT UPDATE

In the recent versions of Mathematica (I tested 12.3.1 and 13.0.1) the Export[..., "Package"]/Put compatibility is partially broken for the "NB" format. The problem is that Export as "Package" and Put write Pattern[sym,obj] as sym:obj instead of Pattern[sym,obj] as it was in earlier versions. The syntax sym:obj is recognized by the FrontEnd as a syntax error when it opens a file as Notebook. I consider this as a bug. As a workaround, we can "protect" the Pattern head like we do above for Cell:

With[{uniqCellHeadName = 
   "$$$MyUniqueCellHead$$$" <> ToString[RandomInteger[{10^8, 10^10}]], 
  uniqPatternHeadName = 
   "$$$MyUniquePatternHead$$$" <> ToString[RandomInteger[{10^8, 10^10}]]}, 
 Export["document.nb", 
  StringReplace[
   ExportString[
    Get["ExampleData/document.nb"] /. {Cell -> Symbol[uniqCellHeadName], 
      Pattern -> Symbol[uniqPatternHeadName]}, "Package", PageWidth -> Infinity, 
    "Comments" -> None], {uniqCellHeadName -> "\nCell", 
    uniqPatternHeadName -> "Pattern"}], "Text"]]