Control of individual Framed edges?

Question

Is there an option or method for Framed analogous to Frame in Graphics to control display of individual edges, eg bottom, left, top, right?

Framed is useful for visualizing nested structures, but often 4 sides are redundant, eg in this healthcare related prototype would like to display only the left edges:

If not an option, is there a workaround that does not explicitly involve Graphics?

In version 8, it used to be possible to do something like this, see this question and answer. Unfortunately, it no longer works in version 10. — Jens, Jun 23 '16 at 04:50

score 8 · Accepted Answer · answered Jun 23 '16 at 04:29

8

Would a CellFrame around a TextCell work?

Framed[
 x -> TextCell[
   Column[{"Depression", "PTSD", "Diabetes Type II", "Smoker"}], 
   "Text",
   CellFrame -> {{True, False}, {False, False}}]]

Mathematica graphics

answered Jun 23 '16 at 04:29

Michael E2

235,386
17
334
747

Great, is it possible to control line width? – alancalvitti Jun 29 '16 at 21:12
@alancalvitti Harder than I thought, given that CellFrameStyle shows up in the option inspector: System`CellFrameStyle -> {{AbsoluteThickness[12], None}, {None, None}} yields this. Note that (on V10.4.1) CellFrameStyle is not already in the System` context and Global`CellFrameStyle won't work. -- Just checked and "CellFrameStyle" -> {{AbsoluteThickness[12], None}, {None, None}} also works. – Michael E2 Jun 29 '16 at 21:22

score 8 · Answer 2 · answered Jun 23 '16 at 05:22

An alternative way of getting a similar display would be to define a new function leftFramed that only puts a vertical extensible line to the left of the content:

leftFrame /: MakeBoxes[leftFrame[obj_], _] := 
 RowBox[{"\[LeftBracketingBar]", ToBoxes[obj]}]

Framed[x -> 
  leftFrame[
   Column[{"Depression", "PTSD", "Diabetes Type II", "Smoker"}]]]

You can see that this vertical line is in fact an extensible character, not a graphical line.

In the same vein, you could also use other extensible symbols to decorate the left side:

leftBrace /: MakeBoxes[leftBrace[obj_], _] := 
 StyleBox[RowBox[{"{", ToBoxes[obj]}], SpanMaxSize -> Infinity]

Framed[x -> 
  leftBrace[
   Column[{"Depression", "PTSD", "Diabetes Type II", "Smoker"}]]]

Jens, yours is a nice approach too, I will likely use it as well, but accepted Michael E2 because TextCell seems easier more user friendly. — alancalvitti, Jul 13 '16 at 19:50

Control of individual Framed edges?

2 Answers2