Axes around image

Question

I have the following image (500*430pixels, 8bit, png): https://i.stack.imgur.com/iCVJy.png

How can I show axes around (horizontal data: [1,15]; vertical data: [2,10])?

The result should be the following:

score 9 · Accepted Answer · edited Nov 16 '16 at 16:24

9

pic = Import["https://i.imgur.com/QVlIq3g.png"];


Graphics[
 Inset[pic, Scaled[{.5, .5}], Automatic, Scaled[1]],
 Frame -> True,
 PlotRange -> {{1, 15}, {2, 10}},
 AspectRatio -> ImageAspectRatio@pic
]

edited Nov 16 '16 at 16:24

Greg Hurst

35,921
1
90
136

answered Nov 16 '16 at 15:44

Kuba

136,707
13
279
740

Great, thank you ... – mrz Nov 16 '16 at 16:00

Julien Kluge · Answer 2 · 2016-11-16T15:31:26.983

4

I wrote you a function for this. It works by explicit setting the option FrameTicks.

ShowImageWithTicks[img_,xRange_,yRange_]:=Module[{dims=ImageDimensions[img]},Show[img,Frame->True,FrameTicks->{{Partition[Riffle[Range[0,dims[[2]],dims[[2]]/(Length[yRange]-1)],yRange],2],None},{Partition[Riffle[Range[0,dims[[1]],dims[[1]]/(Length[xRange]-1)],xRange],2],None}}]]

Which can simply be called with:

img=Import["https://i.imgur.com/QVlIq3g.png"];

ShowImageWithTicks[img,Range[1,15,2],Range[2,10]]

Your Labels can simply be introduced by calling to Show and setting FrameLabel:

Show[ShowImageWithTicks[img,Range[1,15,2],Range[2,10]],FrameLabel->{"time [s]","x [mm]"}]

edited Nov 16 '16 at 15:31

answered Nov 16 '16 at 15:26

Julien Kluge

5,335
1
17
29

You're using a Show inside of a Show. Why not combine it to be more elegant? – corey979 Nov 16 '16 at 15:42
Because its not a complex task to set FrameLabel so i didn't saw the reason to do it. If OP wants to, i'll combine it into a single function with optional parameters. – Julien Kluge Nov 16 '16 at 15:47

score 3 · Answer 3 · answered Nov 16 '16 at 15:23

3

Assume, im is your image. Try this:

f[x_] := {(600 x)/8 - 150, x}
g[x_] := {(600*x)/(14), x}; 

    Show[im, Frame -> True, FrameTicks -> {{f[#] & /@ Range[2, 10, 2], None},
        {g[#] & /@ Range[2, 14, 2], None}}]

Have fun!

answered Nov 16 '16 at 15:23

Alexei Boulbitch

39,397
2
47
96

Thank you ... now I understand how to use FrameTicks ... – mrz Nov 18 '16 at 13:18

Mauricio Fernández · Answer 4 · 2016-11-16T15:24:09.050

2

One possibility, use Show and turn the axes on with Axes->True. A rather crude solution for the ticks would be to scale them as follows (but there are surely more elegant solutions):

tx = Table[{500*i, 15*i}, {i, 0, 1, 1/15}];
ty = Table[{430*i, 10*i}, {i, 0, 1, 1/10}];
Show[img, Axes -> True, AxesLabel -> {"time (sec)", "x (mm)"}, 
 Ticks -> {tx, ty}]

edited Nov 16 '16 at 15:24

answered Nov 16 '16 at 15:03

Mauricio Fernández

5,463
21
45

Thanks ... I would like to have different axes values than the pixel numbers (see above). – mrz Nov 16 '16 at 15:04

corey979 · Answer 5 · 2016-11-18T19:01:12.373

img = Import["https://i.imgur.com/QVlIq3g.png"];

id = ImageDimensions @ img

{500, 430}

ticks = {Transpose @ {Subdivide[0, id[[1]], 7], Subdivide[1, 15, 7]}, 
         Transpose @ {Subdivide[0, id[[2]], 4], Subdivide[2, 10, 4]}}

Labeled[Show[img, Axes -> True, Ticks -> ticks],
 {"time (s)", "x (mm)"}, {Bottom, Left}, RotateLabel -> True]

Using Frame is more straightforward, but I'm providing a different approach. Additionally, one can define pl = {{1, 15}, {2, 10}} and insert specific parts in ticks (as well as the number of subdivisions) to make it automated; I'll leave it as it is for clarity.

Axes around image

5 Answers5

Linked