How to transform the $y$ values in a list of $(x,y)$ pairs

Question

How can I transform

data = {{1, 0}, {0, 1}, {1, 1}}

to

{{1, f[0]}, {0, f[1]}, {1, f[1]}}

---

This is similar to Applying a function to the second element of a list and another way to do this mapping of a two argument function, but it's not the same question

Answer 1

{#1, f@#2} & @@@ data

But we can also generalize MapAt to do the job: Note that

MapAt[f, data, {1, 2}] === {{1, f[0]}, {0, 1}, {1, 1}}

So we can use

MapAtP[f_, expr_, positionPattern_] := MapIndexed[
  If[MatchQ[#2, positionPattern], f@#1, #1] &, expr, Infinity]

MapAtP[f, data, {_, 2}]

---

Aside

David Wagner's “Power programming with Mathematica”

Are you interested in purchasing David Wagner's "Power programming with Mathematica"?

mentions the following idiom as "a more Mathematica-like way" to transform on the values of a list of (x,y) data points.

data = {{1, 0}, {0, 1}, {1, 1}};
data /. {x_, y_} -> {x, f@y}
(**)
{{1, f[1]}, {0, f[0]}, {1, f[1]}}

But it fails with lists of length exactly 2:

data = {{1, 0}, {0, 1}};
data /. {x_, y_} -> {x, f@y}
(**)
{{1, 0}, f[{1, 0}]}

Answer 2

data = {{1, 0}, {0, 1}};
data /. {x_?NumericQ, y_?NumericQ} :> {x, f@y}

and

data = {{1, 0}, {0, 1}};
MapAt[f, data, {All, 2}]

will fix the problems mentioned by masterxilo's answer