Restrictions on variables of two functions in order to be larger and smaller relative to each other

Question

I have two functions

  f1[x_, y_] := -1 + x - Sqrt[8 + x^2 + (1 - x) (1 + x)];
  f2[x_, y_] := -1 - x - Sqrt[8 y^2 + (1 - 3 x) (1 - x) + x^2];

I am searching the restriction and the relation between x and y in which f1 > f2. Also other condition in which f1<f2. But unfortunately I don't know what function must be used.

Answer 1

re = Reduce[f1[x, y] < f2[x, y], {x, y}, Reals]
Reduce[f1[x, y] > f2[x, y], {x, y}, Reals]

x < 1 && -Sqrt[1 - x] < y < Sqrt[1 - x]

(x <= 1 && (y < -Sqrt[1 - x] || y > Sqrt[1 - x])) || x > 1

Edit: You can also directly plot the reduced result.

RegionPlot[re, {x, -10, 5}, {y, -5, 5}, ImageSize -> Small]

Answer 2

By trial and error, if we plot

    Plot3D[{f1[x, y], f2[x, y]}, {x, -2, 2}, {y, -2, 2}]

we see that

 x== 1-y^2 

is the boundary?

   ContourPlot[{f1[x, y] == f2[x, y], x == 1 - y^2}, {x, -2, 2}, {y, -2, 2}, 
   ContourStyle -> {, Dashed}]

Indeed

 eq = f1[x, y]^2 == f2[x, y]^2 // FullSimplify

 eq /. x -> 1 - y^2 // FullSimplify // PowerExpand

(* True *)

Answer 3

Given

f1[x_, y_] := -1 + x - Sqrt[8 + x^2 + (1 - x) (1 + x)];
f2[x_, y_] := -1 - x - Sqrt[8 y^2 + (1 - 3 x) (1 - x) + x^2];

we have a solution for f1[x, y] > f2[x, y]

CylindricalDecomposition[f1[x, y] > f2[x, y], {y, x}]
(* x > 1 - y^2 *)

CylindricalDecomposition is well worth investigating if you need to analyse inequalities.