How to simplify the $Sqrt$

Question

I have a expression:

13 + 6 Sqrt[6 - x] x == x

I want to simplify the Sqrt to be -169+26 x+215 x^2-36 x^3==0.But Simplify[13 + 6 Sqrt[6 - x] x == x, Assumptions -> x < 6] don't work.And I have tried ComplexityFunction:

FullSimplify[13 + 6 Sqrt[6 - x] x == x, 
 ComplexityFunction -> (1000 Count[#, _Sqrt, {0, Infinity}] + 
     LeafCount[#] &)]

I can get anything still.So how to elminate the Sqrt?

I don't understand. How did you obtain the second expression from the first? They don't seem to have the same solutions either. — MarcoB, Feb 21 '17 at 14:52
@MarcoB Confused too.I just want elminate the Sqrt.I get it by ((x-13)/6x)^2+x-6==0//FullSimplify//Expand — yode, Feb 21 '17 at 15:06
OK but that still didn't explain the relationship between the expression with the Sqrt and the equation you have in comments. How did you get from ((x - 13) / 6 x)^2 + x - 6 == 0 to 13 + 6 Sqrt[6 - x] x == x? — MarcoB, Feb 21 '17 at 15:08
@MarcoB Move x - 6 to right of the equal sign,then execute sqrt...and so on — yode, Feb 21 '17 at 15:12
To be explicit, that expression is wrong. You probably meant -169 + 26 x + 215 x^2 - 36 x^3 == 0. — Szabolcs, Feb 21 '17 at 15:15
@Szabolcs Do you think what wrong with ((x-13)/6x)^2+x-6==0//FullSimplify//Expand? — yode, Feb 21 '17 at 15:32
Could have happened to me too ... couldn't see it for quite a while. — Szabolcs, Feb 21 '17 at 15:43

score 4 · Answer 1 · answered Feb 21 '17 at 15:58

4

Perhaps:

Solve[13 + 6 Sqrt[6 - x] x == x, x, Cubics -> False]

{{x -> Root[169 - 26 #1 - 215 #1^2 + 36 #1^3 &, 1]}}

answered Feb 21 '17 at 15:58

Carl Woll

130,679
6
243
355

little wired. :)Thanks all the same. – yode Feb 22 '17 at 02:15

score 3 · Answer 2 · edited Apr 13 '17 at 12:55

3

Adapting the F function from DSolve misses a solution of a differential equation, we get

Clear[rat];
(* rationalize fractional powers *)
rat[eqn_Equal] := rat[Subtract @@ eqn] == 0;
rat[fn_] := Module[{u}, 
   With[{rads = DeleteDuplicates@Cases[fn, Power[a_, b_Rational] :> u[a, b], Infinity]}, 
    First@GroebnerBasis[
      Flatten@{fn /. Power[a_, b_Rational] :> u[a, b], 
        Map[
         Numerator@Together[           (*gets rid of denominators in neg.powers*)
           #^Denominator[Last@#] - First[#]^Numerator[Last@#]
           ] &, 
         rads]}, rads]]];

rat[13 + 6 Sqrt[6 - x] x == x]

(* Out[79]= 169 - 26 x - 215 x^2 + 36 x^3 == 0 *)

edited Apr 13 '17 at 12:55

Community

1

answered Feb 21 '17 at 16:11

Goofy

2,767
10
12

Little long...;) – yode Feb 21 '17 at 16:15
2

@yode I think you mean "too general." :) – Goofy Feb 21 '17 at 16:19

score 0 · Answer 3 · answered Feb 22 '17 at 02:12

0

GroebnerBasis can do this:

First[GroebnerBasis[13 + 6 Sqrt[6 - x] x - x, x]]

169-26 x-215 x^2+36 x^3

answered Feb 22 '17 at 02:12

yode

26,686
4
62
167

How to simplify the $Sqrt$

3 Answers3