Calculate mean and standard deviation from ImageHistogram

Question

I am doing my PhD in Clinical Neuropsychology; I had someone helping me analyse images (.jpg pictures) in Mathematica, but it turns out this person made some really bad decisions, and well, now I have to do it myself. But, I have no idea.

Basically, what I want is to analyze the JPEG image, get a RGB histogram, and get the values for the mean and standard deviation of this histogram.

Using ImageHistogram [[*image*], Appearance, -> "Separated"] works fine, but I can't figure out the next step, turning the histogram plot into numbers.

How can I do that?

Thank you for helping!

You could use ImageData[] to get the values being binned for the histograms... — J. M.'s missing motivation, Oct 12 '12 at 13:27
Hmmm... it says A very large out put was generated, here is a sample of it. "{0., 0., 0.}, {0., 0., 0.}, {0., 0., 0.}," — onemonkey, Oct 12 '12 at 13:33
And if I input: StandardDeviation[Out[37]] I get pretty much the same result. — onemonkey, Oct 12 '12 at 13:34
Try something like : image = ExampleData[{"TestImage", "Lena"}]; data = ImageData[image]; {Mean[#], StandardDeviation[#]} & /@ Transpose[Flatten[data, 1]]. — b.gates.you.know.what, Oct 12 '12 at 13:46
Is it necessary to to get the metrics of the bins or is it sufficient to get the metrics of the RGB values themselves, un-binned, as Murta's answer does? — Mr.Wizard, Oct 12 '12 at 15:22

Murta · Answer 1 · 2012-10-12T14:03:07.410

7

There is one suggestion.

img = ExampleData[{"TestImage", "Lena"}];
imgChannelsRGB = Transpose@Flatten[ImageData[img], 1];

Creating Histogram:

GraphicsRow[Histogram /@ imgChannelsRGB, ImageSize -> 500]

enter image description here

Geting statistics:

TableForm[Through[{Mean, StandardDeviation}[#]] & /@ imgChannelsRGB, 
 TableHeadings -> {{"Red", "Blue", "Green"}, {"Mean", "StDev"}}]

enter image description here

edited Oct 12 '12 at 14:03

answered Oct 12 '12 at 13:53

Murta

26,275
6
76
166

Alternatively: imgChannelsRGB = Flatten /@ ImageData[img, Interleaving -> False]. The Lenna example image is easily accessed as ExampleData[{"TestImage", "Lena"}]. – J. M.'s missing motivation Oct 12 '12 at 14:00
Nice tip. Changed the example. – Murta Oct 12 '12 at 14:03
Am trying it right now! – onemonkey Oct 12 '12 at 14:09
O wow, this is very promissing! I'm going to play with this (and then I might be back). Thnx! – onemonkey Oct 12 '12 at 14:43
You could use ImageData[img] ~Flatten~ {{3}, {1, 2}} in place of Transpose@Flatten[ImageData[img], 1], eliminating Transpose. – Mr.Wizard Oct 12 '12 at 15:19
Hi @Mr.Wizard, nice tip, but i think it makes the code really difficult to read. Few people understands Flatten matrix argument (explained in http://mathematica.stackexchange.com/questions/119/flatten-command-matrix-as-second-argument) – Murta Oct 12 '12 at 15:51
@Murta -- I hoped my comment would help people learn that syntax but I agree with your choice to use Transpose in the answer. – Mr.Wizard Oct 12 '12 at 17:12

cormullion · Answer 2 · 2012-10-13T08:43:31.370

3

I thought it might be interesting to combine the graphs and statistics in small multiple style, but I got stuck... How do you present two numbers as a label without showing the curly brackets?

small multiple

Code:

{r, g, b} = ColorSeparate[img];
Row[
 Labeled[
    ImageHistogram[#, Appearance -> "Transparent",  Joined -> False, 
     Frame -> None],
    {
     Mean[Flatten[ImageData[#]]],
     StandardDeviation[Flatten[ImageData[#]]]
     },
    ImageSize -> 200
    ] & /@ {r, g, b}
 ]

Edit with bill (?!)'s suggestion:

GraphicsRow[
 Labeled[
    ImageHistogram[#, Appearance -> "Transparent", Joined -> False, 
     Frame -> None],
    Style[
     Column[
      {
       Mean[Flatten[ImageData[#]]],
       StandardDeviation[Flatten[ImageData[#]]]
       }
      ], 
     14, Bold], 
    ImageSize -> 500
    ] & /@ {r, g, b}]

better small multiple

edited Oct 13 '12 at 08:43

answered Oct 12 '12 at 19:16

cormullion

24,243
4
64
133

1

Maybe add a Column ? Row[Labeled[ ImageHistogram[#, Appearance -> "Transparent", Joined -> False, Frame -> None], Column[{Mean[Flatten[ImageData[#]]], StandardDeviation[Flatten[ImageData[#]]]}], ImageSize -> 200] & /@ {r, g, b}] – b.gates.you.know.what Oct 12 '12 at 19:26
@b.gatessucks Good idea! As usual, your comments are better than my answers! :) – cormullion Oct 12 '12 at 19:30
Wow! I have been getting some help from a friend, and we will definitely come back to this! – onemonkey Oct 15 '12 at 09:46
OK, so we are on a roll, but now I have a new, buyt related qustion. Should i post it here or open a new topic? – onemonkey Oct 19 '12 at 08:54

Calculate mean and standard deviation from ImageHistogram

2 Answers2

Linked