2

How would I tell Mathematica to evaluate something like

\begin{align*} \exp\left[\int_a^b dx\right]f(x)\equiv f(x)+\int_a^b f(x)dx+\frac{1}{2!}\int_a^b\int_0^{x}f(x')dx'dx+\frac{1}{3!}\int_a^b\int_0^{x}\int_0^{x'}f(x'')dx''dx'dx+\cdots \end{align*}

If $f(x)$ was a polynomial, then this would be straightforward, for each integral would be known and the function of Sum could then be used. However, in general, $f(x)$ will not be that simple. I was thinking that a similar method to the one described in Application of # for the $n^{th}$ derivative could be used, but I am not sure how to apply it for integrals.

If Mathematica is unable to do the exponential of the integral operator, is it possible to compute the series expansion up to a specified term?

Community
  • 1
user85503
  • 992
  • 1
  • 9
  • 22
  • 1
    Because f is a function of the innermost variable only, it should be possible systematically to interchange the order of integration, one level at a time, to collapse all integrals in each term of the series into a single integral, multiplied by a polynomial in a and b. Once the general term has been obtained (inductively), the series probably can be summed. Unfortunately, Integrate apparently cannot handle this process automatically. – bbgodfrey Aug 31 '16 at 22:29
  • Repeated integrals of the form you are using can be written as a single integral. I think that symbolic manipulation can greatly simplify this. – mikado Sep 01 '16 at 05:01
  • http://mathworld.wolfram.com/RepeatedIntegral.html gives a useful result – mikado Sep 01 '16 at 05:29
  • I am not sure to have correctly understood your need, but is this expOp = Exp[Integrate[#, {x, a, b}]] & not what you are looking for? This expOp[x] gives E^(-(a^2/2) + b^2/2) and this expOp[Cos[x]^2] yields E^(1/2 (-a + b - Cos[a] Sin[a] + Cos[b] Sin[b])) ?? – Alexei Boulbitch Sep 01 '16 at 06:56
  • 1
    Are you looking for a numerical solution? Then one could adapt my answer here, because this is essentially the Picard iteration except for the factorials. – Jens Sep 03 '16 at 16:11
  • Speaking of Picard iteration, maybe that's what you're actually after. Are you trying to solve a differential equation? Then you have to include a time ordering operation and the factorials go away, making this a duplicate of the problem I linked to earlier. – Jens Sep 03 '16 at 16:16

1 Answers1

1

Let us start by defining 3 alternative ways of performing the multiple integral

int1[f_, x_, 0] = f[x];
int1[f_, x_, n_] := Integrate[int1[f, u, n - 1], {u, 0, x}]
int2[f_, x_, n_] := Derivative[-n][f][x]
int3[f_, x_, 0] = f[x];
int3[f_, x_, n_] := Integrate[f[u] (x - u)^(n - 1)/(n - 1)!, {u, 0, x}]

The first corresponds to a direct iteration of the integral, the second use of the antiderivative properties of Derivative and the third exploits the transform given at http://mathworld.wolfram.com/RepeatedIntegral.html To test the behaviour of these apply them to Sin. We see that the first and third agree, whereas the second does not handle the end conditions correctly.

Table[Through[{int1, int2, int3}[Sin, x, i]], {i, 0, 3}] // 
  Expand // InputForm

(* {{Sin[x], Sin[x], Sin[x]}, {1 - Cos[x], -Cos[x], 
  1 - Cos[x]}, {x - Sin[x], -Sin[x], 
  x - Sin[x]}, {-1 + x^2/2 + Cos[x], Cos[x], -1 + x^2/2 + Cos[x]}} *)

The integral of interest takes the form

Sum[a[i] int[f, x, i], {i, 0, ∞}];

using the repeated integral expression we have

% /. u_int :> int3 @@ u // InputForm
(* Sum[a[i]*Integrate[((-u + x)^(-1 + i)*f[u])/(-1 + i)!, {u, 0, x}], {i, 0, Infinity}] *)

which can be rewritten

Integrate[
  f[u]*Sum[a[i]*((-u + x)^(-1 + i)/(-1 + i)!), {i, 0, Infinity}], {u, 
   0, x}];

substituting for the required expression we get

% /. a[i_] -> 1/i! // InputForm
(* Integrate[(BesselI[1, 2*Sqrt[-u + x]]*f[u])/Sqrt[-u + x], {u, 0, x}] *)
mikado
  • 16,741
  • 2
  • 20
  • 54