Change integration variable

Question

Are there any automated procedures to change integration variables? For example by changing Sin[u]->x, I can change

Integrate[f[Sin[u]], {u, 0, Pi/2}]

into

Integrate[f[x]/Sqrt[1 - x^2], {x, 0, 1}]

Possible duplicate of Is there a way to rewrite integrals in Mathematica using u substitution? — xzczd, Jun 29 '22 at 06:33

glS · Accepted Answer · 2021-04-19T07:52:17.553

13

Here is a possibly quite naive implementation:

changeVariables[expr_, oldVar_, changeFunc_, newVar_, interval_] := With[{
    inverse = InverseFunction @ changeFunc,
    der = D[changeFunc @ oldVar, oldVar]
  },
  {
    (expr /. changeFunc @ oldVar -> newVar) / (
      der /. oldVar -> inverse @ newVar
    ),
    {newVar, changeFunc @ interval[[1]], changeFunc @ interval[[2]]}
  }
]

which gives the expected result, in at least simple circumstances:

Of course, as the warning reminds us, this method uses inverse functions and may, therefore, give incorrect results in some circumstances. Already in my second example had I used as integration interval $(-\infty,\infty)$ I would have got a wrong result.

edited Apr 19 '21 at 07:52

answered Sep 03 '16 at 16:27

glS

7,623
1
21
61

1

Mathematica will rarely (if ever) change the variable of integration in integrals it cannot evaluate. Your function could be very useful in such cases. Thanks – mikado Sep 03 '16 at 16:34
2

Very useful function.+1 – tanghe2014 May 01 '20 at 11:18

xzczd · Answer 2 · 2022-06-29T06:34:36.850

In v13.1 IntegrateChangeVariables is introduced:

IntegrateChangeVariables[Inactive[Integrate][f[Sin[u]], {u, 0, Pi/2}],
  x, x == Sin[u]]
(* Inactive[Integrate][f[x]/Sqrt[1 - x^2], {x, 0, 1}] *)

But this function is still marked as EXPERIMENTAL and a bit fragile, so, watch your step :) :

(* This gives incorrect result: *)
IntegrateChangeVariables[Inactive[Integrate][f[Sin[u]], {u, 0, Pi/2}], 
  x, Sin[u] == x]
(* Inactive[Integrate][f[Sin[x]], {x, 0, π/2}] *)

score 3 · Answer 3 · answered May 14 '21 at 09:24

Sorry, not allowed to comment on glS' answer. I found the following useful, which builds a rule to change variables in (all!) integrals, building on changeVariables above:

changeVariableRule[changeFunc_, 
  newVar_] := (Integrate[expr_, {x_, start_, stop_}] :> 
   Integrate @@ 
    changeVariables[expr, x, changeFunc, newVar, {start, stop}])

Change integration variable

3 Answers3

Linked