How to get the better coordinate to position a text in the graphic

Question

I created a graphic to obtain a triangle with three vertices.

The code is as follows:

a = {4, 2, 1}; b = {1, 0, 1}; c = {1, 2, 0};

Graphics3D[{
Text[Style["A", Large, Bold, Red], {4.28, 2.09, 1.05}],
Text[Style["B", Large, Bold, Red], {0.86, -0.25, 1.08}],
Text[Style["C", Large, Bold, Red], {0.81, 2.18, -0.15}],
Blue,
PointSize[.05], Point[a], Point[b], Point[c],
Black,
Line[{a, b, c, a}]
}]

You may notice that I put the texts as I wanted, but I managed through the following procedure below from other software.

If I could be objective. What are the steps to achieve this result through the Mathematica?

p.s. Thx for an accept, though it is a good habit to hold on with it a day or two to not discourage others. You can use gray triangles to upvote answers you find useful. — Kuba, Aug 26 '16 at 18:32

Kuba · Accepted Answer · 2016-08-26T18:15:06.750

r=.3;

Graphics3D[{
  MapThread[
    With[{w = Normalize[Normalize[#2 - #1] + Normalize[#3 - #1]]},
       Text[Style[#4, Large, Bold, Black], #1 - r w]
    ] &, 
    N @ {{a, b, c}, {b, c, a}, {c, a, b}, {"A", "B", "C"}}
  ],
  Blue, PointSize[.05], Point[a], Point[b], Point[c], Black, 
  Line[{a, b, c, a}]},
 BoxRatios -> Automatic, Axes -> True]

Let's create something more general:

LabeledPolygon[
   labels_List, r_, p : Polygon[pts_List, ___]
] /;  Length[labels] == Length[pts] := {
  MapThread[
     With[{w = Normalize[Normalize[#2 - #1] + Normalize[#3 - #1]]},
        Text[Style[#4, Large, Bold, Black], #1 - r w]
     ] &, 
     N @ Append[NestList[RotateLeft, pts, Length[pts] - 1], labels]
  ], 
  p
}

and now:

Graphics3D[{
  Blue, PointSize[.05], Point[{a, b, c}],
  FaceForm[None], EdgeForm[Black], 
  LabeledPolygon[{"A", "B", "C"}, .3, Polygon[{a, b, c}]]
}]

works the same.

How to get the better coordinate to position a text in the graphic

1 Answers1