1

I have the following function

(1/(35 \[Pi]^3 (-1 + 
t^2)^13))65536 t (-(-1 + t) (1 + t) (363 + 10310 t^2 + 58673 t^4 + 
  101548 t^6 + 58673 t^8 + 10310 t^10 + 363 t^12) + 
140 (1 + t^2) (1 + 48 t^2 + 393 t^4 + 832 t^6 + 393 t^8 + 48 t^10 +
   t^12) Log[t]) (t - t^3 + (-1 + t^4) ArcTanh[t] + 
t^2 (-4 PolyLog[2, t] + PolyLog[2, t^2]))^2

and would like to obtain a high-precision estimate of its integral over [0,1] (which I would then input, say to WolframAlpha, to check for a possible exact value). I've encountered numerical problems near t = 1.

bbgodfrey
  • 61,439
  • 17
  • 89
  • 156
Paul B. Slater
  • 2,335
  • 10
  • 16
  • How high a precision do you need? – bbgodfrey Dec 15 '16 at 03:22
  • Thanks bbgodfrey! Well, I'm basically (perhaps wildly) speculating that there might be some underlying exact value of note (maybe even a rational number), based on some prior considerations. So, if WolframAlpha, say, doesn't indicate such a value for a given precision, I could just try to get more numerical precision and try again. Of course, such a process could not go on for ever. I would imagine that perhaps an estimate accurate to say 15 places might settle the issue. – Paul B. Slater Dec 15 '16 at 03:35
  • Try 0.450160328041638434796903399409, but I am not aware of any capabilities that WolframAlpha has that Mathematica does not. – bbgodfrey Dec 15 '16 at 03:37
  • Can you maybe describe the provenance of this function? – J. M.'s missing motivation Dec 15 '16 at 06:48
  • For a possible exact value: Can Mathematica propose an exact value based on an approximate one? and an example application. Try also RootApproximant with ToRadicals. – corey979 Dec 15 '16 at 07:55
  • Thanks, J. M. To be very brief at this moment, I'm trying to find the complex analogue (\chi_2(\epsilon)) to (\chi_1(\epsilon)), that is eq. (9) in https://arxiv.org/pdf/1610.01410.pdf, but my analysis/approach may not be entirely correct. Also, bbgodfrey, I understand that one can evoke the WolframAlpha machinery in Mathematica itself. The suggested value 0.450160328041638434796903399409 doesn't seem to lead to anything of particular note--so I'm inclined, at this point, to suspect that I'm not fully correct in my attempted extension of the indicated Attila-Lovas eq. (9). – Paul B. Slater Dec 15 '16 at 13:18
  • To add to my just-posted comment, I was working under a ("Dyson-index/random-matrix") conjecture that \chi_2(\epsilon) would be proportional to the square of (\chi_1(\epsilon)). Getting things fully right here, however, seems quite tricky/challenging. – Paul B. Slater Dec 15 '16 at 13:35

1 Answers1

1
f[t_] = (1/(35 \[Pi]^3 (-1 + t^2)^13)) 65536 t (-(-1 + t) (1 + 
        t) (363 + 10310 t^2 + 58673 t^4 + 101548 t^6 + 58673 t^8 + 
        10310 t^10 + 363 t^12) + 
     140 (1 + t^2) (1 + 48 t^2 + 393 t^4 + 832 t^6 + 393 t^8 + 
        48 t^10 + t^12) Log[t]) (t - t^3 + (-1 + t^4) ArcTanh[t] + 
      t^2 (-4 PolyLog[2, t] + PolyLog[2, t^2]))^2;

High WorkingPrecision is required to Plot

Plot[f[t], {t, 0, 1}, WorkingPrecision -> 30]

enter image description here

Table[
   {wp, NIntegrate[f[t], {t, 0, 1},
      WorkingPrecision -> wp,
      MaxRecursion -> Infinity] //
     N[#, 15] &}, {wp, 15, 40, 
    5}] //
  Grid // Quiet

enter image description here

So the integral stabilizes to 15 decimal places at a WorkingPrecision of around 35

(int = NIntegrate[f[t], {t, 0, 1}, WorkingPrecision -> 35, 
     MaxRecursion -> Infinity]) // N[#, 15] & // Quiet

(*  0.450160328041638  *)

Using Round to rationalize

intr = int // Round[#, 10^-15] &

(*  225080164020819/500000000000000  *)

intr // N[#, 15] &

(*  0.450160328041638  *)

Using Rationalize

intr2 = Rationalize[int, 10*^-16]

(*  18677965/41491806  *)

intr2 // N[#, 15] &

(*  0.450160328041638  *)
Bob Hanlon
  • 157,611
  • 7
  • 77
  • 198