How can I make a lists of pairs out of two lists of triples?

Question

I want to use this expression for my computation:

FoldList[vt[#2[[1]], #1, #2[[2]], b] &, v0,
Transpose[Join[{ea, cm}]]]

My problem now is that ea and cm is not only one list each it is a set of lists. How can I make a list of pairs out of these two set of lists?

For example:

ea = {{5, 6, 7}, {1, 2, 3}, {4, 8, 9}} 
cm = {{1, 2, 3}, {4, 5, 6}, {7, 8, 9}}

and i want a list of pairs of these lists but again in one list each like these:

eacm = 
  {{{5, 1}, {6, 2}, {7, 3}}, {{1, 4}, {2, 5}, {3, 6}}, {{4, 7}, {8, 8}, {9, 9}}}

My real lists are longer than those shown above. I have 720 numbers in each list.

score 11 · Accepted Answer · answered Jul 16 '16 at 23:19

11

Transpose[{ea, cm}, {3, 1, 2}]

Flatten[{ea, cm}, {{2}, {3}, {1}}]

answered Jul 16 '16 at 23:19

Hotoke

156
1
2

Ok but i will have the problem that i will have 10.000 lists i a row because i am doing a monte carlo simulation – user41673 Jul 16 '16 at 23:38
sorry you couldn´t know but thank you very much for your solution – user41673 Jul 16 '16 at 23:39
7

@user41673. I don't see how having two lists of 10000 triples invalidates this answer. – m_goldberg Jul 17 '16 at 00:10
A very interesting explanation about Transpose second argument here -> 16968 – Murta Jul 18 '16 at 00:51

m_goldberg · Answer 2 · 2016-07-17T10:52:21.580

This is not an answer, but an extended comment on Hotoke's answer.

The OP seems to think Transpose isn't applicable when ea and cm are very long lists, say, of 10000 triples each. Perhaps the OP thinks it would be very slow is such a case. But actually it is very fast even for long lists, as I will demonstrate here.

SeedRandom[42];
With[{n = 10000, k = 12},
  Module[{m, mt, t},
    m = RandomInteger[42, {2, n, 3}];
    t = AbsoluteTiming[mt = Transpose[m, {3, 1, 2}]][[1]];
    {t, Column[{#, mt[[#]]} & /@ RandomSample[Range[n], k]]}]]

It still works well even if the sublists are longer. Here is example with 5-tuples.

SeedRandom[42];
With[{n = 10000, i = 5, k = 8},
  Module[{m, mt, t},
    m = RandomInteger[42, {2, n, i}];
    t = AbsoluteTiming[mt = Transpose[m, {3, 1, 2}]][[1]];
    {t, Column[{#, mt[[#]]} & /@ RandomSample[Range[n], k]]}]]

That's some hardcore localization you got going on there ;)) — e.doroskevic, Jul 17 '16 at 00:24

score 5 · Answer 3 · answered Jul 17 '16 at 07:47

5

Does it fit your needs?

MapThread[List, {ea, cm}, 2]

answered Jul 17 '16 at 07:47

Kuba

136,707
13
279
740

score 2 · Answer 4 · answered Jul 17 '16 at 00:06

2

Example

Transpose @ # & /@ Transpose[{ea, cm}]

Note: ea and cm same as in original post

answered Jul 17 '16 at 00:06

e.doroskevic

5,959
1
13
32

Murta · Answer 5 · 2016-07-18T00:46:23.140

2

Transpose second argument is like magic/cryptic for me. Here is another option using Map:

Map[Transpose, Transpose@{ea, cm}, {-3}]

edited Jul 18 '16 at 00:46

answered Jul 17 '16 at 02:30

Murta

26,275
6
76
166

How can I make a lists of pairs out of two lists of triples?

5 Answers5