Are there more readable and terse method can get this list

Question

I have a list like following

list = {{1, 2, 3, 4, 5}, {6, 7, 8, 9, 10}};

I want get this list by a more better method:

I don't care the ordering of its elements.This is my current method.I'm missed in cloud when I manage to write it.

Flatten[MapThread[
  Distribute[List[##], List, List, List, UndirectedEdge] &, {{a, b}, 
   list}]]

{a<->1,a<->2,a<->3,a<->4,a<->5,b<->6,b<->7,b<->8,b<->9,b<->10}

Join@@ MapThread[Thread[#1 <-> #2] &, {{a, b}, list}] or Flatten or Catenate to flatten list — ubpdqn, Jun 13 '16 at 06:36
@ubpdqn Can you make it as a answer?I think it is a better solution than me. — yode, Jun 13 '16 at 06:39

J. M.'s missing motivation · Accepted Answer · 2016-06-13T11:56:51.083

14

Since it hasn't been proposed yet:

Inner[UndirectedEdge, {a, b}, {{1, 2, 3, 4, 5}, {6, 7, 8, 9, 10}}, Sequence]

{a <-> 1, b <-> 6, a <-> 2, b <-> 7, a <-> 3,
 b <-> 8, a <-> 4, b <-> 9, a <-> 5, b <-> 10}

(You did say that "I don't care (about) the ordering of its elements"! ;))

edited Jun 13 '16 at 11:56

answered Jun 13 '16 at 11:36

Wonderful!I have to say this is a magic to me.It is exact what I want. – yode Jun 13 '16 at 11:53
Inner is such a nice function. Neat :) – ubpdqn Jun 13 '16 at 12:04
1

Inner is certainly one of my favorite underused functions. +1 – rcollyer Jun 13 '16 at 17:16

ubpdqn · Answer 2 · 2016-06-13T07:31:36.873

11

As per request:

Join@@ MapThread[Thread[#1 <-> #2] &, {{a, b}, list}]

Flatten or Catenate to flatten list result from MapThread.

See comment by Kuba below.

edited Jun 13 '16 at 07:31

answered Jun 13 '16 at 06:41

ubpdqn

3

V10 style: Thread@*UndirectedEdge – Kuba Jun 13 '16 at 07:27
Or maybe can simplfy it to Flatten[Thread/@Thread[{a,b}<->list]] – yode Jun 13 '16 at 07:29
@Kuba I always compose :( – ubpdqn Jun 13 '16 at 07:31
I'm sorry to change the choice.But the J.M. 's answer seem to more flexible.Thank again. – yode Jun 13 '16 at 12:00
@yode it is your choice. Thank you for alerting me to J.M.'s answer so I can learn also. – ubpdqn Jun 13 '16 at 12:02
@Kuba what does the @* do? it's... a little tough to search for... – Ben Kalziqi Jun 14 '16 at 01:29
@BenKalziqi Equal to Composition. – yode Jun 14 '16 at 02:44

score 6 · Answer 3 · answered Jun 13 '16 at 07:48

6

How about:

{a, b} + list /. a_ + b_ :> a <-> b // Flatten

answered Jun 13 '16 at 07:48

xzczd

1

Or maybe UndirectedEdge@@@Flatten[{a,b}+list].Thanks a lot. – yode Jun 13 '16 at 07:51
2

@yode Or even terser: # <-> #2 & @@@ Flatten[{a, b} + list] – xzczd Jun 13 '16 at 08:03
Well,feel pity that I cannot upvote it again. :) – yode Jun 13 '16 at 08:22

kglr · Answer 4 · 2016-06-14T01:06:02.210

3

♭ = ## & @@ (♯  #1 <-> ♯) /@ #2 & @@@ ({##}) &

♭[{a, b}, list]

or

♭2 = #2 <-> # & @@@ (## & @@@ +##) &;
♭2[{a, b}, list]

edited Jun 14 '16 at 01:06

answered Jun 13 '16 at 23:45

kglr

Upvote for such proficiency in using pure function. :) – yode Jun 14 '16 at 02:47

4 Answers4