A simple plot returns empty, even though specific points values exist

Question

I'm in a bit of a pickle:

I try to plot a graph of a simple function, and for some reason unknown to me, it is drawn blank even though evaluation of the function at specific points returns the required values. My code is as follows:

A = 0.1;
B = 0.11;
CParam[x_] :=  BesselK[2, A/x] BesselI[0, B/x] + BesselI[2, A/x] BesselK[0, B/x];
Plot[Log[Log[-CParam'[x]]], {x, 10^-8, 10^-5}]

However, typing {Log[Log[-CParam'[10^-5]]], Log[Log[-CParam'[10^-6]]], Log[Log[-CParam'[10^-7]]], Log[Log[-CParam'[10^-8]]]} returns {6.91618835667271168, 9.211416996515317434, 11.5130562034263446895, 13.81552593513862411174}.

Why doesn't Plot work properly?

Thanks

try LogLinearPlot, and try manually specifying PlotRange — george2079, Oct 24 '16 at 11:25
you also may need to do Plot[Evaluate[expression],..] because of the derivative — george2079, Oct 24 '16 at 11:30
Seems to be a bug. Try ListLinePlot@ Table[Log[Log[-CParam'[x]]], {x, Subdivide[10^-8, 10^-5, 100]}] (I'm on V11.0.0.) — Michael E2, Oct 24 '16 at 12:31
Thanks @MichaelE2. That did it - I think I would use that in other places as well. — EZLearner, Oct 24 '16 at 12:40
Works fine under "10.4.1 for Linux x86 (64-bit) (April 11, 2016)". — corey979, Oct 24 '16 at 13:29

score 3 · Accepted Answer · answered Oct 24 '16 at 13:15

I think this is a bug in Plot[].

Aside from making a table and ListPlot-ing it, such as in my comment,

ListLinePlot@ Table[Log[Log[-CParam'[x]]], {x, Subdivide[10^-8, 10^-5, 100]}]

one could use NDSolve to get adaptive sampling:

ListLinePlot@
 NDSolveValue[{y[x] == Log[Log[-CParam'[x]]], z'[x] == 1, 
   z[10^-8] == 0}, y, {x, 10^-8, 10^-5}, PrecisionGoal -> 3]

Mathematica graphics

Adaptive sampling is not needed here, but in an oscillatory function, it could be helpful, should Plot[] fail as in this case.

Options[adaptiveListLinePlot] = Options[ListLinePlot];
adaptiveListLinePlot[f_, {x_, a_, b_}, opts : OptionsPattern[]] :=
  Module[{y, z, a1, b1},
   {a1, b1} =              (* open sampling *)
    Rescale[{Sqrt@$MachineEpsilon, 1 - Sqrt@$MachineEpsilon}, {0, 1}, {a, b}]; 
   ListLinePlot[
    NDSolveValue[{y[x] == f, z'[x] == 1, z[a1] == 0}, y, {x, a1, b1}, PrecisionGoal -> 3],
    opts]
   ];

adaptiveListLinePlot[Sin[x^2], {x, 0, 20}]

Mathematica graphics

score 1 · Answer 2 · answered Oct 24 '16 at 12:48

I can verify the comment of @Michael E2 as I ran into the same problem with LogPlot on Version 11.0. The solution he suggested worked for me by extracting the calculation from inside Plot into Table. So for your problem it works like this:

A = 0.1;
B = 0.11;
CParam[x_] := BesselK[2, A/x] BesselI[0, B/x] + BesselI[2, A/x] BesselK[0, B/x];
stepIncrement = 10^(-8);
data = Table[Log[Log[-CParam'[x]]], {x, 10^-8, 10^-5, stepIncrement}];
ListPlot[data]

Choose the value of stepIncrement to a value that fulfills your requirements regarding precision.

A simple plot returns empty, even though specific points values exist

2 Answers2

Linked