Looking for a better way to delete an arbitrary list of rows from a matrix

Question

Delete is not suitable to delete the rows of a matrix, as illustrated below:

  SeedRandom[0];
; r = 100
; rows = RandomReal[{0, 1}, {r, 2}]
; toDrop = Select[Range[r], PrimeQ]
; reducedRows = Delete[rows, toDrop]

Mathematica graphics

I know that I can always do something like

  toKeep = Complement[Range[r], toDrop]
; reducedRows = rows[[toKeep]]

...but this strikes me as inefficient, at least whenever toKeep is large (IOW, whenever r is much greater than Length[toDrop]).

Is there any other built-in that achieves what Delete[rows, toDrop] aspires to?

Despite acknowledgement of Complement I feel that this problem is already described in other questions: (17002), (20228), (43785), (108336). Note that the answers below largely duplicate methods already given in answer to these. I shall probably mark this as a duplicate unless someone makes a compelling argument against that. — Mr.Wizard, May 20 '16 at 20:26
Also related (StackOverflow): Efficient way to pick/delete a list of rows/columns in a matrix in Mathematica — user1066, May 21 '16 at 14:29
It's already incorporated in kglr's answer; please vote for his instead. — J. M.'s missing motivation, May 21 '16 at 17:25

score 10 · Answer 1 · edited May 21 '16 at 13:54

10

Probably the simplest way will be:

reducedRows = ReplacePart[rows, Transpose[{toDrop}] -> Nothing[]]

edited May 21 '16 at 13:54

faysou

10,999
3
50
125

answered May 20 '16 at 19:21

ciao

25,774
2
58
139

I believe you need to do List /@ toDrop -> Nothing[]. (Cant verify with 10.1 though) – george2079 May 20 '16 at 20:01
1

@george2079 - oops, copied wrong - fixed (Transpose faster than map List) – ciao May 20 '16 at 20:05
3

(+1) because I've learned Nothing. – Jens May 20 '16 at 21:25
I didn't know Nothing as well, I was using ##&[] instead. I'll do a find and replace in all my code ! – faysou May 21 '16 at 13:45
2

I fixed the Transpose correction. Also you don't need Nothing[], Nothing only works. – faysou May 21 '16 at 13:54

kglr · Accepted Answer · 2016-05-21T12:47:35.893

Make the to-be-dropped rows vanish:

rows[[toDrop]] = ##&[]

or as a function:

f = Module[{m = #, d = #2}, m[[d]] = ##&[]; m] &;

f[rows, toDrop]

Some timings

ClearAll[f0, f1, f2, f3, f4, f5]
f0 = ReplacePart[#, Transpose[{#2}] -> Nothing[]]&; (* ciao's answer *)
f1 = ReplacePart[#, Thread[#2 -> Sequence[]]] &; (* v9 version of ciao's answer*)
f2 = Module[{m = #, d = #2}, m[[d]] = ## &[]; m] &;
f3 = #[[Complement[Range@Length@#, #2]]] &; (* from george2079's deleted answer*)
f4 = Delete[#, Transpose[{#2}]] &; (* from ciao's comment *)
f5 = Delete[#, List /@ #2] &; (* from J.M.'s comment *)


SeedRandom[0];
r = 1000000;
rows = RandomReal[{0, 1}, {r, 2}];
toDrop = Select[Range[r], PrimeQ];
{HoldForm[#], First[AbsoluteTiming[#[rows, toDrop]]]} & /@ {f0, f1, f2, f3, f4, f5} // Grid

Equal @@ (#[rows, toDrop] & /@ {f0, f1, f2, f3, f4, f5})

True

score 2 · Answer 3 · answered May 21 '16 at 01:35

2

A solution that keeps instead of drops.

toKeep = Select[Range[r], PrimeQ /* Not];
reducedRows = rows[[toKeep]];

Hope this helps.

answered May 21 '16 at 01:35

Edmund

42,267
3
51
143

Looking for a better way to delete an arbitrary list of rows from a matrix

3 Answers3