Gaps in curves from ParametricPlot

Question

Why do I get gaps in my plots below? Looking at this post suggests that using Exclusions-> None should fix the problem if there is a discontinuity. However there is no discontinuity in my case. So why do I get the gaps? Using Exclusions-> None does fix the problem so it must be a similar but different problem.

Module[{H, Ha, A = 0.015, α = 4, β, γ = 0.001},
 H[β_] := (
  E^(-2 π α (I β + γ)) (-I E^(
      2 π α (I β + γ)) (β - 
        I γ) + (I β + γ) Cos[2 π α] - 
     Sin[2 π α]))/(-1 + β^2 - 
   2 I β γ - γ^2);
 Ha[β_] := 
  A (I β + γ)/(1 - (β - I γ)^2);

 pp = ParametricPlot[{ReIm@Ha[β], ReIm@H[β]}, {β, 0,
     2},
   ImageSize -> 11 72, PlotRange -> All
   ]

 ]

Note that there is a gap in the yellow curve near the horizontal axis as well as the obvious one in the blue curve.

To look more closely I did

Length@Cases[pp, _Line, ∞]
(* 4 *)

This shows that the blue and yellow curves have been each been split up into two sections. I thought it might be due to the course sampling but increasing the PlotPoints to 200 still leaves a gap in the blue curve.

Now with Exclusions-> None added I get a good result and there are now just two lines as expected.

Module[{H, Ha, A = 0.015, α = 4, β, γ = 0.001},
 H[β_] := (
  E^(-2 π α (I β + γ)) (-I E^(
      2 π α (I β + γ)) (β - 
        I γ) + (I β + γ) Cos[2 π α] - 
     Sin[2 π α]))/(-1 + β^2 - 
   2 I β γ - γ^2);
 Ha[β_] := 
  A (I β + γ)/(1 - (β - I γ)^2);

 pp = ParametricPlot[{ReIm@Ha[β], ReIm@H[β]}, {β, 0,
     2},
   ImageSize -> 11 72, PlotRange -> All, Exclusions -> None
   ]

 ]

So why do I get the gaps?

Answer 1

You need to increase the number of PlotPoints to get a smooth curve and use the option Exclusions to force evaluations close to the exclusion points (i.e., close the gaps).

Module[
 {H, Ha, A = 0.015, α = 4, β, γ = 0.001},
 H[β_] :=
  (E^(-2 π α (I β + γ)) (-I E^(2 π α (I β + γ)) (β - I γ) +
       (I β + γ) Cos[2 π α] - Sin[2 π α]))/
   (-1 + β^2 - 2 I β γ - γ^2);
 Ha[β_] := A (I β + γ)/(1 - (β - I γ)^2);
 pp = ParametricPlot[
   {ReIm@Ha[β], ReIm@H[β]}, {β, 0, 2},
   Exclusions -> {β == 2},
   ImageSize -> Medium,
   PlotRange -> All,
   PlotPoints -> 300]]

EDIT: The gaps are closed when the Exclusion is at the max value of β

Manipulate[
 Module[
  {H, Ha, A = 0.015, α = 4, β, γ = 0.001},
  H[β_] :=
   (E^(-2 π α (I β + γ)) (-I E^(2 π α (I β + γ)) (β - I γ) +
        (I β + γ) Cos[2 π α] - Sin[2 π α]))/
    (-1 + β^2 - 2 I β γ - γ^2);
  Ha[β_] := A (I β + γ)/(1 - (β - I γ)^2);
  pp = ParametricPlot[
    {ReIm@Ha[β], ReIm@H[β]}, {β, 0, βmax},
    ImageSize -> Medium,
    PlotRange -> All,
    PlotPoints -> 300,
    Exclusions -> {β == βmax}]],
 {{βmax, 2}, 1, 2, .1, Appearance -> "Labeled"}]